RPG Academy: BIF Up Your Code! Retrieve the Day of the Week with %DIFF

  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

As you've learned, we can do some basic "date math" using the plus (+) and minus (–) operators. Let's expand on that by using the %DIFF BIF to retrieve the day of the week.


Like many other date-related RPG operations, adding or subtracting days, months, or years to a date can be a real pain. The previous article in this series introduced the %DATE BIF, which allows you to use the plus (+) and minus (–) operators instead of the ADDDUR and SUBDUR op codes. There's another BIF, called %DIFF, that allows you to discard these op codes completely by providing a way to calculate the difference between two dates.


Introducing the %DIFF BIF

%DIFF is a very versatile BIF because it can calculate the difference between two dates, two times, or two timestamps and return the result in days, months, or years (for the date data type) and hours, minutes, seconds, or milliseconds (for the time and timestamp data types). You can also calculate the difference between a date and a timestamp, but only the date portion of the timestamp is considered when the calculation is performed. Likewise, you can calculate the difference between a time and a timestamp; in this case, naturally, only the time portion of the timestamp is taken into account.


Let's use %DIFF to retrieve the day of the week of a given date in two steps. The first function, Clc_DayOfWeek, calculates the day of the week's "numeric value" (1 for Monday, 2 for Tuesday, and so on) using a variation of Dinh's Algorithm. The second function, Rtv_DayOfWeek, simply takes the result of the first function and returns the corresponding three-letter abbreviation of the weekday (MON, TUE, and so on). I could have built only one function, but as you'll see in the next article in this series, being able to calculate the number of days between weekdays can be useful. This will also show how to orchestrate functions, making the output of one the input of another.


The Clc_DayOfWeek Function

The function follows the same methodology used in previous articles, and it's fairly unremarkable:



*   Day of the week (returns the day of the week of a given date as nbr) *


P Clc_DayOfWeek   B                   Export                              

D Clc_DayOfWeek   PI            1P 0                                    

* Input parameters                                                      

D P_Date                         D   VALUE                              


* Work variables                                                        

D W_Return       S             1P 0 INZ(9)                              

D W_RefDate     S               D   INZ(D'0001-01-01')                  


* Check input parms                                                      

* P_Date                                                                

C                   TEST(E)                P_Date                        

C                   IF       %ERROR                                      

C                   RETURN   W_Return                                    

C                   ENDIF                                                


* If the input parm is ok, calculate the day of the week                

C                   EVAL    W_Return = %REM(%DIFF(P_Date : W_RefDate :  

C                                                   *DAYS) :              

C                                            7) + 1


* Return it                                                              

C                   RETURN   W_Return                                    


P Clc_DayOfWeek   E                                                      


The only statement worth discussing is the calculation of the day of the week: it uses %DIFF to calculate the number of days (specified by the *DAYS in the third parameter) between the input date (first parameter) and the reference date (second parameter, with the value of 0001-01-01). Then the resulting number of days is divided by seven (because that's the number of days a week has), and the integer remainder is returned using yet another BIF: %REM. The result is the "numeric value of the day of the week," as I explained before. The final "+1" is just to make the result more readable, making Monday day number 1, Tuesday day number 2, and so on.


The Rtv_DayOfWeek Function

This "numeric value of the weekday" is the input for the second function. This function is even simpler than the first:



*   Day of the week (returns the day of the week of a given date in text)*


P Rtv_DayOfWeek   B                  Export                              

D Rtv_DayOfWeek   PI             3A                                      

* Input parameters                                                      

D P_DayNbr                     1P 0 VALUE                                


* Work variables                                                        

D W_Return       S             3A   INZ(*Blanks)                        


* Check input parms                                                      

* P_DayNbr                                                              

C                   IF      P_DayNbr < 1 Or P_DayNbr > 7                

C                   RETURN   W_Return                                    

C                   ENDIF                                                


* If the input parm is ok, Return the corresponding text                

C                   SELECT                                                

* Monday                                                                  

C                  WHEN     P_DayNbr = 1  

C                   EVAL     W_Return = 'MON'

* Tuesday                                  

C                  WHEN     P_DayNbr = 2  

C                   EVAL     W_Return = 'TUE'

* Wednesday                                  

C                  WHEN     P_DayNbr = 3  

C                   EVAL     W_Return = 'WED'

* Thursday                                  

C                  WHEN     P_DayNbr = 4  

C                   EVAL     W_Return = 'THU'

* Friday                                    

C                  WHEN     P_DayNbr = 5  

C                   EVAL     W_Return = 'FRI'

* Saturday                                  

C                  WHEN     P_DayNbr = 6  

C                   EVAL     W_Return = 'SAT'

* Sunday                                    

C                  WHEN     P_DayNbr = 7  

C                   EVAL     W_Return = 'SUN'

* Error                                      

C                   OTHER                      

C                   EVAL     W_Return = *Blanks

C                   ENDSL                      


C                  RETURN   W_Return        


P Rtv_DayOfWeek   E                            


If you prefer the output to be the complete word instead of the abbreviation or want to return the weekday in another language, be sure to adapt the W_Return variable and the prototype interface accordingly.


Testing the Last Two Articles' Functions

If you read the previous article, you probably noticed that I neglected to include an example. Well, here you have some basic examples of the functions of these last two articles:


H DECEDIT(',') DATEDIT(*DMY.)                                            



*   Variables                                                           *


D W_ValidDate   S              D   INZ                                

D W_Day         S             2P 0 INZ(*Zeros)                        

D W_DayNbr       S             1P 0 INZ(*Zeros)                        

D W_WeekDay     S             3A   INZ(*Blanks)                        



*   Copy Statements                                                     *


* Date Operations                                                        

/Copy QCPYLESRC,DTE_OPS_PR                                              


C                   EVAL     W_ValidDate = %Date('2014-11-16')          


* Test LastDayOfMonth                                                

C                   EVAL     W_Day = LastDayOfMonth(W_ValidDate)    

* "W_Day" is now 30                                                

* Test Clc_DayOfWeek and Rtv_DayOfWeek                              

C                   EVAL     W_DayNbr = Clc_DayOfWeek(W_ValidDate)

C                   EVAL     W_WeekDay = Rtv_DayOfWeek(W_DayNbr)    

* "W_WeekDay" is now 'TUE'                                          

C                   EVAL     W_DayNbr = Clc_DayOfWeek(%DATE())    

C                   EVAL     W_WeekDay = Rtv_DayOfWeek(W_DayNbr)    


C                   EVAL     *INLR = *On                            


Just a couple of notes:


Because the LastDayOfMonth and Clc_DayOfWeek functions accept a date variable as input parameter, you can pass the %DATE BIF instead of a variable name. %DATE() without any parameters returns the system's current date.


I could do without the W_DayNbr variable altogether by calling the Clc_DayOfWeek function inside the call to Rtv_DayOfWeek like this: Rtv_DayOfWeek(Clc_DayOfWeek(W_ValidDate)). It's not the most readable way to write code and can make debugging a little bit harder, but it's possible. I prefer to write code keeping readability and maintainability in mind. However, in most object-oriented languages, calling methods (functions) inside other methods is common practice.


I hope these simple functions inspire you to write your own date-calculation functions. Here are a few ideas:

  • Calculate a due date
  • Calculate the number of Mondays a given month has
  • Calculate the number of work days until you retire (or don't; you might get depressed!)

That's all for now! You can download the source code for the date functions service program and test program here. The next article will be about time-related BIFs, using a fun example to demonstrate some of them. Meanwhile, comment away in the Comments section below or in the RPG-related LinkedIn groups where these articles typically pop up.