Database update collisions are a common problem, and qualified data structures provide an easy solution.

Database update collisions have been around since the advent of interactive database maintenance. First, we had no record locks. That left us with "last Enter key wins." Let's say I edit a record and you update the same record at the same time. We key in conflicting changes and press Enter. If I hit Enter first, my change is written to the database first; then your Enter is processed, and your change overwrites my change. Last Enter key wins!

A number of techniques have been used over the years to address this problem. Some applications used record locking, but that was ugly because the second person ended up with a hard halt, often after a relatively long wait period. Another option was to mark the record as busy by setting a busy flag in the record itself, but then jobs inevitably ended abnormally, leaving records locked and requiring periodic cleanup programs.

One of the cleaner techniques is the "last change check." Nobody locks the record during editing; instead a program that intends to update a record retrieves the record and saves it before displaying the data to the user. After the user changes the data and requests an update, the maintenance program then retrieves the record again, this time locking it. The program compares the newly retrieved record to the saved record. If there are no changes, the program updates the record. If the record has been changed, however, the update is canceled and the user is notified with a message along the lines of "Record has been changed by another user."

Implementing the Last Change Check

The last change check can be achieved in one of two basic ways. One is to use a "last changed" timestamp. This is relatively easy to implement and works especially well in environments where you are already storing the last change user, program, and timestamp in each record as opposed to recording a full audit journal.

This article, however, is going to use a different technique, the before and after image check. Image checking is done by comparing the entire contents of the saved record to that of the re-read record. Doing this in RPG hasn't always been very easy, and in fact prior to RPG IV's D-spec it was downright difficult. While you could use an externally described data structure, you couldn't have two data structures with the same field names, so it was hard to define both the before and after images. But with the advent of the qualified data structure, it has become very easy.

Let's look at a program that takes advantage of this RPG feature.

A    fCUSTMAST  UF   E           K DISK

B    d dsCUSTMAST1   e ds                  extname(CUSTMAST:*input) qualified

B    d dsCUSTMAST2   e ds                  extname(CUSTMAST:*input) qualified

B    d dsCUSTMAST3   e ds                  extname(CUSTMAST:*output) qualified

C    d myCust          s                   like(CMCUST)

C    d success         s               n

      /free

D      // Get myCust from user

D      chain(n) (myCust) CUSTMAST dsCUSTMAST1;

E      // Show data to user

E      // Get input from user

E      // Edit input

F      chain (myCust) CUSTMAST dsCUSTMAST2;

F      if (dsCUSTMAST1 <> dsCUSTMAST2);

         // Send "record has changed" message

G        unlock CUSTMAST;

G        success = *off;

       else;

         // Copy input fields into output data structure

H        eval-corr dsCUSTMAST3 = dsCUSTMAST2;

         // Move updated fields into dsCUSTMAST3

H        update CUSTMASTR dsCUSTMAST3;

H        success = *on;

       endif;

I      *inlr = *on;

      /end-free

The program is simple. In fact, it's a little more complex than it needs to be because of a quirk in the extname keyword, but I'll explain that as I go through the program.

A. Here I define a keyed update-capable file. Nothing unusual. Note that I haven't described a display file or anything; we're not making any assumptions as to how the program communicates with the user, only that it does.

B. Next, I define the data structures. Since they are qualified, I can have as many data structures based on the same file as I need. This is the first place we run into the quirk I mentioned earlier. Externally described data structures are formatted as an exact match to the buffer layout of the record named. Since records can theoretically have input-only or output-only fields, the input buffer could conceivably be different from the output buffer. Because of that, you have to tell the compiler which buffer layout you're matching: input or output. Only input data structures can be used for CHAINs and READs; only output data strcutures can be used for WRITEs and UPDATEs. We'll deal with this issue again in a moment.

C. Here are our work variables. They're just there to help flesh out the program a little more.

D. OK, the user entered a customer number (somehow). The first chain is done using the (n) extender so the record is not locked. Also notice that we read into dsCUSTMAST1.

E. This is where the meat of the program goes: displaying the data to the user, accepting input, editing the results, applying business rules, etc.—all the stuff that does the actual business work but doesn't pertain to the locking mechanism.

F. Now for the focus of this article: all I do to implement the record check is to read the record again, this time with a lock, into the second data structure, dsCUSTMAST2. Then I compare dsCUSTMAST1 to dsCUSTMAST2. That's all it takes!

G. If the before and after images are different, I notify the user through a message or some other method. For our example, I just set success to *off. Also, note that if you wanted to implement the timestamp technique, this is the place where you would do that. Rather than save the entire record, you need to save only the timestamp and here compare the saved timestamp with the timestamp from the second read.

H. If the images do match, I can do the update. This is the second time we run into the input vs. output buffer issue. Since we cannot perform an UPDATE from a data structure based on the input format, we have to move the data from one to another. We could just move one data structure to another, but let's consider the rare situation where the input and output buffers don't match; a straight data-structure-to-data-structure move would potentially give you some bad results. However, RPG provides a really nice alternative, the EVAL-CORR opcode, which moves all named fields from one data structure to the matching fields in another, all in one instruction. Very handy. So I move all the fields from the second input data strcuture to the output data structure, update the output data structure with whatever fields have changed, and then execute the UPDATE instruction.

I. For our simple example, it's time to get out.

That's it. I hope this technique provides a helpful introduction to qualified data structures and the ways they can help your programming.

as/400, os/400, iseries, system i, i5/os, ibm i, power systems, 6.1, 7.1, V7, V6R1

Joe Pluta is the founder and chief architect of Pluta Brothers Design, Inc. He has been extending the IBM midrange since the days of the IBM System/3. Joe uses WebSphere extensively, especially as the base for PSC/400, the only product that can move your legacy systems to the Web using simple green-screen commands. He has written several books, including Developing Web 2.0 Applications with EGL for IBM i, E-Deployment: The Fastest Path to the Web, Eclipse: Step by Step, and WDSC: Step by Step. Joe performs onsite mentoring and speaks at user groups around the country. You can reach him at This email address is being protected from spambots. You need JavaScript enabled to view it..

---

MC Press books written by Joe Pluta available now on the MC Press Bookstore.

		Developing Web 2.0 Applications with EGL for IBM i Joe Pluta introduces you to EGL Rich UI and IBM’s Rational Developer for the IBM i platform. List Price $39.95 Now On Sale
		WDSC: Step by Step Discover incredibly powerful WDSC with this easy-to-understand yet thorough introduction. List Price $74.95 Now On Sale
		Eclipse: Step by Step Quickly get up to speed and productivity using Eclipse. List Price $59.00 Now On Sale

Also Read

Advanced/Free - Function Calls and Return Values

PRACTICAL ILE - ILE Service Programs

Data-Manipulation Operations Using Free Format, Part Two