Retrieving the Directory Contents of an FTP Server from Within RPG PDF Print E-mail
Programming - RPG
Written by Thomas Snyder   
Wednesday, 16 September 2009 00:00

Support MC Press - Visit Our Sponsors

 

Forums Sponsor

POPULAR FORUMS

Forums

 

 

Search Sponsor

 

POPULAR SEARCHES

Search

Create an RPG program to retrieve a list of existing files on an FTP server.

 

In a previous article, I discussed how to upload a file to an FTP server and how to automate the process using RPG in a manner that would allow your program to evolve to easily support future modifications and server additions and changes. In this article, I'll discuss how you can retrieve information from an FTP server and use that information to download files.

Verifying FTP Server Access from the IBM i

As I mentioned in my previous article, you should test out your file transfer interactively prior to automating your FTP process. For this example, we will be listing the contents of a directory on a fictitious FTP server:

 

 

Fictitious Target FTP Server Information

Target FTP Server

ftp.example.com

User Name

tomsnyder

Password

mcpress

 

Testing the FTP process interactively will ensure that the IBM i has access to the server and that the user name and password are active on the target server. You can do this by typing FTP or STRTCPFTP on the command line and prompting it to enter the DNS name or IP address of the server, or you can enter the FTP server information with this command:

 

FTP RMTSYS('ftp.example.com')

 

or

 

STRTCPFTP RMTSYS('ftp.example.com')

 

Once you have successfully connected to the FTP server, you will enter your user name and password interactively.

 

Interactively Retrieving the Directory List from the FTP Server

 

To retrieve the contents of the directory list, we will use the DIR command on the FTP server that we are connected to. If you used the DIR command alone, it would list the directory contents to the screen. But there is a (DISK option that we will usr with the DIR command to download the list to a physical file.

 

USER PWD

dir (DISK

close

quit

 

When you execute the dir (DISK command, the directory contents of the location that your profile has access to on the server will be downloaded into the DIROUTPUT member of the DIROUTPUT file in your current library.

Retrieving the Directory List from the FTP Server in Batch

 

Now that we have verified that we can successfully download the directory list into a physical file, we can automate the process by reusing the program that we created in the previous article. For this article, we will refer to the previous program as FTPPGM.

 

The FTPPGM will use the FTPINPUT file, which will be overridden to be the INPUT file that is expected for use with the STRTCPFTP command. The FTPINPUT file will be a physical file containing a single field that will contain the commands to be sequentially executed by STRTCPFTP.

 

For this example, we will create a new member in the FTPINPUT file named MCP_DIR. The MCP_DIR member will contain the user name and password in the first record; the rest of the commands are listed above when the FTP was executed interactively:

 

tomsnyder mcpress

dir (DISK

close

quit

 

Overriding the DIROUTPUT File

 

The first thing I would like to do is override the DIROUTPUT file to put it into its own member. This will help to avoid creating file locks and/or inadvertently overwriting your expected data when another directory listing program is running at the same time. No problem: just create a physical file with a field large enough to accommodate the file information and override it to the member that you would like to use. I displayed the file description for DIROUTPUT to be 256 characters, so I made FTPOUTPUT the same size. For this example, we will be using the MCP_DIR member of a new file named FTPOUTPUT. You could get more creative by using the job name or whatever you would feel adequate to avoid file locks with other concurrent jobs. Here is the DDS we'll use for that file:

 

A          R FTPFMT2

A            FTPOUT       256

 

Overlaying Fields onto the File Information

 

When you download the directory listing into your FTPOUTPUT file, you will probably want to overlay some fields onto the data to separate the information into usable data. I am sure that with all the different operating systems and FTP servers that you support, as I do, you may find differences between the data results of an IBM i versus Windows, UNIX, Linux, or a Mac, and you may have to tweak your overlays, but I have found this one to work for most cases.

 

DXFTPOUTPUT       E DS                  EXTNAME(FTPOUTPUT)

D FOFILEDATE              1      8

D FOFILETIME             11     17

D FOFILEDATIM             1     17

D FOFILEDIR              25     29

D FOFILESIZE             29     38

D FOFILENAME             40     89

D FOMACFNAME             49     98

 

One solution to supporting multiple operating systems would be to expand the FTPSERVERS file that contains the server information to include the operating system of the FTP server to determine which overlay template to use. You can see that there is a FOMACFNAME field defined that I use for file names on Macintosh FTP servers.

The Code

 

At this point, we have tested the FTP commands interactively, created a data structure to overlay the results of the FTP DIR command, populated our FTPINPUT file to contain the commands that will be executed in batch, and successfully downloaded the directory listing into our FTPOUTPUT file. Now we can use this information to create a basic RPG program that will utilize these resources and that can be used as a starting point for more-complex implementations. In order to do this, we will reuse the application that was created in the previous FTP article to execute the commands. Then we will read through the data that was downloaded using the DIR (DISK command.

 

FFTPOUTPUT IF   E           K DISK    USROPN

D**********************************************************************

DARGS             DS

D ARGSITE                       10A

D ARGJOB                        10A

D* Field Overlays onto DIR results in FTPOUTPUT file.

D XFTPOUTPUT    E DS                  EXTNAME(FTPOUTPUT)

D  FOFILEDATE             1      8

D  FOFILETIME            11     17

D  FOFILEDATIM            1     17

D  FOFILEDIR             25     29

D  FOFILESIZE            29     38

D  FOFILENAME            40     89

D  FOMACFNAME            49     98

D* Prototype for QCMDEXC

D ExecuteCommand...

D                 PR                  extPgm('QCMDEXC')

D  argInCommand              65535A   const options(*varsize)

D  argInLength                  15P 5 const

D*

D cmd             S           1024A

D displayBytes    S             52A

D*

C/EJECT

C     *ENTRY        PLIST

C                   PARM                    ARGS

/free

// Change the current library for DIROUTPUT

cmd = 'CHGCURLIB CURLIB(MYLIB)';

ExecuteCommand(%trim(CMD):%len(%trim(CMD)));

// Override the DIROUTPUT file Member

cmd = 'OVRDBF FILE(DIROUTPUT)'

+ ' TOFILE(DIROUTPUT)'

+ ' MBR(' + %TRIM(ARGJOB) + ')';

ExecuteCommand(%trim(CMD):%len(%trim(CMD)));

// Execute the FTP commands to download the directory list

// This is the program discussed in the previous FTP article

cmd = 'CALL FTPPGM ''SCRANTON  MCP_DIR''';

ExecuteCommand(%trim(CMD):%len(%trim(CMD)));

// Copy the DIROUTPUT file to FTPOUTPUT

cmd = 'CPYF FROMFILE(DIROUTPUT)'

+ ' TOFILE(FTPOUTPUT)'

+ ' FROMMBR(' + %TRIM(ARGJOB) + ')'

+ ' TOMBR(' + %TRIM(ARGJOB) + ')'

+ ' MBROPT(*REPLACE) FMTOPT(*NOCHK)';

ExecuteCommand(%trim(CMD):%len(%trim(CMD)));

// Override the DIROUTPUT file Member

cmd = 'OVRDBF FILE(FTPOUTPUT)'

+ ' TOFILE(FTPOUTPUT)'

+ ' MBR(' + %TRIM(ARGJOB) + ')';

ExecuteCommand(%trim(CMD):%len(%trim(CMD)));

open FTPOUTPUT;

read FTPOUTPUT;

dow not %eof(FTPOUTPUT);

displayBytes = 'File: '

+ %trim(FOFILENAME) + ' '

+ %trim(FOFILEDATIM);

dsply displayBytes;

read FTPOUTPUT;

enddo;

close FTPOUTPUT;

*inlr = *ON;

/end-free

 

This program will demonstrate how to get the basic functionality working. With this foundation, you could reuse the logic in batch to verify file transfers, retrieve file lists to assist with errors associated with missing files on a Web server for XML feeds, or automatically perform administrative tasks on remote servers.

 

You could also use this logic for interactive programs to allow users to view and perform transfers on files that are located on remote servers. This can be done simply by writing the contents to a display file and providing some options for actions to be performed. If you were to allow navigation through the folders, you could simply repopulate the FTPINPUT file within your program, resubmit the call to the FTPPGM with the new FTPINPUT file to execute the desired commands, and then repopulate the subfile with the results.

 

Download the Code

 

You can download the code used in this article--as well as the fixed-format version--by clicking here.

 

More Information

 

For more information on FTP on the IBM i, you can find a PDF about FTP on the IBM Web site that contains additional information on the FTP DIR command.

 


Thomas Snyder
About the Author:

Tom Snyder has a diverse spectrum of programming experience encompassing IBM technologies, open-source, Apple, and Microsoft and utilizing these technologies with applications on the server, on the web, or on mobile devices.

 

Tom has over 20 years experience as a software developer in various environments, primarily in RPG, Java, C#, and PHP and holds certifications in Java from Sun and PHP from Zend. Prior to software development, Tom worked as a Hardware Engineer at Intel and is a proud United States Naval Veteran Submariner who served aboard the USS Whale SSN638 submarine.

 

Tom is the best-selling author of Advanced Integrated RPG, which covers the latest programming techniques for RPG ILE and Java to utilize open-source technologies.

 

Originally from and currently residing in Scranton, Pennsylvania. Tom is currently involved in a Mobile Application Start-up company named JoltRabbit LLC.

 

 


MC Press books written by Thomas Snyder available now on the MC Press Bookstore.

 

Advanced, Integrated RPG Advanced, Integrated RPG

This book shows you how to take advantage of the latest technologies from within existing RPG applications.

List Price $79.95
Now On Sale
 

 

Read More >>
Last Updated on Wednesday, 16 September 2009 00:00
 
User Rating: / 5
PoorBest 
   MC-STORE.COM