RPG's date-related BIFs form a powerful set of tools that will help ease your date-operations-caused pains! Keep reading to learn how to use them properly.

Date operations, such as calculating a due date or something apparently as simple as retrieving the last day of a given month, are the source of many headaches for RPG programmers everywhere.

Everyone has a few homegrown date routines in their applications. Even though they work well most of the time, they become a nightmare when they don't do what we expect. RPG has a well-balanced set of BIFs to handle date, time, and timestamp data types, and you can use them to replace those error-prone, ages-old code, thus making your code clearer, faster, and more reliable. Let's start with the date-related BIFs and leave the time/timestamp BIFs for later.

A Simple Problem: Calculating the Last Day of the Month

What seems to be a simple problem can sometimes be a big chore. Calculating the last day of the month is a common date operation that many of us have in our applications. Most solutions I've seen use a compile time array and do some math to determine the last day of February. To be honest, most implementations of this date operation work well and don't need replacing (surely there are more urgent situations to address), but I chose to use this as an example because it's a very common situation.

I'm going to build a function that returns the last day of the input date. For that, I'll use a Date variable as input parameter and return a two-digits-long packed decimal. You might say, "OK, that's a problem for me because my dates are all stored in decimal (8, 0) format." To that, I say, "Not a problem; just use a BIF to convert them to Date format." That's where I'm going to start.

Introducing the %DATE BIF

In two recent TechTips (1 and 2), I explained how to use BIFs to convert between numeric and character data types. Some readers commented that I had forgotten about %DATE, but it wasn't a lapse; it was a conscious attempt not to overwhelm the readers with information. Anyway, the time has come to introduce %DATE. This BIF takes character, numeric, or timestamp expression data and converts it into a date data type. There's a second, optional parameter to indicate the date format of the expression. If the date format is not specified for character or numeric input, the default value is either the format specified on the DATFMT control-specification keyword or *ISO. Here are some examples of the %DATE BIF usage:

D W_ValidDate   S               D   INZ

(…)

C                   EVAL     W_ValidDate = %Date('2014-11-16')

C                   EVAL     W_ValidDate = %Date(20141116)  

This, however, will produce an error, because the date is not valid:

C                   EVAL     W_ValidDate = %Date('2014-31-99')

This will cause a compile time error because the expression can be evaluated at compile time. If instead of the literal I had a variable as %DATE's input parameter, then the error would occur at run time.

Now that we know how to convert the numeric and character fields to date, we can provide the input that the LastDayOfMonth function expects. So let's build it!

The LastDayOfMonth Function

As I said before, this function takes in a date and returns the last day of that date's month. There are many (creative) ways to calculate the last day of a given month, so feel free to use whatever you prefer. The one I present here was engineered to make use of a few more date-related BIFs, as you'll see in a moment. Let's start with the function prototype, work variables, and input parameter validation:

*------------------------------------------------------------------------*

*   Copy Statements                                                     *

*------------------------------------------------------------------------*

* Date Operations                                                        

/Copy QCPYLESRC,DTE_OPS_PR                                              

*------------------------------------------------------------------------*

*   Last day of the month (returns the last day of the month of a date) *

*------------------------------------------------------------------------*

P LastDayOfMonth B                  Export                              

D LastDayOfMonth PI             2P 0                                    

* Input parameters                                                      

D P_Date                         D   VALUE                        

* Work variables                                                        

D W_Return       S             2P 0 INZ(99)                            

D W_Date        S               D   INZ                                

D W_TempDate    S               D   INZ

* Check input parms                                                      

* P_Date                                                                  

C                   TEST(E)                 P_Date                        

C                   IF       %ERROR                                      

C                   RETURN   W_Return                                    

C                   ENDIF                                                

This first part of this code, right down to the input parameter validation, is very similar to the Chg_Case function's from two previous TechTips (1 and 2), so I won't go over it in detail. Notice, however, that I'm using the TEST opcode with the (E) extender to test if the input parameter contains a valid date. The extender allows me to do without yet another indicator and use the %ERROR BIF instead. I'll talk more about this BIF when I discuss error handling, later in the series. Anyway, if P_Date doesn't contain a valid date, 99 (the value to which W_Return is being initialized) is returned. It's a simple way to indicate an error, because 99 is definitely not a valid last of the month. Now let's skip to the calculation itself, since there's no need to retrieve additional information (remember the three-step process of building a function introduced before?). I'm going to calculate the last day of the month by first finding the last day of the previous month, adding a month to the resulting date and then extracting the day of that date. For that, I'll use the %DAYS, %MONTHS, and %SUBDT BIFs. While the first two are straightforward (they convert a numeric value to a "Date-type-operation-compatible" format), %SUBDT is a bit more complex; think of it as a kind of %SUBST for dates, where you indicate the part of the date you want to extract instead of the starting character. While the first two are straightforward (they convert a numeric value to a "Date-type-operation-compatible" format), %SUBDT is a bit more complex; think of it as a kind of %SUBST for dates, where you indicate the part of the date you want to extract instead of the starting character. Look at the code below, and all of this will become clearer:

* If the input parm is ok, calculate the last day of the month          

* by adding a month and then subtracting the day part of that date,

* from the itself, to get the last day of the input date's month

C                  EVAL     W_TempDate = P_Date + %Months(1)               

C                  EVAL     W_Date = W_TempDate

C                                   - %Days(%SubDt(W_TempDate: *Days))

* Return the last day of the month                                      

C                   EVAL     W_Return = %SUBDT(W_Date:*D)                

C                   RETURN   W_Return                                    

P LastDayOfMonth E                                                      

There are two steps to the process: calculate the last day of the month by first adding a month to the original date – W_TempDate = P_Date + %Months(1) – and then subtract the day part of this temporary date to find the last day of the previous month – W_Date = W_TempDate - %Days(%SubDt(W_TempDate: *Days)). So there you have it —20 something lines of code, including comments and the function's header and footer, that solve a simple problem in a simple way.

Two things that I haven't mentioned: there's also a %YEARS BIF that works just like %DAYS and %MONTHS; and %SUBDT can be used to extract any of the three date components by specifying *DAYS, *MONTHS, or *YEARS or their short versions (*D, *M, or *Y, respectively) in the BIF's second parameter. The readers with SQL experience are probably wondering why use RPG for this if there's an SQL function that does the same thing. Well, you're right: I'll be talking about the Last_Day SQL function in a future TechTip of the SQL 101 Series.

As I said in the beginning, the date-related BIFs are very powerful and useful. The next TechTip will demonstrate just that by doing some more "date math" with %DIFF. Until then, I want to hear from you: use the Comments section below (or the usual LinkedIn groups) to leave your comments and questions!

Rafael Victória-Pereira has more than 20 years of IBM i experience as a programmer, analyst, and manager. Over that period, he has been an active voice in the IBM i community, encouraging and helping programmers transition to ILE and free-format RPG. Rafael has written more than 100 technical articles about topics ranging from interfaces (the topic for his first book, Flexible Input, Dazzling Output with IBM i) to modern RPG and SQL in his popular RPG Academy and SQL 101 series on mcpressonline.com and in his books Evolve Your RPG Coding and SQL for IBM i: A Database Modernization Guide. Rafael writes in an easy-to-read, practical style that is highly popular with his audience of IBM technology professionals.

Rafael is the Deputy IT Director - Infrastructures and Services at the Luis Simões Group in Portugal. His areas of expertise include programming in the IBM i native languages (RPG, CL, and DB2 SQL) and in "modern" programming languages, such as Java, C#, and Python, as well as project management and consultancy.

---

MC Press books written by Rafael Victória-Pereira available now on the MC Press Bookstore.

		Evolve Your RPG Coding: Move from OPM to ILE...and Beyond Transition to modern RPG programming with this step-by-step guide through ILE and free-format RPG, SQL, and modernization techniques. List Price $79.95 Now On Sale
		Flexible Input, Dazzling Output with IBM i Uncover easier, more flexible ways to get data into your system, plus some methods for exporting and presenting the vital business data it contains. List Price $79.95 Now On Sale
		SQL for IBM i: A Database Modernization Guide Learn how to use SQL’s capabilities to modernize and enhance your IBM i database. List Price $79.95 Now On Sale

Also Read

Advanced/Free - Function Calls and Return Values

PRACTICAL ILE - ILE Service Programs

Data-Manipulation Operations Using Free Format, Part Two