Tips and Techniques: Converting Time

APIs
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

In the feature story in this issue ("When Was I Born?"), the RTVSBMJOBA command took advantage of the QWCCVTDT API. If you have character text that is used as a date value, this API allows you to convert it from one date format to another. The API will also retrieve the current system date and time for you.

The QWCCVTDT API is a program (not a procedure call), but it seems to run fairly fast. To use it, you need to prototype it, convert your date values into character format without embedded date separators, and pass the API your date and the format in which it is stored.

Here is the prototype for the QWCCVTDT API:

D QWCCVTDT        PR                  ExtPgm('QWCCVTDT')
D  inFmt                        10A   Const OPTIONS(*VARSIZE)
D  inDate                       64A   Const OPTIONS(*VARSIZE)
D  outFmt                       10A   Const OPTIONS(*VARSIZE) 
D  outDate                      64A         OPTIONS(*VARSIZE)
 /IF DEFINED(*V5R1M0)
D  api_error                          LikeDS(QUSEC)
 /ELSE
D  api_error                          Like(QUSEC)
D/ENDIF

The following illustrates how to call the QWCCVTDT API.

D FromDate        DS                  LikeDS(CvtDT17_T)
D ToDate          DS                  LikeDS(CvtDT16_T)
D Today           S               D   Inz(*SYS)
D JobDate         S              6S 0
     
C                   eval      FromDate.szDate17_cvt = %char(Today:*ISO0)
C                   
C                   callp     QwcCvtDT('*YYMD':FromDate:'*JOB':ToDate)
C                   eval      JobDate = %Int(ToDate.szDate16_cvt)

In this example, the system date is automatically stored in the field named TODAY. That date is converted to character and copied into the szDate17_cvt subfield. Then, the date is converted to the job's date format by QWCCVTDT and copied into the JOBDATE field. This is an obviously contrived example that ends up with JOBDATE containing effectively the same value as UDATE, with one exception. UDATE is static and never changes, whereas the INZ(*SYS) on the TODAY field causes the current system clock date to be used.

The input date and return date parameters have a special format that includes the time down to the milliseconds. The data structures for the two classes of date format are as follows:

 **********************************************************
 **  Data structure of the data input to and returned from 
 **  the QWCCVTDT API. This 16-byte structure is use for
 **  date formats: *JOB *SYSVAL *YMD *MDY *DMY and *JUL
 **********************************************************
D CvtDT16_T       DS
D  nCent16_cvt                   1A
D  szDate16_cvt                  6A
D  szTime16_cvt                  6A
D  szMS16_cvt                    3A

 **********************************************************
 **  Data structure of the data input to and returned from 
 **  the QWCCVTDT API. This 17-byte structure is use for
 **  date formats: *YYMD *MDYY *DMYY and *LONGJUL
 **********************************************************
D CvtDT17_T       DS
D  szDate17_cvt                  8A
D  szTime17_cvt                  6A
D  szMS17_cvt                    3A

The date is the only thing that is variable in these two data structures. The szTime16_cvt and szTime17_cvt subfields always contain the time in HHMMSS format, using a 24-hour clock.

QWCCVTDT is a simple, yet useful API to convert dates from one format to another. While the API requires character parameters, your implementation could define the date subfields in the two data structures as numeric.

Bob Cozzi is a programmer/consultant, writer/author, and software developer. His popular RPG xTools add-on subprocedure library for RPG IV is fast becoming a standard with RPG developers. His book The Modern RPG Language has been the most widely used RPG programming book for more than a decade. He, along with others, speaks at and produces the highly popular RPG World conference for RPG programmers.

In the feature story in this issue ("When Was I Born?"), the RTVSBMJOBA command took advantage of the QWCCVTDT API. If you have character text that is used as a date value, this API allows you to convert it from one date format to another. The API will also retrieve the current system date and time for you.

The QWCCVTDT API is a program (not a procedure call), but it seems to run fairly fast. To use it, you need to prototype it, convert your date values into character format without embedded date separators, and pass the API your date and the format in which it is stored.

Here is the prototype for the QWCCVTDT API:

D QWCCVTDT        PR                  ExtPgm('QWCCVTDT')
D  inFmt                        10A   Const OPTIONS(*VARSIZE)
D  inDate                       64A   Const OPTIONS(*VARSIZE)
D  outFmt                       10A   Const OPTIONS(*VARSIZE) 
D  outDate                      64A         OPTIONS(*VARSIZE)
 /IF DEFINED(*V5R1M0)
D  api_error                          LikeDS(QUSEC)
 /ELSE
D  api_error                          Like(QUSEC)
D/ENDIF

The following illustrates how to call the QWCCVTDT API.

D FromDate        DS                  LikeDS(CvtDT17_T)
D ToDate          DS                  LikeDS(CvtDT16_T)
D Today           S               D   Inz(*SYS)
D JobDate         S              6S 0
     
C                   eval      FromDate.szDate17_cvt = %char(Today:*ISO0)
C                   
C                   callp     QwcCvtDT('*YYMD':FromDate:'*JOB':ToDate)
C                   eval      JobDate = %Int(ToDate.szDate16_cvt)

In this example, the system date is automatically stored in the field named TODAY. That date is converted to character and copied into the szDate17_cvt subfield. Then, the date is converted to the job's date format by QWCCVTDT and copied into the JOBDATE field. This is an obviously contrived example that ends up with JOBDATE containing effectively the same value as UDATE, with one exception. UDATE is static and never changes, whereas the INZ(*SYS) on the TODAY field causes the current system clock date to be used.

The input date and return date parameters have a special format that includes the time down to the milliseconds. The data structures for the two classes of date format are as follows:

 **********************************************************
 **  Data structure of the data input to and returned from 
 **  the QWCCVTDT API. This 16-byte structure is use for
 **  date formats: *JOB *SYSVAL *YMD *MDY *DMY and *JUL
 **********************************************************
D CvtDT16_T       DS
D  nCent16_cvt                   1A
D  szDate16_cvt                  6A
D  szTime16_cvt                  6A
D  szMS16_cvt                    3A

 **********************************************************
 **  Data structure of the data input to and returned from 
 **  the QWCCVTDT API. This 17-byte structure is use for
 **  date formats: *YYMD *MDYY *DMYY and *LONGJUL
 **********************************************************
D CvtDT17_T       DS
D  szDate17_cvt                  8A
D  szTime17_cvt                  6A
D  szMS17_cvt                    3A

The date is the only thing that is variable in these two data structures. The szTime16_cvt and szTime17_cvt subfields always contain the time in HHMMSS format, using a 24-hour clock.

QWCCVTDT is a simple, yet useful API to convert dates from one format to another. While the API requires character parameters, your implementation could define the date subfields in the two data structures as numeric.

Bob Cozzi is a programmer/consultant, writer/author, and software developer. His popular RPG xTools add-on subprocedure library for RPG IV is fast becoming a standard with RPG developers. His book The Modern RPG Language has been the most widely used RPG programming book for more than a decade. He, along with others, speaks at and produces the highly popular RPG World conference for RPG programmers.

BLOG COMMENTS POWERED BY DISQUS