The API Corner: Understanding and Using UNIX-Type Time Values PDF Print E-mail
Programming - APIs
Written by Bruce Vining   
Wednesday, 15 February 2012 00:00

Support MC Press - Visit Our Sponsors

Forums Sponsor

POPULAR FORUMS

Forums

Search Sponsor

Search

Learn how to format a returned value such as 1,329,293,701 to a fixed definition of days, months, years, etc.

 

Earlier this month, over on the RPG Programming section of the IBM i mailing list rpg400-l@midrange.com, this question was posed: "Does anyone know how to convert the time values that are returned from the stat() IFS API for an IFS file?" The answer to the question of course is yes, and in this article, we'll look at some of the possible solutions.

 

First a little background on the stat() API. The stat() IFS API, also known as Get File Information and documented here, returns status information on a given IFS file to an application program. The information returned includes things like type of file (directory, file, symbolic link, etc.), the allocated size of the file, and—of interest today—time values for when the file was last accessed, when the file contents were last changed, and when the status of the file was last changed. The stat() API, along with many of the UNIX-type APIs, returns time information as 4-byte integer values representing the number of seconds since a fixed point in time known as the Epoch. This fixed point in time is defined by the industry as being January 1, 1970 at time 00:00:00 UTC.

 

Let's say that the stat() API has been called and has returned a value of 1,329,293,701 for the time of last access for a given file. If all we want to do is convert this value to a human-readable format, we can use the Convert Time to a Character String (ctime) API as shown below (where the variable Seconds is initialized to the value returned by the stat() API).

 

h dftactgrp(*NO) bnddir('QC2LE')                                  

                                                                 

dCTime            pr              *   extproc('ctime')           

d SecsAftEpoch                  10i 0 const                      

 

dSeconds          s             10i 0 inz(1329293701)

 

dTZPtr            s               *                                

dTZChar           s             26a   based(TZPtr)                 

 

 /free                                             

                                                    

  TZPtr = ctime(Seconds);                          

  dsply TZChar;                                    

              

  *inlr = *on;                                                        

  return;               

                         

 /end-free                       

 

The preceding program, when compiled and run, will display a message similar to this:

 

Wed Feb 15 02:15:01 2012­        

 

I say "similar to" because the text you actually see can vary due to the time zone your system is running in (my system, being in Rochester, Minnesota, is using United States Central Time), the national language environment your job is running in, and other factors. It's these "factors" influencing the actual text returned by the ctime() API that can make using the API a bit awkward for application programmers. This text approach is fine for display purposes, but trying to make application decisions based on the message text can lead to some rather convoluted programming. Much better, from an application point of view, would be to understand how to format the returned value of 1,329,293,701 to a fixed definition of days, months, years, etc., which is the focus of the remainder of this article.

 

The ctime() API, by the way, is documented in the ILE C/C++ Run-Time Library Functions manual found here and available on all current systems regardless of whether or not you have the C language compiler installed. And, if your system is at 6.1 or later, you do not need to specify the bnddir('QC2LE') H-spec control keyword that is used in the sample program. The QC2LE binding directory, which is associated with C run-time library functions, is implicitly used by the system when creating programs at 6.1 and later. Also note that you may see a "blob" following the year in the previous message display. This is due to the ctime() API returning a null byte (x'00') at the end of the text string—and the sample program doesn't bother removing this null byte.

 

One approach to formatting the time value returned by the stat() API is to convert the number of seconds returned by the API to an RPG Timestamp variable as shown in the following program.

 

h dftactgrp(*NO) bnddir('QC2LE')                                 

 

dSeconds          s             10i 0 inz(1329293701)              

dAccessDate       s               z 

 

dEpoch            s               z   inz(z'1970-01-01-00.00.00')  

 

 /free                                             

 

  AccessDate = Epoch + %seconds(Seconds);                             

  dsply %char(AccessDate);                                            

 

  *inlr = *on;                                                        

  return;               

                         

 /end-free                       

 

This program displays a timestamp value of  2012-02-15-08.15.01.000000 and, from an application program usage point of view, enables you to then use the wealth of date, time, and timestamp operators of RPG to analyze and manipulate the date and time of last access to the IFS file. You might notice, though, that the ctime() API returned a time of 2:15:01 while the RPG Access Date variable shows a time of 8:15:01. The reason for this six-hour difference is that the stat() API is returning a UTC time value, and while the ctime() API automatically adjusts the UTC time to your local time zone, the RPG timestamp operation does not. Assuming that you would prefer to work in local time, there is an API, Get Offset from Universal Time Coordinated to Local Time (CEEUTCO) documented here, that can be used as shown below to retrieve the offset of our local time zone from UTC.

 

h dftactgrp(*NO) bnddir('QC2LE')                                

 

dGetUTCOffset     pr                  extproc('CEEUTCO')         

d Hours                         10i 0                            

d Minutes                       10i 0                             

d Seconds                        8f                              

d FC                            12a   options(*omit)             

 

dSeconds          s             10i 0 inz(1329293701)              

dAccessDate       s               z 

 

dUTCOfsHrs        s             10i 0  

dUTCOfsMins       s             10i 0  

dUTCOfsSecs       s              8f    

 

dEpoch            s               z   inz(z'1970-01-01-00.00.00')  

 

 /free                                             

 

  GetUTCOffset(UTCOfsHrs :UTCOfsMins :UTCOfsSecs :*omit);             

  AccessDate = Epoch + %seconds(Seconds) + %seconds(%int(UTCOfsSecs));

  dsply %char(AccessDate);                                            

 

  *inlr = *on;                                                         

  return;               

                        

 /end-free                        

 

By adding in the local time zones offset from UTC, in seconds, to AccessDate, the sample program now displays a time zone value of 2012-02-15-02.15.01.000000—the local time of last access to the IFS file. In case you're wondering why I used the UTC offset in seconds, as opposed to hours, there are a few time zones in the world where the offset is not an integer number of hours. Using seconds when making local time zone adjustments allows the program to function correctly in many geographical locations without requiring local customizations.

 

A second approach to formatting the returned value of 1,329,293,701 is using the Convert Time (localtime) API. This API, documented in the ILE C/C++ Run-Time Library Functions manual found here, converts a UTC time value to a data structure comprised of integer subfields defining the date and time in terms of seconds, minutes, hours, days, years, etc. as shown by the data structure TM in the following program.

 

h dftactgrp(*NO) bnddir('QC2LE')                                 

                                                                  

dLocalTime        pr              *   extproc('localtime')       

d SecsAftEpoch                  10i 0 const                      

 

dSeconds          s             10i 0 inz(1329293701)              

 

dTMPtr            s               *                                

dTM               ds                  based(TMPtr)                 

d SecsOfMinute                  10i 0                              

d MinutesOfHour                 10i 0                              

d HourOfDay                     10i 0                              

d DayOfMonth                    10i 0              

d MthsAftJan                    10i 0              

d YrsAft1900                    10i 0              

d DaysAftSun                    10i 0              

d DaysAftJan1                   10i 0              

d DSTFlag                       10i 0              

                                                   

 /free                                             

 

  TMPtr = localtime(Seconds);                      

  dsply %char(SecsOfMinute);                       

  dsply %char(MinutesOfHour);                      

  dsply %char(HourOfDay);                          

  dsply %char(DayOfMonth);                         

  dsply %char(MthsAftJan);                                            

  dsply %char(YrsAft1900);                                            

  dsply %char(DaysAftSun);                                            

  dsply %char(DaysAftJan1);                                            

  dsply %char(DSTFlag);                                               

                                                                      

  *inlr = *on;                                                        

  return;                

                        

 /end-free                        

 

The previous program, when run, will display the following information.

 

DSPLY  1                                

DSPLY  15                               

DSPLY  2                                 

DSPLY  15                               

DSPLY  1                                

DSPLY  112                              

DSPLY  3                                

DSPLY  45                               

DSPLY  -1                                

 

The previous displays are showing that the TM data structure subfields of SecsOfMinute (second), MinutesOfHour (minute), HourOfDay (hour), DayOfMonth (day), MthsAftJan (month), YrsAft1900 (year), DaysAftSun (day of week), DaysAftJan1 (day of year), and DSTFlag (Daylight Saving Time) are set to 1, 5, 2, 15, 1, 112, 3, 45, and -1, respectively. In other words, the time is 2:15:01 on Wednesday Feb 15 2012, which happens to be the 46th day of the year. There are a few items I would like to point out about these fields. First, several of the subfields are defined as being base 0. For instance, the MthsAftJan will be set to the value of 0 for January rather than the 1 you might expect (meaning a value of  1 indicates the month of February, one month after January); Sunday is represented by the DaysAftSun value of 0, and January 1 is considered day 0 of the returned year. Second, you may (or may not) be surprised by seeing (infrequently) some minutes having 60 or 61 seconds rather than the expected 0 – 59 seconds after the minute. These additional seconds are to accommodate leap seconds, which the i does support right along with leap days (that we're all familiar with).

 

Returning to the first program of this article, where the ctime() API created a textual representation of a time value, while automatically adjusting the input UTC time value to local time, there is also the Convert Time to Character String (asctime) API, which will take as input a structure such as our TM data structure and then return a character string representation of the time without making any time zone adjustments. Using this API as shown below will also result in the character string Wed Feb 15 02:15:01 2012 being displayed.

 

h dftactgrp(*NO) bnddir('QC2LE')                                  

                                                                 

dLocalTime        pr              *   extproc('localtime')       

d SecsAftEpoch                  10i 0 const                      

 

dASCTime          pr              *   extproc('asctime')         

d TMStruct                            like(TM)                   

 

dSeconds          s             10i 0 inz(1329293701)              

 

dTZPtr            s               *                                

dTZChar           s             26a   based(TZPtr)                 

 

dTMPtr            s               *                                

dTM               ds                  based(TMPtr)                 

d SecsOfMinute                  10i 0                              

d MinutesOfHour                 10i 0                              

d HourOfDay                     10i 0                              

d DayOfMonth                    10i 0              

d MthsAftJan                    10i 0              

d YrsAft1900                    10i 0              

d DaysAftSun                    10i 0              

d DaysAftJan1                   10i 0              

d DSTFlag                       10i 0              

                                                   

 /free                                              

 

  TMPtr = localtime(Seconds);                      

  TZPtr = asctime(TM);                                                

  dsply TZChar;                                                       

                                                                       

  *inlr = *on;                                                        

  return;               

                        

 /end-free                        

 

If you work very often with the UNIX-type APIs, where the IFS APIs are simply one member of the UNIX-type family of APIs, you will find that Epoch-based time values can show up most anyplace. This article hopefully provides you with a few approaches as to how you can work with these Epoch time values in an easy, familiar, and productive manner.

 

As usual, if you have any API questions, send them to me at bvining@brucevining.com. I'll see what I can do about answering your burning questions in future columns.

 

 


Bruce Vining
About the Author:

Bruce Vining is president and co-founder of Bruce Vining Services, L.L.C., a firm providing contract programming and consulting services to the System i community (www.brucevining.com). He began his career in1979 as an IBM Systems Engineer in St. Louis, Missouri, and then transferred to Rochester, Minnesota, in 1985, where he continues to reside. From 1992 until leaving IBM in 2007, Bruce was a member of the System Design Control Group responsible for OS/400 and i5/OS areas such as System APIs, Globalization, and Software Serviceability. He is also the designer of Control Language for Files (CLF).

 

A frequent speaker and writer, Bruce can be reached at bvining@brucevining.com.

 

MC Press books written by Bruce Vining available now on the MC Press Bookstore.

 

IBM System i APIs at Work IBM System i APIs at Work

Master APIs with this in-depth, example-rich exploration into these powerful tools.

List Price $89.95
Now On Sale
 
Read More >>
Last Updated on Wednesday, 15 February 2012 00:00
 
User Rating: / 1
PoorBest 

   MC-STORE.COM