TechTip: RPG IV--What's Different About Programming Structures in Free-Format? PDF Print E-mail
Tips & Techniques - RPG
Written by Jim Martin   
Sunday, 15 February 2004 18:00

The arrival of free-format RPG IV in V5R1 was announced with little fanfare. I suppose IBM assumed it was just another alternative for RPG programmers. But I think IBM should have renamed the language or at least called it RPG V! With free-format, the era of "Goto" in RPG is ended. This is significant, since it forces programmers to use good procedural structures for the logic in their programs rather than the happenstance logic (sometimes called "spaghetti code") often found in programs. True, good structural code does not require free-format, but nonstructural options still abound. Free-format coding requires some thinking because many of the old, fixed-format ways of coding logic are just not available.

The fact that the Goto operation is not supported in free-format should not be a problem for most programmers, since good programming practice should have precluded its use long ago. But we all have coded--or at least seen--Goto loops, such as the following:

C         Loop          Tag
C                       Exfmt   Scrnfmt
C                       If      *In03 = *Off and *In12 = *Off
C*   Not exit and not cancel, so process data from the screen   
C                       If      Error_1
C                       Eval    *In20 = *on
C                       Goto    Loop
C                       Endif
C                       If      Error_2
C                       Eval    *In21 = *On
C                       Goto    Loop
C                       Endif
C
C* More error checking and looping back...
C*   Error messages on the screen are conditioned by *In20, *In21, etc.
   

How could the above be coded without Goto? The following is a fixed-format scheme:

C                       Dou     *In03 or *In12
C                       Exfmt   Scrnfmt
C                       If      *In03 = *Off and *In12 = *Off
C*   Not exit and not cancel, so process data from the screen  
C                       If      Error_1
C                       Eval    *In20 = *on
C                       Iter
C                       Endif
C                       If      Error_2
C                       *In21 = *On
C                       Iter
C                       Endif


Here's the free-format alternative:

/free
  Dou Exit or Cancel;             // Begin screen display and edit
    Exfmt Scrnfmt;                //   Display the screen
    If Not Exit and Not Cancel;   //   Check for F3 or F12 keys
      If Error_1;                 //   Checking for error 1 
        Scrnfield1_error = *On;   //   Set error flag indicator
        Iter;                     //   Exit remaining check section
     Endif;
      If Error_2;                 //   Checking for Error 2
        Scrnfield2_error = *On;   //   Set error flag indicator
        Iter;                     //   Exit remaining check section
      Endif;
  //
  //  More error checking here
  //
 Enddo;   
/end-free      


The free-format alternative is very much the same as a good fixed-format alternative. The only difference is that I have chosen to use named indicators from the display file instead of numbered ones. This is not required, but it sure adds a lot of clarity to the code. Don't forget to use the file-level keyword INDARA in the DDS of the display file if you choose to use a named indicator data structure. Also, when doing this, the numbered indicators in the RPG program no longer reference the display file indicators. They can only be referenced by their name. (For more information on named file indicators, check for indicator data structures in the RPG Reference manual. Look at page 133 for information and page 142 for an example.)

Other logical flow operators that are missing in free-format are DO and case (CASxx). The DO operation is easily replaced by the FOR operation. The following shows a DO group with a starting value other than one, an increment other than one, and the index option:

C         2             Do      20                  Index
C                       Eval    Array(Index) = Index;
C         Index         Chain   SubfileRec
C                       If      %found
C                       Eval    SF_Field_1 = 44
C                       Endif
C                       Enddo   2


Here's the free-format equivalent:

 /free
  For Index = 2 to 20 by 2;            // Set up a controlled loop
    Array(Index) = Index;              // Set Array element
    Chain Index SubfileRec;            // Get subfile record
    If %found;                         // If found
      SF_Field_1 = 44;                 //   Set subfile field
    Endif;
  Endfor;
 /End-free 



Case groups can easily be modified to use the Select, When, and Other operations.

The If, DOW (Do While), and DOU (Do Until) operations are still available in free-format. And the logic interrupters Iter (Iteration), Leave (leave Do or For group), and LeaveSR (leave subroutine) are an essential part of your logical structures. Also, the new operation ElseIf could be a very nice option in a program, eliminating a long string of Endifs.

Coding in free-format RPG IV is not a panacea for programmers, but it does force us into using better program structures. By using indenting, named indicators, indicator data structures for files, and line comments, program maintenance productivity and overall readability is greatly improved.

Jim Martin is the corporate technical instructor at Jack Henry & Associates in Monett, Missouri. He is a veteran of RPG programming, beginning in 1967 with a position at IBM as a systems engineer. Later, he was a staff programmer at the Rochester systems programming lab. For eight years, he was at Lakeview Technology as an AS/400 and RPG instructor and a speaker at various local midrange user group meetings and conferences. He can be reached by email at martin2638@hotmail.com.


Jim Martin
About the Author:
Jim Martin has a BS degree in mathematics and an MS in computer science. He was employed by IBM for 26 years, where he wrote RPG applications for customers and also worked in the programming laboratory as a programmer of portions of CPF and OS/400. After leaving IBM, he took post-graduate work in computer science and performed RPG training. He is an IBM-certified RPG IV developer.

 

MC Press books written by Jim Martin available now on the MC Press Bookstore.

 

Free-Format RPG IV Free-Format RPG IV
This book, a "how-to" guide and the first of its kind, will provide you with concise and thorough information on this powerful new way of coding RPG IV.

List Price $59.95
Now On Sale
 
Functions in Free-Format RPG IV

Functions in Free-Format RPG IV


The ultimate guide to writing RPG IV programs with functions in the free-format style.

List Price $59.95
Now On Sale
 
Read More >>

< Prev   Next >
Last Updated on Sunday, 15 February 2004 18:00
 
MC Press Web Site Staff
This is a discussion about [B>TechTip: RPG IV--What\'s Different About Programming Structures in Free-Format?[/b>.

Click here for the article.

avrahamn@coop.co.il
It is easier to see and analyze the code. All variables being changed are in the result filed position. The same way as elimnating the GOTO statement, You could eliminate many other bad code. In my opinion to many nested levles of if-do-else confuses. In such a case it is better to use subroutines and procedures. But to many nested short subroutines and short procedures is also confusing. So you have to be balanced. EVAL statement could be easy to understand if it is not to complex, but if You make it complex it also bad code. Example of free code that is hard to understand and follow: A=(B+C)/%ELEM(a1)* proc1(J+G:proc2(K:M)). From the other Side, 1 or 2 goto staments in a program does not make the program unreadble: Screen1 TAG EXFMT SCREEN1 IF EXIT EXSR ENDPGM ENDIF EXSR PROCESS1 IF ERROR1 GOTO SCREEN1 ENDIF SCREEN2 TAG EXFMT SCREEN2 IF PREVIOUS GOTO SCREEN1 ENDIF GOTO SCREEN2 Here You have a short program tha did not abuse neither the use of to many levels of nested DO and not to many GOTO. The logic is very similar to our thinking. The bad opinion about GOTO goes back to the days of indicators when there was no IF and DO. Now when we have those codes, we could write a nice balanced program that uses all tools that are the most appropriate.
derek_111
When you say its easier to read because all changed fields are in the result column, i think that it is easier because that is what you are used to reading. Myself, i am more used to free form, so it is much easier for me to read the other way. So, which is easier could be argued all day long, but it basically comes down to what you are used to using that makes a difference in what is easier to read for different people. One big advantage for me when i\'m reading free form is the tabbing. I can quickly see the flow of the logic by just looking at where things are tabbed. I can see the main loop because it is all the way to the left, i know that everything tabbed over is going to be executed everytime through the loop. With fixed format, i would have to count the number of endifs, and enddos and so on till i find the one that matches up with the one i want. anyways, just my opinion.
dwiesner@charter.net
I have been a proponent of using do loops instead of goto\'s for many years. Whenever someone would use the excuse that a program was small so it didn\'t matter, I always heard in the back of my mind "If you don\'t do it in the small programs, why would you start in the larger programs?" But I do agree, there must be balance. I have worked on COBOL converted from a mainframe and there are procedure calls to execute one line of code.
uptech
You can line up your code using free format. Indent the nested if\'s and do\'s. It\'s easy and it\'s great! And you get back all that "white space" on the left "formerly" occupied by the total-time indicators, the indicatora, factor 1, plus!
buck.calabro@commsoft.net
> When some problem arise, I like to be able to see which > lines I have changed the last time I (or someone else) > changed the program. Before I would look at the date > part of the source in SEU to identify those lines. How does one find lines that were deleted by looking at the source date? Please don\'t tell me that you comment them out and leave them in the code. I have had to work in such a shop and I would rather slash my wrists with a rusty tuna can lid than do that again. Far better is to use a change management package to show the changes between versions. --buck
kaj@maxjenne.dk
In general I like the /free format RPG that allows me to indent my code, thereby making the code more readable. However I have also discovered something that has made me a bit reluctant to use it. When some problem arise, I like to be able to see which lines I have changed the last time I (or someone else) changed the program. Before I would look at the date part of the source in SEU to identify those lines. But because every block of code that has to be shifted, either to the right or to the left also changes the date, I can no longer use this information to identify when a change last occured. [i> In my oppinion IBM has to change this behavior of SEU as soon as possible.[/i>
cramer@multi-support.dk
I don\'t think there is much difference in using goto or iter (or leave). Iter (and leave) opcodes are also goto statements. Iter means go to the beginning of the loop (leave means go to the first statement after the loop ie enddo). I would prefer to use the example given without any Iter (and leave) opcode. It can be done - I use the select statement insted of repetetive if blocks with the Iter opcode. Or, if as in the example you only whants to set a display format indicater you could use the following: Eval *in20 = Error_1 Eval *in21 = Error_2 or Eval *in20 = (Error_1 = \'1\') or something similar. This is a direct way to compute the indicator value (leaving a lot of code behind). But don\'t create a too complex eval statement (as the example in an earlier reply) without good commenting the statement.
ACT
With Free format RPG should be renamed to PL/I. My two cents.
avrahamn@coop.co.il
But in CL, if there is a big CL program, with some logic in it, it is hard to follow. I agree tha the result indicators need to be taken away, and the same also L and detail indicators. But the RPG Cycle, when it comes to control Breaks, there is no alternative to it.
Please login to make comments.
User Rating: / 0
PoorBest 

TRIAL SOFTWARE

The following trial software can be found at the MC Press Software Center.

 

WEBCAST

The following webcasts can be found on the MC Webcast Center.

 

WHITE PAPERS

The following White Papers can be found at the MC White Paper Center

 

 
   MC-STORE.COM