You probably use, or have seen, the Initial program to call (INLPGM) parameter on user profiles. The INLPGM runs in interactive jobs under the control of the QSYS/QCMD routing entry program. But have you ever needed to call an exit point program before the INLPGM? Do you need an INLPGM in batch jobs, or a Last program to call (LASTPGM) parameter?

For these sorts of jobs, you need a custom program at the top of the call stack. Have you ever wondered how you can call a program that runs at call stack level one?

Routing data is the key to starting a program at the top of the call stack. Request data is the set of messages that feeds the top-most program when it runs. With routing and request data, you can replace the top-level QCMD with a custom program that you design, which means you can do all sorts of wild and wonderful things.

I’ve been using routing and request data for several years to link together applications from different vendors for my users. I do the following from a top-of-call-stack program:
• Create file member overrides at the OVRSCOPE(*JOB) level
• Transfer the user to an appropriate subsystem for an application
• Initialize group jobs with a common attention key/menu bar program
• Archive user time and accounting statistics to an audit log
• Change library lists and job attributes according to user authority levels
• Set device recovery action according to location: local or remote
• Scan for command labels in request messages to condition certain actions
• Suppress propagation of adopted user profile authorities Routing Around Routing data is an 80-byte job attribute. Interactive and batch jobs get initial routing data from the job description object. Communication jobs get initial routing data from a substring of the program start request. Prestart jobs do not use routing data.

Your first step in using routing data is to use one of the seven commands with a Routing data (RTGDTA) parameter: Create Job Description (CRTJOBD), Change Job Description (CHGJOBD), Submit Job (SBMJOB), Batch Job (BCHJOB), Reroute Job

(RRTJOB), Transfer Job (TFRJOB), or Transfer Batch Job (TFRBCHJOB). The commands in Figure 1 show how routing data is prepared for a job.

A batch job also can get initial routing data from the SBMJOB or BCHJOB command by way of its job description if the RTGDTA parameter is *JOBD. While running, a job can dynamically change its own routing data with RRTJOB, TFRJOB, and TFRBCHJOB.

Your next step in using routing data is to modify a subsystem description table of routing entries. Here is where you link the name of a program to a routing data comparison value. Use Add Routing Entry (ADDRTGE) and Change Routing Entry (CHGRTGE) to maintain this table. The command examples in Figure 2 create three routing entries with sequence numbers 10, 15, and 9999 in a subsystem description named PIANO.

During key moments in the life of a job, OS/400 searches the routing entry table in sequence number order for a comparison value equal to the job’s current routing data. When it finds a match, OS/400 transfers control to the program named in the routing entry. That program then runs at call stack level one.

Figure 2 provides an example. If a job’s routing data is MIDRANGERS, program APP/PAY001 runs. Routing data MIDRANG runs GENELIB/TEST, however, because the routing data does not match the complete routing data in entry 10. Routing data of “MID” runs QSYS/QCMD, because “MID” does not match the first two routing entries.

Remember the inverted pyramid rule when you add routing entries. Comparison values must be ordered from the most specific case down to the most general case. Don’t worry; ADDRTGE and CHGRTGE will give you a warning message if you don’t get this right.

To test the search rules for routing entries without invoking any routing entry programs, I wrote a command called Display Routing Data (DSPRTGDTA). It uses a REXX command processing program, RTG001RX, and takes one parameter, which is a subsystem description name. You can download my utility from MC’s Web site at www.midrangecomputing.com/mc/99/03.

The command displays the SEQNBR, PGM, and CMPVAL columns from the subsystem description routing table. Then, it prompts you to type some test routing data. (The REXX prompter is case sensitive, so you may need to hold down the Shift key as you type.) Press the Enter key, and the name of the program that matches your routing data appears. Continue typing and testing more routing data. To exit, type nothing, and press the Enter key twice. (REXX fans may recognize that the ABBREV(rtgdta,cmpval) function is the equivalent OS/400 search rule for routing entries.)

OS/400 maintains an internal count of routing steps for each job. OS/400 increments a job’s routing step count whenever OS/400 searches the routing table. The following events in a job will trigger a routing entry search:

• The job begins to run.
• The job executes a RRTJOB, TFRJOB, or TFRBCHJOB command.
• The job is interactive and the top-most program executes a RETURN. Note that the RETURN event means OS/400 handles interactive jobs as infinite loops. OS/400 repeatedly calls an interactive job’s routing entry program in an infinite loop until one of the following occurs:

• The job executes a SIGNOFF command.
• An event in another job cancels this job; e.g., QINACTITV expired.
• The total number of active jobs through this routing entry exceeds the Maximum active routing steps (MAXACT) parameter in the routing entry.

• A routing step ends, and the severity level of an unhandled escape message in its program message queue is equal to or greater than the job’s End severity (ENDSEV) attribute that was set in the *JOBD object or BCHJOB command when the job was initiated.

Request and You Shall Receive

After you get a program running at the top of the call stack, it can do anything you want. In theory, you can have as many routing entry programs as you have tasks to accomplish on AS/400. However, you’ll probably want to pass some controlling information to the program and thereby limit the number of routing entry programs. Routing entry programs cannot receive external parameters (e.g., *ENTRY PLIST in RPG receives zero parameters). Instead, you can send request data to the program.

You prepare request data by executing a command with a Request data (RQSDTA) parameter. Guess what? The seven commands that have a RTGDTA parameter also have a RQSDTA parameter. The command examples in Figure 3 prepare request data for a job.

When a job or secondary routing step starts, OS/400 writes the associated RQSDTA to a request message on the job’s external message queue. The routing entry program can then execute Receive Message (RCVMSG) or call the Receive Program Message (QMHRCVPM) API to fetch that request message. How it interprets the request message depends on its context. QCMD, for example, treats request messages as CL commands and sends them through an equivalent of QSYS/QCMDEXC, the command executor.

Figure 4 shows a prototype routing entry program that duplicates every function of QCMD. Notice the program first receives a request message and sends it through QCMDEXC. If the job is interactive, the job reads the user profile and sets the attention key program, calls the INLPGM, and runs the Initial menu INLMNU. The program relies on OS/400 to call it in an infinite loop. If the program executes the RETURN at the bottom, OS/400 again will write the RQSDTA from the *JOBD to another request message and then reinvoke the program from the top as a secondary routing step. You can clone the program shown in Figure 4 to start your own routing entry program and add or delete things as needed.

Remember, request messages don’t have to be CL commands. This gives you some interesting flexibility because the routing program can read any sort of meaning into request messages and act upon them accordingly.

Error Handling If you add a global Monitor Message (MONMSG) command to trap unhandled escape messages, keep in mind this program runs at the top of the call stack. That means the common “forward unhandled program messages to prior message queue” technique will not work here. Think carefully about how you want to handle error conditions at call stack level one. Should the program restart itself? Should the program notify the user of an abnormal condition, print the job log, and end? If the job is batch, should the job queue “hang” until the system operator responds to a message at the system console? Although there are probably as many error handling techniques and proclivities as there are AS/400 programmers, here are some points to consider with errors in routing entry programs.

OS/400 assigns a job ending code at job termination. A job’s final job log message, CPF1164, contains the job-ending code in positions 50 through 51 of the message data. These codes and their meanings are shown in Figure 5.

OS/400 automatically sends CPF1241, “Job completed normally,” or CPF1240, “Job ended abnormally,” to the message queue named in the MSGQ parameter on the SBMJOB command after a batch job ends. If the job ending code is 10 or less, a CPF1241 (normal) is sent. But, if the job ending code is 20 or greater, a CPF1240 (abnormal) is sent, and the job log automatically prints.

The point where job termination crosses the line from normal to abnormal is an arbitrary, human decision. A routing entry program can arbitrate that threshold by ending a routing step such that an unhandled escape message exists in its program message queue with a severity level equal to or greater than the End severity (ENDSEV) attribute that was set in the *JOBD object or BCHJOB command when the job was initiated. The key point here is that this escape message must be left unhandled.

Simply adding a global MONMSG to a routing entry program will handle escape messages and thus create a job ending code 0, but that may not be enough to report a

condition you feel is abnormal. To create a job ending code 20 and thereby trigger a CPF1240 (abnormal) message from OS/400, the routing entry program must send another escape message explicitly to itself with a severity level equal to or greater than the job’s ENDSEV attribute, and then not handle it. That’s not possible in CL because the new escape message would retrigger the global MONMSG and thereby mark the new message as handled. If you’re really serious about monitoring for messages in a routing entry program, your best bet is to use a language that can dynamically turn off message monitors before sending yourself a new escape message.

Message severity levels range from 0 to 99. The default for the ENDSEV parameter on the CRTJOBD command is 30. If a non-CL routing entry program sends itself an escape message with severity level 40 and doesn’t handle it and if it runs in a job created with ENDSEV of level 30, then the combination will set a job ending code of 20 and trigger an automatic CPF2140 (abnormal) message from OS/400 after job termination. (Got that?)

Try not to confuse job ending codes with message severity levels; they are separate numbering systems. Also, the job ending codes are not related to the Message logging (LOG) parameter on CRTJOBD, CHGJOBD, SBMJOB, and BCHJOB. The LOG parameter affects only how the job log prints, not the job ending code.

A Real-world Example I support an application that uses a lot of multimember physical and logical files. The application reviews medical bills for Auto No-Fault and Workers’ Compensation claims. Because laws and reimbursement rules are different between U.S. states, we keep the states separate, and the member names are the two-letter abbreviations used by the U.S. Postal Service. Rather than code CL “wrapper” programs that issue Override with Data Base File (OVRDBF) before each program, the application uses a routing entry program to put out all possible overrides at once. All subsequent programs run under this routing entry and thus open the correct members. This eliminates the hassle of continually updating CL “wrappers” as new files are added.

Users work in a particular U.S. state by selecting a menu option that executes a Reroute Job (RRTJOB) command containing request data specifying the desired U.S. state abbreviation. RRTJOB gives the application a tabula rasa because it closes all files, reclaims all named activation groups and heap storage, removes all overrides and commitment control, and triggers a new search down the routing table to launch a new routing entry program. RRTJOB does not change the library list or any QTEMP objects. Figure 6 shows an abbreviated routing entry program in this application that parses the desired U.S. state abbreviation out of a command label, then issues the overrides. Figure 7 is an example of how the application can run a program named REVIEW such that files will open to the MI (Michigan) dataset.

Go the Route Routing entry programs and request data give you considerable flexibility when designing an application. For more information on this subject, see OS/400 Work Management (SC41-5306-02, CD-ROM QB3ALG02).

CRTJOBD JOBD(MYJOBD) RTGDTA('INVOICE')
SBMJOB CMD(CALL MYPGM) RTGDTA('TICKETS')

Figure 1: Here are some examples of routing data.

ADDRTGE SBSD(PIANO) SEQNBR(10) CMPVAL('MIDRANGE' 1) PGM(APP/PAY001)
ADDRTGE SBSD(PIANO) SEQNBR(15) CMPVAL('MIDR' 1) PGM(GENELIB/TEST)
ADDRTGE SBSD(PIANO) SEQNBR(9999) CMPVAL(*ANY) PGM(QSYS/QCMD)

Figure 2: This is how you create routing entries in a subsystem.

CRTJOBD JOBD(MYJOBD) RQSDTA('WRKSPLF SELECT(*CURRENT *ALL INVOICE)')
RRTJOB RQSDTA('DSPJOB OPTION(*STSA)')
SBMJOB CMD(CALL MYPGM) RQSDTA(*CMD)

Figure 3: Here are some ways to pass request data to a job.

/******************************************************************************/

/* Prototype Routing Entry Program */
/******************************************************************************/

PGM
DCL &OBJ *CHAR 10
DCL &LIB *CHAR 10
DCL &MSG *CHAR 6000
DCL &TYPE *CHAR 1

/* process any request data */
RCVMSG PGMQ(*EXT) MSGTYPE(*RQS) RMV(*NO) MSG(&MSG)
CALL QCMDEXC (&MSG 6000)

/* if batch job, return */
RTVJOBA TYPE(&TYPE)
IF (&TYPE *EQ '0') RETURN

/* set the attention key program */
RTVUSRPRF ATNPGM(&OBJ) ATNPGMLIB(&LIB)
IF (&OBJ *NE '*NONE') (SETATNPGM &LIB/&OBJ)

/* call the initial program */
RTVUSRPRF INLPGM(&OBJ) INLPGMLIB(&LIB)
IF (&OBJ *NE '*NONE') (CALL &LIB/&OBJ)

/* run the initial menu */
RTVUSRPRF INLMNU(&OBJ) INLMNULIB(&LIB)
IF (&OBJ *EQ '*SIGNOFF') SIGNOFF
GO &LIB/&OBJ

/* trigger a new routing step */
RETURN
ENDPGM

Figure 4: Here’s a prototype routing entry program.

Code Meaning

0 The job completed normally. 10 The job completed normally during controlled ending. 20 The job exceeded end severity (ENDSEV) job attribute. 30 The job ended abnormally.
40 The job ended before becoming active.
50 The job ended while the job was active.
60 The subsystem ended abnormally while the job was active. 70 The system ended abnormally while the job was active.
80 The job ended (ENDJOBABN command).
90 The job was forced to end after time limit (ENDJOBABN com-

Figure 5: This is a list of job-ending codes.

PGM
DCL &MSG *CHAR 6000
DCL &MBR *CHAR 10

/* extract U.S. state abbreviation from command label */

RCVMSG PGMQ(*EXT) MSGTYPE(*RQS) RMV(*NO) MSG(&MSG)
IF (%SST(&MSG 3 1) = ':') (CHGVAR &MBR (%SST(&MSG 1 2)))
IF (&MBR *NE 'AL' + *AND &MBR *NE 'AK' +

/* etc.*/+

*AND &MBR *NE 'WV' ) (SNDPGMMSG MSGID(CPF9898) MSGF(QCPFMSG) +

MSGDTA('Invalid U.S. state abbreviation') +

TOPGMQ(*SAME) MSGTYPE(*ESCAPE))

/* process the request */

OVRDBF CLAIMS MBR(&MBR) OVRSCOPE(*JOB)
OVRDBF DIAGNOSES MBR(&MBR) OVRSCOPE(*JOB)
OVRDBF DRUGS MBR(&MBR) OVRSCOPE(*JOB)
OVRDBF HOSPITALS MBR(&MBR) OVRSCOPE(*JOB)
OVRDBF INVOICE MBR(&MBR) OVRSCOPE(*JOB)
OVRDBF PROVIDERS MBR(&MBR) OVRSCOPE(*JOB)
CALL QCMDEXC (&MSG 6000)

ENDPGM

Figure 6: The SURGICAL routing entry program runs a CL command under database overrides.

SBMJOB CMD(MI: CALL PGM(REVIEW) PARM('12/25/1998' 'Y')) RTGDTA('SURGICAL')

Figure 7: The application submits program REVIEW to run under the MI (Michigan) overrides.

Also Read

Practical Middleware: Starting the Journey

IBM i 7.2: The Carrot Versus the Stick

A Renaissance for Domino