RPG Fundamentals Tip #1: Working with Cycle Main Programs

RPG
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

 

 

In cycle main programs, the compiler automatically includes the RPG cycle to provide program initialization and termination as well as ordered processing steps for file input and output (I/O).

 

Editor’s note: This article is excerpted from Programming in ILE RPG, Fifth Edition, chapter 14, “Building Modular Programs with Procedures.”

Up to now, all the RPG programs we’ve discussed [in this chapter] have been cycle main programs. A cycle main program has a main procedure implicitly specified in the main section of the program. In a cycle main program, the main procedure does not have a name; it is the main procedure by virtue of its location in the program code. A cycle main program includes a main source section (the main procedure), followed by zero or more subprocedure sections. The main procedure is everything before the first Dcl-proc instruction. You need not code anything special to define the main procedure. It does not begin with a Dcl-proc instruction or end with an End-proc instruction. The cycle main program is so called because the compiler automatically includes the RPG cycle to provide program initialization and termination as well as ordered processing steps for file input and output (I/O). Most traditional RPG programs are cycle main programs.

To understand the basic coding requirements for a cycle main program, let’s look at an example. The following program demonstrates how to code a main procedure and include the example Celsius subprocedure within the same source, an architecture sometimes called a local procedure. Although the program is complete as shown, we have abbreviated it to concentrate those lines that relate to procedures.

// ----------------------------------------------------

//

// Program – THISPGM – Displays Celsius temperature and

//                     corresponding water state

//

// ----------------------------------------------------

// ------------------------- Cycle main procedure PR/PI

Dcl-pr Thispgm Extpgm;

  *N Int(5);

End-pr;

Dcl-pi Thispgm;

  Englishtemp Int(5);

End-pi;

// ----------------------------------------- Prototypes

Dcl-pr Celsius Int(5);

  *N Int(5);

End-pr;

// ----------------------------------- Global variables

Dcl-s Message    Char(50);

Dcl-s Metrictemp Int(5);

Dcl-s State      Varchar(8);

// ------------------------------------- Main procedure

Metrictemp = Celsius(Englishtemp);

Select;

  When Metrictemp < 0;

    State = 'solid';

  When Metrictemp = 0;

    State = 'freezing';

  When Metrictemp = 100;

    State = 'boiling';

  When Metrictemp > 100;

    State = 'gaseous';

  Other;

    State = 'liquid';

Endsl;

Message = 'At ' + %Char(Englishtemp) + ' degrees (' +

          %Char(Metrictemp) + ' Celsius), water is ' +

          State + '.';

Dsply Message;

*Inlr = *On;

Return;

// ----------------------------------------------------

//

// Procedure – Celsius – Converts Fahrenheit to Celsius

//

Dcl-proc Celsius;

  // ------------------------------ Procedure interface

  Dcl-pi *N Int(5);

    Fahrenheit Int(5);

  End-pi;

  // ---------------------------------- Local variables

  Dcl-s Temperature Int(5);

  Eval(H) Temperature = (5/9) * (Fahrenheit - 32);

  Return Temperature;

End-proc Celsius;

Notice the declarations in this program under the Global variables comment for Message, Metrictemp, and State. Those variables, which you define before the main procedure, have a global scope and can be accessed from anywhere in the compile unit. If you have a need to do so, the Celsius subprocedure can also process any of those variables as well as the Englishtemp parameter, which is also global. The main procedure in a cycle main program cannot declare local variables or access a subprocedure’s local variables.

Tip: Generally, you should define variables with the narrowest scope that will accomplish your program’s goal. Instead of accessing global variables in a subprocedure, you should pass parameters to share information between the main procedure and any subprocedures. In a large program consisting of many modules, this practice helps avoid confusion and errors and makes your programs easier to maintain.

The main procedure of this program accepts one parameter, Fahrenheit, and then executes the Celsius subprocedure to convert that value to Celsius. It then assigns a (sea level) state based on the temperature and builds a message along the lines of “At 20 degrees (-7 Celsius), water is solid.” Finally, the Dsply (Display Message) operation shows the message on the workstation that is running the program (or sends the message to the job log).

The Celsius subprocedure is coded following the main procedure. In a cycle main program, the main procedure code ends once it encounters the first subprocedure. The main procedure code should end with *Inlr set to *On to ensure proper cleanup after the program has completed. The cycle then automatically closes files, unlocks data areas, and frees memory used by the program.

BLOG COMMENTS POWERED BY DISQUS