If you have ever tried to use the batch language of Windows and found it wanting, Windows Script Host (WSH) is your dream come true. Microsoft has taken the functionality of its scripting languages and put it directly into its Windows operating system. This means that you can now write script files that access the operating system and its services as objects, just as you can write macros in Microsoft Word or Excel to control a document or spreadsheet. Using WSH is like using CL on your AS/400; it’s a powerful tool for automating user logins, writing programs to move data, and performing other system administration tasks.

WSH Can Do a Whole Lot!

If you have ever written a Word or an Excel macro, programmed in Access or Visual Basic (VB), or used Active Server Pages (ASP), you are already familiar with what WSH code looks like. WSH can run VBScript or JScript right out of the box, and several third-party vendors sell packages that support Perl, REXX, and other languages inside WSH. WSH can be downloaded from the Web for the Windows 9x and NT 4.0 platforms and will ship standard in Windows 2000.

WSH is basically an interpreter that allows access to operating-system components and programs via the ActiveX object model (i.e., Microsoft’s Component Object Model, or COM, architecture). WSH is based on the ActiveX Scripting Model used in Microsoft Internet Explorer and Internet Information Server (IIS), but WSH has a much smaller memory footprint than those engines.

A WSH script can create an instance of any ActiveX object, set and interrogate object properties, and invoke object methods. Because Microsoft represents most operating-system interfaces as ActiveX objects, a WSH script can map networked drives, work with user accounts and the system registry, connect and change printers, manipulate the file system, and perform other system functions. Since WSH is based on ActiveX, all ActiveX controls or objects are accessible to WSH, allowing it to interact with the AS/400 via ODBC, OLE DB, or the ActiveX controls that come with Client Access. Finally, since most programs that execute under the Windows environment export their internal methods and properties via the ActiveX interface, WSH can also be used to control those programs.

Scripts: The Mechanics of WSH

WSH provides two engines for running a script: the WSCRIPT.EXE and CSCRIPT.EXE programs. You can use WSCRIPT.EXE for executing scripts in the Windows GUI; CSCRIPT.EXE executes scripts from a DOS command prompt window. Within Windows, you can use Windows Explorer to double-click a script file, or you can click Start/Run... and type the name of a script file into the command prompt. From a DOS window, you can run a script by typing CSCRIPT and pressing Enter; is the fully qualified path and file name of the script to run; and are any parameters you wish to apply to the script. See the WSH documentation for more information about the command line options of CSCRIPT or type CSCRIPT /? at the DOS command line.

A script is just another file, as far as the operating system is concerned. The file extension lets WSH know which language the script is written in. WSH comes with the ability to run VBScript or JScript. VBScript scripts have a filename extension of .vbs, while JScript scripts use the .js extension. WSH also has some built-in objects, methods, and properties that are accessible to a running script. Here’s a brief overview of the two most useful objects: the Shell and Network objects.

The Shell Object

The Shell object allows WSH to interact with the Windows environment. The object contains methods for working with registry settings and environment variables, running commands and programs, and changing or viewing the SpecialFolders object. Following are the objects, methods, and collection that are most valuable when working with the Shell object.

• The SpecialFolders object allows a script to access the Windows Start menu and the desktop and personal folders. Using this object, you can create menu entries, desktop icons, folders, or shortcuts to programs and files.

• The Run method allows you to execute Windows commands and programs. It can return the status of the executed command and control the type of window that the command runs in. You can also specify whether control returns to the script after the command finishes executing or as soon as the command is executed.

• The Arguments collection allows a script to access any command-line parameters issued when the script is started. This is useful for including commands whose processing is dependent on user input.

• The Environment object contains properties and methods that let you interact with the user’s computer so you can access things like the operating system and version number, the type and number of processors, the user’s home drive, and the System Path statement.

The Shell object also contains a pop-up method that can be very useful for communicating with the user. This method allows you to display pop-up messages that have complete control over the choice buttons displayed to the user. The pop-up method can return whichever button a user presses or user input variables to the script, so it is very useful for decision points in a script.

The Network Object

The Network object contains methods and properties for interacting with the network to which the computer is connected. You can use the Network object to map a networked drive, add or remove a printer in the user’s printer collection, find out what domain the user is operating in, or set the user’s default printer.

What Can WSH Do for Me?

At this point, you may be asking what good WSH is to your organization. One of the most prevalent uses of WSH is the coding of user login scripts in the Windows environment.

Although you can program a batch file to execute when a user logs in to a Windows system, WSH gives you programmatic access to the operating system and network environments.

Another use of WSH is automating routine commands or processes that you have to perform at your organization. One of my favorite scripts is the example in this article. It is a script that automates the creation of new user accounts on both Windows NT 4.0 servers and the AS/400 at my company.

Downloading and Installing WSH

Since WSH does not come with Windows 9x or NT, you need to go to Microsoft’s Web site and download the required files to run WSH. My sample script uses ActiveX Data Objects (ADO), Active Directory Services, and WSH. The following is a list of URLs for getting the required elements to download and install WSH on your system:

• Go to www.microsoft.com/msdownload/vbscript/scripting.asp to get the WSH components.

• Go to www.microsoft.com/ntserver/nts/downloads/other/ADSI25/ default.asp to get Active Directory Services Interface (ADSI). (Although this Web address specifies the Windows NT server, this download also installs ADSI object on Windows 9x machines.)

• Go to www.microsoft.com/data/download.htm to get ADO via Microsoft Data Access Components (MDAC). (If you already have ADO installed on your system, you do not need to download the MDAC elements.)

A WSH Script for Windows NT-AS/400 Maintenance

When a new user account is created at my company, I must create an NT home directory for the user, an AS/400 login, and an NT user account. To facilitate this process, I have created the script shown in Figure 1 to automate these functions for me.

The script needs two pieces of information in order to run: the user ID created and the full name of the user. This information is gathered by making a call to the InputBox function. At this point, the script adds a new Windows NT user to the specified domain.

I’ll leave you to review the Windows NT user and home directory creation parts of the code on your own, but let’s take a minute to discuss how this script automates the process of adding a new AS/400 user.

The script initiates a call to the AS/400 via ADO in order to issue the Create User Profile (CRTUSRPRF) command. The OPEN method of the ADOCON object initiates a connection with the AS/400 using QSECOFR so I have authority to issue a CRTUSRPRF command. In my script, I am relying on an OLE DB connection using the TCP/IP host name of my AS/400. Anyone’s OLE DB provider can be used. For the purposes of this article, I tested with the IBM OLE DB provider that comes with Client Access Express for Windows.

The only interesting thing to note about the CRTUSRPRF command is that you must provide the library and name of the default job description because the QCMDEXC program does not have access to the complete library list when running from a remote connection. After the Execute method is run against the ADOCMD object, the user profile is created. At this point, the script creates a message box to let the user know that the process is complete.

Scripting Your World

For more information about WSH and script programming, visit the following URLs:

• Go to wsh.glazier.co.nz for login script examples.
• Go to www.microsoft.com/scripting for WSH information.
• Go to cwashington.netreach.net for more than 300 script examples. I have found WSH invaluable in the support of my Windows desktops. If you spend some time experimenting with it, you will probably find it invaluable, too. Play

around with the Network object to get a feel for how you can control your users’ world, and don’t forget that ADO and Client Access objects allow your scripts access to the AS/400. Scripting can definitely save you time, and I think it is well worth the small amount of time you spend learning it. Script on, dude!

'Get the user name and user id
UserName = InputBox("Enter the full name of the user")
UserID = InputBox("Enter the User ID")
'now lets get an NT ADSI container
Set Container = GetObject("WinNT://HOWARD")
'Now we create a user account object for UserID
Set NewUser = Container.Create("user", UserID)
'Set the full name of the user
NewUser.FullName = UserName
NewUser.SetInfo
'create a home directory path
DirP = "howardcdrvusers"" & UserID
'create an instance of the shell object and then create a directory
'with the md command
Set WshShell = Wscript.CreateObject("Wscript.Shell")
'Run the command, 6 makes a minimized window
'true indicates to wait for command to finish
WshShell.Run "command.com /C md " & DirP ,6,TRUE
'Set the homedirectory property of the user
'to the newly created directory
NewUser.HomeDirectory=DirP
'write the user account object to the nt active directory
'set the users password
NewUser.SetPassword(UserID)
'make ado objects to connect to 400
Set ADOCON = wscript.createobject("ADODB.Connection")
Set ADOCMD = wscript.createobject("ADODB.Command")
'log into AS400 via OLEDB with a profile that has QSECOFR authority
CONSTR="Provider=IBMDA400;Password=HOWARD;"
CONSTR=CONSTR & "User ID=SECRET;Data sOurce=S10367AM"
ADOCON.open CONSTR
ADOCMD.ActiveConnection=ADOCON
'construct a string of the crtusrprf command
CRTUPT = "crtusrprf usrprf(" & UserID & ") password(" & UserID & ") "
CRTUPT=CRTUPT & "astlvl(*basic) JOBD(qgpl/qdftjobd) "
CRTUPT=CRTUPT & "pwdexpitv(45) lmtdevssn(*yes)"
'put the string in nice AS400 format for calling via ODBC
ADOCMD.CommandText = mkruncmd(CRTUPT)
'execute the command to create the user profile
ADOCMD.Execute
MSGBOX "USER: " & UserID & " ACCOUNT CREATED!"

Function MkRunCmd(CmdToRun)
'A simple dodge to make the properly formated call to QCMDEXC
'Get the length of the passed in string
StringLen = Len(CmdToRun)
'Get the number of spaces that the length of StringLen will take
DisplayLen = Len(CStr(StringLen))
'Make the decimal number fo the command length as a string
DecimalLen = Mid("0000000000", 1, 10 - DisplayLen) & CStr(StringLen) & ".00000"
MkRunCmd = "CALL QSYS.QCMDEXC('" & CmdToRun & "'," & DecimalLen & ")"
End Function

Figure 1: This script creates a user account on Windows NT and on my AS/400.

Also Read

The API Corner: Moving Jobs Within and Across Job Queues

The API Corner: What Time Zone Do You Want That Date and Time In?

The API Corner: How Do You Want That Date and Time?