Many iSeries programmers do a great job of writing comments within their RPG IV code, and as far as I am concerned, the more comments the better. I once saw code with comments that jumped right out at me because the comments were white, with the code green. The programmer had "borrowed" the program that had this in it from someone else, who borrowed from another, etc. It sounded like borrowing yeast for bread as our ancestors once did.
I also borrowed one of these programs, populating my comments to white as well. Finally, my curiosity overcame me, and I decided to check out how this little trick was done. Just before the comment, in the same line, was what appeared to be a blank, but upon further investigation, it was not a blank at all. It was a value of hex 22. I found this out by doing a display of the physical file member for my program source. When the source line is sent to the screen, using SEU, the hex 22 changes the display attribute of the remainder of the line to high intensity. Since I am using a 5250 emulator (Client Access), high intensity doesn't exist, so the emulator sets the color to white.
The following is a short RPG IV program that you can use to set your comments to appear in white, regardless of whether you prefer fixed-format or free-format calculations. You must use V5R1 (or later) to compile the program. I have called the program SRCCMTHI (for source comments high intensity):
* Program SRCCMTHI to turn comments to white within an RPGLE source member
* The source member to be affected is determined by an Ovrdbf command
* Example: OVRDBF FILE(QRPGLESRC) MBR(source-program-name)
* CALL SRCCMTHI
F Qrpglesrc UF e disk Rename(Qrpglesrc:Rec)
* Constants and variables
D Hex22 C X'22'
D loc S 2 0
D fflag S n
* Data structure to help minimize substringing
D DS
D Srcdta
D Stdcomment 2 overlay(Srcdta:7)
D free 5 overlay(Srcdta:7)
D Calcmt 69 overlay(Srcdta:8)
/free
Read Rec; // Read first source statement
Dow not %eof; // While not at eof
If Stdcomment = '* '; // Position 7 is * and 8 a blank?
%subst(srcdta:8:1) = Hex22; // Yes – put the high int. char in 8
Elseif free = '/free' // No – Is this free-format start?
or free = '/Free' // (differing upper/lower case)
or free = '/FREE';
fflaf = *On; // Yes, set free-format flag
Elseif fflag = *On; // Is fflag set from earlier time?
If free = '/end-' // Is this an end-free line?
or free = '/End-' // (differing upper/lower case)
or free = '/END-';
fflag = *Off; // Yes, reset free format flag
Else; // No
Loc = %scan('//':Calcmt:1); // Find start of free format comment
If loc > 0 and %subst(Calcmt:loc+2:1) = *blank // Found comment and
// next char after slashes is a blank
%subst(Calcmt:Loc+2:1) = Hex22; // Set high int. byte after slashes
Endif;
Endif;
Endif;
Update Rec; // Update every record
Read Rec; // Read next record
Enddo;
*Inlr = *On; // End program
/end-free |
|
This code will work if there are compile time arrays or tables, unless there is an asterisk (*) in position 7 followed by a space in 8 within the table/array data. If that happens, the space is turned into a hex 22. No results are guaranteed if you use this code, but it has worked well for me so far.
You may want to try the program first with a copy of your source program, just to see if you're going to like the results.
Jim Martin is corporate technical instructor at Jack Henry & Associates in Monett, Missouri. He is a veteran of RPG programming, beginning in 1967 with a position at IBM as a systems engineer and later was a staff programmer at the Rochester systems programming lab. For eight years, he was at Lakeview Technology as an AS/400 and RPG instructor and was a speaker at various local midrange user group meetings and conferences. He can be reached by email at jmartin@truevine.net.
|
