Something as trivial as changing the case (from lowercase to UPPERCASE, for instance) of a string can be a challenge in RPG, because unlike SQL (and MS Excel), RPG doesn't have a change case function. So let's build one, using yet another BIF: %XLATE.

Changing the case of a string in MS Excel is easy; as far as I know, there are three functions to do this: UPPER, LOWER, and PROPER. This TechTip will cover the first two, and I'll discuss the third on the next TechTip. If you haven't used them, here's a quick recap: UPPER and LOWER, as their names imply, change all the string's characters to uppercase and lowercase, respectively. These are handy functions that don't exist in RPG; UPPER and LOWER exist in SQL, though. We're going to build them, just like we built LEFT and RIGHT in the previous TechTip, and we'll build an additional one, Sentence case, which turns the first character of the string to uppercase and all the others to lowercase, just for the fun of it. I discussed %SCAN and %REPLACE in an earlier TechTip, but those are not good solutions for this problem, because %SCAN requires an exact match. However, there's another op-code-turned-function that does the trick: %XLATE

Just %XLATE It

Similar to its op code counterpart, %XLATE uses two lists of characters, referred to as the "from" and the "to" arguments, to translate a string. In this case, we're going to translate the lowercase characters to uppercase and vice versa. If we follow Excel's example, then we need three options: Upper, Lower, and Sentence. However, we're not going to create three functions this time: I'm going to demonstrate a different way to approach this problem. The function we're about to create, Chg_Case, will have two parameters: the string and the "destination case." This type of solution, concentrating functionality in a single function instead of separating it into several functions, may be, in certain situations, preferable. I usually prefer to have an RPG function performing one function, but there are always exceptions. This is a way to implement the functionality concentration (three-in-one in this particular case).

The Chg_Case Function

Anyway, enough talk. Let's get down to business! Here, I'm going to follow the same three-task approach from the previous TechTip. So, without further ado, here's the function header and task 1:

*------------------------------------------------------------------------*

*   Chg_Case (Returns the input string in the case indicated in 2nd parm)*

*------------------------------------------------------------------------*

P Chg_Case       B                  Export                              

D Chg_Case       PI         32767A   VARYING                            

* Input parameters                                                      

D P_String                 32767A   OPTIONS(*VARSIZE)                  

D                                     CONST                              

D P_Case                       1A   CONST                              

* Work variables                                                        

D W_String       S         32767A   VARYING INZ(*Blanks)                

D W_TempStr     S         32767A   VARYING INZ(*Blanks)                

D W_Return       S         32767A   VARYING INZ(*Blanks)                

D W_Pos         S             5P 0 INZ(*Zeros)                        

D W_OldPos       S             5P 0 INZ(*Zeros)                        

* Constants for %XLATE                                                  

D UC             C                   'ABCDEFGHIJKLMNOPQRSTUVWXYZ'        

D lc             C                   'abcdefghijklmnopqrstuvwxyz'        

* Check input parms                                                

* P_String                                                          

C                   IF       P_String = ''                          

C                   RETURN   P_String                              

C                   ENDIF                                            

* "Clean" P_String because of OPTIONS(*VARSIZE)                    

C                   EVAL     W_String = %SUBST(P_String : 1 :      

C                                              %LEN(%TRIM(P_String)))

* P_Case                                                        

C                   IF       P_Case = ''  

C                            AND P_Case <> 'U'

C                             AND P_Case <> 'L'

C                             AND P_Case <> 'S'

C                   RETURN   P_String                                  

C                   ENDIF                                                

While there are some similarities to the LEFT and RIGHT functions from the previous TechTip, there are some new things here: notice the two constants "UC" and "lc." These are going to be used in the "from" and "to" parameters of %XLATE to perform our change case operations. In order to prepare this function to translate special characters, such as "Ã" and "ä", for instance, be sure to add them to the UC and lc constants in the respective upper or lower cases. Then notice the P_Case validation: since P_Case accepts a predefined set of values, that's being checked also.

Task 2 doesn't really exist here. There's no need for additional information, so the code continues with Task 3, which changes according to the P_Case parameter. While translating the string to uppercase or lowercase are simple operations, as you can see from the code below, the Sentence case is slightly different. Let's start with Upper and Lower:

* If the input parms are ok, process                            

* Perform the appropriate change case operation                  

C                   SELECT                                        

* UPPER CASE                                                    

C                   WHEN     P_Case = 'U'                        

C                   EVAL     W_Return = %XLATE(lc : UC : W_String)

* lower case                                                    

C                   WHEN     P_Case = 'L'                        

C                   EVAL     W_Return = %XLATE(UC : lc : W_String)

These are direct applications of the %XLATE BIF that show its elegance and simplicity. Before moving on to Sentence case, let's take a moment to think about what we need to do. Sentence case seems simple enough; after all, it's just converting the first character to uppercase and the rest to lowercase. As you probably remember from previous TechTips of this series, it's possible to use functions inside functions; just be careful to keep the code readable. And that's the solution for this case. We're going to use a %SUBST instead of the whole W_String variable to do the appropriate translations:

* Sentence case (First character in upper case, the rest in lower case)

C                   WHEN     P_Case = 'S'                              

C                   EVAL     W_Return = %XLATE(lc : UC :              

C                                              %SUBST(W_String : 1 : 1))

C                                       +                              

C                                       %XLATE(UC : lc :              

C                                              %SUBST(W_String : 2))  

If you remember %SUBST's syntax from a previous TechTip, when you don't specify the third parameter, it assumes that you want the substring that starts in the position you indicated in the second parameter (2 in this case) and ends with the last non-blank, usable character of the source string. So what's happening here is exactly what the sentence case's description says: first character in uppercase: %XLATE(lc : UC : %SUBST(W_String : 1 : 1)) and the rest in lower-case: %XLATE(UC : lc : %SUBST(W_String : 2)). Note that even though I'm still using fixed-format RPG, I'm doing some indentation in the BIFs to improve readability.

If Chg_Case's second parameter is not valid (the OTHER clause of our SELECT), we're just going to pass the input string to the W_Return variable. Then the function ends with the return op code:

* If an unknown case was passed, just return the input string

C                   OTHER                                    

C                   EVAL     W_Return = W_String            

C                   ENDSL                                    

C                  RETURN   W_Return                      

P Chg_Case       E                                          

Chg_Case demonstrates not only the simplicity and elegance of %XLATE, but also a different approach to building a function. I hope it served to strengthen your understanding of how to build a function and also how RPG's BIF can be used, either isolated or in conjunction with other BIFs, to solve fairly complex situations in an easy, readable, and, more importantly, maintainable fashion.

In the next TechTip, I'm going to take it up a notch with the implementation of the Proper Case Excel function, which requires a bit more coding. Until then, feel free to comment or propose your own solutions for these or other Excel functions in the Comments section below or in the usual LinkedIn groups.

Rafael Victória-Pereira has more than 20 years of IBM i experience as a programmer, analyst, and manager. Over that period, he has been an active voice in the IBM i community, encouraging and helping programmers transition to ILE and free-format RPG. Rafael has written more than 100 technical articles about topics ranging from interfaces (the topic for his first book, Flexible Input, Dazzling Output with IBM i) to modern RPG and SQL in his popular RPG Academy and SQL 101 series on mcpressonline.com and in his books Evolve Your RPG Coding and SQL for IBM i: A Database Modernization Guide. Rafael writes in an easy-to-read, practical style that is highly popular with his audience of IBM technology professionals.

Rafael is the Deputy IT Director - Infrastructures and Services at the Luis Simões Group in Portugal. His areas of expertise include programming in the IBM i native languages (RPG, CL, and DB2 SQL) and in "modern" programming languages, such as Java, C#, and Python, as well as project management and consultancy.

---

MC Press books written by Rafael Victória-Pereira available now on the MC Press Bookstore.

		Evolve Your RPG Coding: Move from OPM to ILE...and Beyond Transition to modern RPG programming with this step-by-step guide through ILE and free-format RPG, SQL, and modernization techniques. List Price $79.95 Now On Sale
		Flexible Input, Dazzling Output with IBM i Uncover easier, more flexible ways to get data into your system, plus some methods for exporting and presenting the vital business data it contains. List Price $79.95 Now On Sale
		SQL for IBM i: A Database Modernization Guide Learn how to use SQL’s capabilities to modernize and enhance your IBM i database. List Price $79.95 Now On Sale

Also Read

Advanced/Free - Function Calls and Return Values

PRACTICAL ILE - ILE Service Programs

Data-Manipulation Operations Using Free Format, Part Two