There's one task to accomplish and so many ways to do it.

This article is about a common thing, something we do every day, something most of us never really think about. Maybe we were provided with some code long ago, and since then, that's just the way we do it.

I am talking about looping through a file in RPG, a subject I hope really can stir up your coffee cup sitting next to your keyboard. I am not saying my way of looping is the correct or best or most bright one, but I will show you the method I have developed and used for many years; it never let me down or came in "late," and it always did the job.

Let me admit it I never liked this way:

1. Setll
2. Read
3. Enter the loop
4. Process the record
5. And then, as the last thing, read again

I never could see the point in that way of looping, so I'm risking putting my nose out for a big punch. I offer you "My Way of Looping."

But before I throw myself in front of the lions, please allow me to explain what I define as a looping task. A looping task to me is where you want to read a file (part of a file), do some checking of the data read, and use the data if the checking is all right; otherwise, reject the record and read a new one.

You might not always have the correct data when reading your data; therefore, sometimes you have to read more records than you actually need to use. Maybe the user made an input selection on some codes or types where it doesn't make sense to have an index, so you just process that extra data and, looping through, you do the checking.

I know I could use SQL, and I often do, but I know that still a lot of looping and reading are done through good ol' RPG.

So my way of looping looks like this:

1. Setll
2. Enter the loop
3. Read
4. Check for EOF
5. Check data
6. Process the record

I have created a small test file that I will use throughout this article. All my source code is stored in library MWOL, and you can download it as a save file (see links at the end of this article).

The DDS layout for MWOL0100 is like this:

     A          R MWRECORD

     A            MWKEY          3A         TEXT('Key field')

     A            MWNAME        50A         TEXT('Name')

     A            MWCODE         2A         TEXT('Code')

     A            MWTYPE         3A         TEXT('Type')

     A            MWPRICE        6S 2       TEXT('Price')

      * Key

     A          K MWKEY

The data in the file is like this:

MWKEY MWNAME       MWCODE MWTYPE MWPRICE

1     PROD-2       P2     A2      123.12

2     PROD-1       P1     A1      123.12

3     PROD-3       P3     C1     1423.12

4     PROD-123     P2     A1       10.01

5     PROD-222     P1     A2      450.01

6     PROD-711     P3     B1       50.01

The first example will just read the file from start to end and is mostly done just to give you an idea of "My Way of Looping."

Please note that the examples do nothing. You can run them through the debugger to see what happens if you want.

Here is how the code looks:

     H CopyRight('Copyright My Way of Looping (c) - 2011')

     H DatEdit(*YMD.)

     H Option( *SrcStmt: *NoDebugIO)

     H DECEDIT(*JOBRUN)

      //*=============================================================

      //*

      //* Function  : Example 1 - My Way of Looping

      //*

      //* ------------------------------------------------------------

     FMWOL0100  IF   E           K DISK

      //==============================================================

      //             DECLARE WORK FIELDS, ARRAYS AND MORE

      //==============================================================

      //---------------------------------------------------------------

      // Declare key list(s) (KLIST)

      //---------------------------------------------------------------

     D kMWOL0100       ds                  LikeRec( MWRECORD : *Key )

     D EOF             s               n   inz( *OFF )

      //==============================================================

      // Main Loop

      //==============================================================

      /free

       //---------------------------------------------------------------

       // Init program...

       //---------------------------------------------------------------

       //---------------------------------------------------------------

       // Read data

       //---------------------------------------------------------------

A

         SetLL *START MWOL0100;

B

        DoW NOT EOF;

C

            // Read data

              Read MWRECORD;

D

            // End of file

              If %eof( MWOL0100 );

               Leave ;

              Endif ;

E

            // Check data

            // -- No checking

F

            // Process record

              MWKEY   = MWKEY;

              MWNAME  = MWNAME;

              MWCODE  = MWCODE;

              MWTYPE  = MWTYPE;

              MWPRICE = MWPRICE;

        EndDo;

G

       //---------------------------------------------------------------

       // Stop Program

       //---------------------------------------------------------------

         ExSr StopPgm;

       //---------------------------------------------------------------

       // Stop Program

       //---------------------------------------------------------------

       BegSr StopPgm;

         *inLR = *ON;

         Return;

       EndSr;

      /end-free

The program is very simple, but the structure reflects how I like to loop through a file.

1. A: Setll in the file.
2. B: Start the loop and use filed EOF, which is init to *OFF to control the loop (if you are really brave, use 1 = 2 because the EOF does not really serve any purpose in this example).
3. C: Read a record.
4. D: Check for EOF and, if yes, leave the loop.
5. E: Check data (nothing in this example).
6. F: Process the data.
7. G: Stop the program.

So far, so good. I hope that you haven't spilled your coffee, because now let's add some setll'ing and checking.

Have a look at example 2.

     H CopyRight('Copyright My Way of Looping (c) - 2011')

     H DatEdit(*YMD.)

     H Option( *SrcStmt: *NoDebugIO)

     H DECEDIT(*JOBRUN)

      //*=============================================================

      //*

      //* Function  : Example 2 - My Way of Looping

      //*

      //* ------------------------------------------------------------

     FMWOL0100  IF   E           K DISK

      //==============================================================

      //             DECLARE WORK FIELDS, ARRAYS AND MORE

      //==============================================================

      //---------------------------------------------------------------

      // Declare key list(s) (KLIST)

      //---------------------------------------------------------------

     D kMWOL0100       ds                  LikeRec( MWRECORD : *Key )

     D EOF             s               n   inz( *OFF )

 A   D chk_MWCODE      s                   like( MWCODE )

      //==============================================================

      // Main Loop

      //==============================================================

      /free

       //---------------------------------------------------------------

       // Init program...

       //---------------------------------------------------------------

  B      chk_MWCODE = 'P1';

       //---------------------------------------------------------------

       // Read data

       //---------------------------------------------------------------

  C      kMWOL0100.MWKEY = '1';

         Setll  %kds(kMWOL0100) MWRECORD;

        DoW NOT EOF;

            // Read data

              Read MWRECORD;

            // End of file

              If %eof( MWOL0100 );

               Leave ;

              Endif ;

   D        // Check if wanted MWCODE

              If (MWCODE <> chk_MWCODE );

               Iter ;

              Endif ;

            // Process record

              MWKEY   = MWKEY;

              MWNAME  = MWNAME;

              MWCODE  = MWCODE;

              MWTYPE  = MWTYPE;

              MWPRICE = MWPRICE;

        EndDo;

       //---------------------------------------------------------------

       // Stop Program

       //---------------------------------------------------------------

         ExSr StopPgm;

       //---------------------------------------------------------------

       // Stop Program

       //---------------------------------------------------------------

       BegSr StopPgm;

         *inLR = *ON;

         Return;

       EndSr;

      /end-free

Of course, you get the point. Here is what happens.

1. A: Define "Input prompt" field to hold check value.
2. B:  Set check value to 'P1' (that is the only thing we want to read).
3. C:  Setll (just for the example): Note the *KEY definition will define the key as a unique data structure, a very nice RPG feature if you ask me.
4. D: In my world, this is where the "clever" part kicks in; this is the place where you do all the checking, and by doing it this way, you gain two things: 1) You always know where to put the checking part (after the EOF checking) and 2) after checking is done, you always know that the record is valid and you can process it.

Maybe you have to do some more chains to other files, or you might want to call a subroutine to do some reading, or likewise, but no matter what, it's very easy to add a new check code like I have done in example 3 (only the checking part is shown):

       //---------------------------------------------------------------

       // Init program...

       //---------------------------------------------------------------

         chk_MWCODE  = 'P1';

         chk_MWPRICE = 100;

       //---------------------------------------------------------------

       // Read data

       //---------------------------------------------------------------

         kMWOL0100.MWKEY = '1';

         Setll  %kds(kMWOL0100) MWRECORD;

        DoW NOT EOF;

            // Read data

              Read MWRECORD;

            // End of file

              If %eof( MWOL0100 );

               Leave ;

              Endif ;

            // Check if wanted MWCODE

              If ( MWCODE <> chk_MWCODE );

               Iter ;

              Endif ;

            // Process only records with a price greater than chk_MWPRICE

              If ( MWPRICE < chk_MWPRICE );

               Iter ;

              Endif ;

As you can see in example 3, only records with a price greater than 100 are processed.

If you want to download my code as a save file, click on the link below. I have also uploaded the examples as text files, so if that is what you like, they are here as well.

Downloads

MWOL as save file

RPG Source

MWOL001     RPGLE       My Way of Looping, Example 1

MWOL002     RPGLE       My Way of Looping, Example 2

MWOL003     RPGLE       My Way of Looping, Example 3

DDS Source

MWOL0100    PF          My Way of Looping

End Looping

So hit your keyboard, and let me know if what I have been doing for years can be done in a much more clever and simple way. Maybe it's not too late to teach an old dog like me new tricks and methods, and believe me I really want to be tested about this.

Till next time, happy looping.

as/400, os/400, iseries, system i, i5/os, ibm i, power systems, 6.1, 7.1, V7, V6R1

Jan Jorgensen is one of the owners of www.reeft.dk, which specializes in mobile and i5 solutions. He works with RPG, HTML, JavaScript, Perl, and PHP. You can reach him at This email address is being protected from spambots. You need JavaScript enabled to view it.. 

 

Also Read

Getting Started with Ansible on IBM i

Maximize the power of your lines of defense against cyber-attacks with IBM Storage FlashSystem and IBM Storage Defender

Building the human firewall: Navigating behavioral change in security awareness and culture