Those of us who "grew up" on RPG find it strange that there would be a need for character-to-numeric built-ins, since good old MOVE has done the job quite well for a long time. But it's a whole new world out there. In free-format calculations, there is no MOVE instruction!
Assuming that free-format will become the preferred method, then learning a few things about these built-ins now will give you a head start on the future. You can also start using these built-ins using the expanded factor 2 coding method before adopting the free-format method.
First, I'd like to introduce you to the simple, but very useful %int built-in. Its V5R1 purpose was to truncate decimal fractions from mixed numbers, returning the whole number part. But since V5R2, this built-in function can take a character variable (made of numbers) and convert it to integers. If the character variable contains non-numbers, an exception occurs. For negatives, the character string can have the minus preceding or following the numbers ('12345-'). Here's an example:
D Account# S 6 0
D Account_A S 6 Inz('123456')
/free
Account# = %int(Account_A); After the calculation, Account# contains 123456. When numeric data comes into RPG IV programs as character data, you can use this new built-in instead of MOVE.
If all numeric fields were integers, I'd be done with this tip. But such is not the case in reality. Sometimes, we get numeric data in alpha fields that is to be converted to a decimal mixed number, such as dollars and cents. In this case, the %dec built-in function is the solution. Again, V5R2 or later is needed, and a couple of additional parameters are required to get the desired result. The format of the built-in function is as follows:
%dec(character-field:length:dec-places) The character field can have blanks in it and a leading or trailing plus or minus sign (+ or -), but embedded commas and currency symbols need to be removed. You can easily do this using the %xlate built-in function inside the %dec. The %dec built-in function interprets a period or comma as the decimal "point." The following are some examples:
D Amount1_A S 10 Inz('3 26 4.78-')
D IntRate_A S 12 Inz('. 0 5 6 2 5')
D Amount1 S 9 2
D IntRate S 5 5
/free
Amount1 = %dec(Amount1_A:9:2);
IntRate = %dec(IntRate_A:5:5); The Amount1 field is now –3264.78, and IntRate is .05625. Remember though that the decimal point of the answer is being determined by the decimal point in the character field. In real life, nothing seems to match to these examples quite so nicely. What if the character input data doesn't have a decimal point in it (and you want the last two digits as the decimal positions)? When this occurs, using a 2 as the third parameter in %dec doesn't work!
If you are thinking of using built-in functions %len and %decpos (of the result field) as the second and third parameters, forget it. That won't work either. First, these two parameters must be literals or named constants, and second, they only define the return value.
The decimal fraction outcome of the %dec conversion is dependent on the location of the decimal point or comma in the character string.
To clarify, I will use a code illustration. In the following illustration, a character variable (Amount_A) has no decimal point, but it is desired that the last two digits are the decimal positions of the answer (should I use a 2 as the third parameter of the %dec?).
D Amount_A S 10 Inz('326478-')
D Amount S 9 2
/free
Amount = %dec(Amount_A:9:2); This code doesn't work! Since the input field has no decimal point, the Amount field becomes 326478.00-. In addition, if my example used an eight-digit number (for the Inz value) for Amount_A instead of six digits, a runtime sizing error would occur because the result value of the %dec would be 10 digits (eight to the left plus the two decimal positions). To get the desired result and handle various decimal position situations, I suggest the following:
D Amount_A S 10 Inz('326478-')
D Amount S 9 2
D LenA C %len(Amount)
D DecA C %decpos(Amount)
/free
Amount = %dec(Amount_A:LenA+DecA:0)/10**DecA; This scheme handles the conversion by first making the length of the return value larger to accommodate the decimal positions as integers and then dividing by the correct power of 10 to provide the decimal positions desired. With this code, the Amount field becomes 3264.78-. As a reminder, the exponentiation expression 10**DecA has a higher precedence than the division function, so no parentheses are needed in the denominator.
The %int and %dec built-in functions provide data conversion from character to either integer or decimal. Try it!
Jim Martin is corporate technical instructor at Jack Henry & Associates in Monett, Missouri. He is a veteran of RPG programming, beginning in 1967 with a position at IBM as a systems engineer and later was a staff programmer at the Rochester systems programming lab. For eight years, he was at Lakeview Technology as an AS/400 and RPG instructor and was a speaker at various local midrange user group meetings and conferences. He can be reached by email at jmartin@truevine.net.
|
[size="1">Code[/size>