17
Wed, Apr
5 New Articles

The API Corner: Deleting Objects

APIs
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

The Delete Object API offers flexibility in terms of removing unneeded objects.

 

As a new year approaches, many of you may be looking at general house-cleaning of your i. This activity might include deleting those objects that have been created over the last 12 months and are no longer needed. In the past, if you wanted to automate such cleanup activities from, say, an RPG application program, you may have written various CL programs that were then called from the RPG program in order to run the appropriate DLTxxx CL command or, as an alternative, constructed the appropriate CL DLTxxx command within an RPG program variable and then run the command using an API such as Process Commands. If your system is at V6 or later, you now have another option, one that does not rely on running CL commands. This new technique, of course, is also available to your application programs whenever they need to delete an object, not just for general system maintenance.

 

The Delete Object (QLIDLTO) API, documented here, can be used to delete many (though not all) types of objects on your system. Object types supported include files, data areas, data queues, programs, menus, panel groups, device descriptions, and so on. A complete list of the object types supported can be found in the API documentation.

 

The API itself is quite straightforward with five parameters.

 

The first parameter is a standard 20-byte qualified object name with the first 10 characters identifying the name of the object to be deleted and the second 10 characters the library. The object name can be a specific name, such as FILE1, a generic name, such as FILE1*, or a special value, such as *ALL. Similarly, the library name can be a specific name, such as BHVLIB, or one of several special values, such as *LIBL, *CURLIB, *ALLUSR, etc. You will want to be careful with some of these combinations. For instance, if you specify a generic object name such as FILE1* and the special value *LIBL for the library, then all objects in your library list (of the type identified with the second parameter of the API) starting with the characters FILE1 will be deleted. This behavior might be just what you are looking for, or it might really ruin your day. If, on the other hand, you used the specific object name of FILE1 with the special value of *LIBL, then only the first occurrence of FILE1 within your library list would be deleted.

 

The second parameter is the type of object you want to delete. The value specified is prefixed by an asterisk (*) as in *FILE, *DTAARA, *DTAQ, *PGM, *MENU, *PNLGRP, *DEVD, etc. Note that there is no special value, such as *ALL, for this parameter. You must explicitly identify the type of object to be deleted by the API.

 

The third parameter identifies the auxiliary storage pool where the library containing the object(s) to be deleted can be found. Special values include *, *SYSBAS, *ALLAVL, etc.

 

The fourth parameter allows you to control whether or not completion and informational messages related to the object(s) deleted should be retained in the job log. The parameter is a 1-byte value where a value of '0' indicates that messages should not be removed and a value of '1'indicates that diagnostic and informational messages should be removed following the successful deletion of an object.

 

The fifth parameter is the standard API error-code parameter.

 

Here is a sample program demonstrating how to call the QLIDLTO API. To create the program, you can use the CRTBNDRPG command.

 

h dftactgrp(*no)                                               

                                                                

dDltObj           pr                  extpgm('QLIDLTO')        

d QualObj                       20    const                    

d ObjTyp                        10    const                    

d ASPDevice                     10    const                    

d RmvMsg                         1    const                    

d ErrCde                              likeds(QUSEC)            

                                                               

dSndPgmMsg        pr                  extpgm('QMHSNDPM')       

d MsgID                          7    const                    

d QualMsgF                      20    const                    

d MsgDta                     65535    const options(*varsize)  

d LenMsgDta                     10i 0 const                    

d MsgTyp                        10    const                    

d CSE                           10    const                    

d CSE_Counter                   10i 0 const                       

d MsgKey                         4                               

d ErrCde                              likeds(QUSEC)              

d LenCSE                        10i 0 const options(*nopass)     

d QualCSE                       20    const options(*nopass)     

d PgmMsgWait                    10i 0 const options(*nopass)     

d CSETyp                        10    const options(*nopass)     

d MsgDtaCCSID                   10i 0 const options(*nopass)     

                                                                  

dObjTyp           s             10                               

dLenMsgDta        s             10i 0                            

dMsgKey           s              4                               

                                                                  

dQualObjName      ds                                             

d Obj                           10                               

d Lib                           10                               

                                                                  

dQualMsgF         ds                                       

d MsgF                          10    inz('QCPFMSG')       

d MsgL                          10    inz('*LIBL')         

                                                            

 /copy qsysinc/qrpglesrc,qusec                             

                                                           

dErrCde           ds                  qualified            

d Hdr                                 likeds(QUSEC)        

d MsgDta                       512                         

                                                           

dEscErrCde        ds                  qualified            

d Hdr                                 likeds(QUSEC)        

                                                           

 /free                                                     

                                                           

  ErrCde.Hdr.QUSBPrv = %size(ErrCde);                       

  EscErrCde.Hdr.QUSBPrv = 0;                               

                                                              

  Obj = 'FILE1';                                              

  Lib = 'BHVLIB';                                             

  ObjTyp = '*FILE';                                           

                                                              

  DltObj(QualObjName :ObjTyp :'*' :'0' :ErrCde);              

                                                              

  select;                                                     

     when ErrCde.Hdr.QUSBAvl = 0;                             

          // Everything is fine, the object was deleted       

                                                              

     when ErrCde.Hdr.QUSEI = 'CPF2105';                       

          // Object not found so no need to worry about       

          // the delete failing                               

                                                              

     other;                                                   

          if ErrCde.Hdr.QUSBAvl <= %size(QUSEC);              

             LenMsgDta = 0;                               

          else;                                           

             LenMsgDta = (ErrCde.Hdr.QUSBAvl -            

                          %size(QUSEC));                  

          endif;                                          

                                                          

          SndPgmMsg(ErrCde.Hdr.QUSEI :QualMsgF            

                    :ErrCde.MsgDta :LenMsgDta :'*DIAG'    

                    :'*' :0 :MsgKey :EscErrCde);          

                                                          

  endsl;                                                   

                                                          

  *inlr = *on;                                            

  return;                                                 

                                                           

 /end-free                          

 

The program defines two instances of the API error-code structure. The first instance, named ErrCde, is used when calling the QLIDLTO API to delete an object. The bytes-provided subfield of the ErrCde data structure (ErrCde.Hdr.QUSBPrv) is set to a non-zero value so that any error conditions encountered by the API will be returned in ErrCde, as opposed to being sent as escape messages to the application program. You will see how the sample program utilizes this ErrCde data structure shortly.

 

The second instance of the API error-code structure, named EscErrCde, is used when calling the Send Program Message (QMHSNDPM) API. This API, documented here and previously introduced in the article "Inform Users of Problems by Sending Error Messages from Application Programs," is used by the application program to send some (but not all) error conditions reported by the Delete Object API to the job log. The bytes-provided subfield of the EscErrCde data structure (EscErrCde.Hdr.QUSBPrv) is set to 0 so that any error condition encountered when sending a message will result in an escape message, allowing the user to know that something totally unexpected has occurred.

 

Having initialized the ErrCde and EscErrCde error-code data structures, the program then identifies what object it wants to delete. The object is a *FILE named FILE1, located in library BHVLIB. The QLIDLTO API is then called with the fourth parameter set to '0' (retain informational messages in the job log) and the fifth parameter to the ErrCde error-code data structure.

 

When the QLIDLTO API returns control to the application program, the sample program examines the ErrCde data structure to determine if any errors were encountered.

 

If the file BHVLIB/FILE1 was successfully deleted, the subfield ErrCde.Hdr.QUSBAvl will be 0 and the program moves on to its next task (in our case, setting on LR and returning). In this case, the successful deletion of file FILE1 in BHVLIB (the message CPC2191 – Object FILE1 in BHVLIB type *FILE deleted) will also be found in the job log due to the fourth parameter being set to '0' when calling the QLIDLTO API. If the API's fourth parameter were set to the value '1', then no message would be found in the job log.

 

If the file BHVLIB/FILE1 was not successfully deleted, the subfield ErrCde.Hdr.QUSBAvl will be non-zero and the program further interrogates the ErrCde data structure in order to determine the cause of the failure. The program first checks whether the subfield ErrCde.Hdr.QUSEI (the message exception ID) is set to the value 'CPF2105'. Message CPF2105 indicates that the file was not found, making it understandably difficult to delete the file. As our objective was to delete the file, and the file does not exist, the program simply continues on to its next task. In this case, no message such as CPC2191 will be in the job log as the file was not deleted, nor will there be any error messages.

 

If the subfield ErrCde.Hdr.QUSEI was not set to message ID CPF2105, the sample program then uses the QMHSNDPM message to resend the escape message identified by ErrCde.Hdr.QUSEI, as a diagnostic message, to the job log. These messages might be that the user of the program is not authorized to delete the object, that the object could not be deleted due to dependencies, that the object is locked by another job, etc. Using the message replacement data found in subfield ErrCde.MsgDta, the sample program writes to the job log the same message that the API would have sent as an escape message had we not set ErrCde.Hdr.QUSBPrv to a non-zero value—but without having to monitor for the escape message and/or ending abnormally. In this case, a message will be found in the job log documenting why the object was not deleted.

 

The QLIDLTO API provides a very flexible, and easy, way for application programs to delete objects that are no longer needed. I suspect that many of you will find one or two places within your applications where the API fits right in.

 

As usual, if you have any API questions, send them to me at This email address is being protected from spambots. You need JavaScript enabled to view it.. I'll see what I can do about answering your burning questions in future columns.

                     

Bruce Vining

Bruce Vining is president and co-founder of Bruce Vining Services, LLC, a firm providing contract programming and consulting services to the System i community. He began his career in 1979 as an IBM Systems Engineer in St. Louis, Missouri, and then transferred to Rochester, Minnesota, in 1985, where he continues to reside. From 1992 until leaving IBM in 2007, Bruce was a member of the System Design Control Group responsible for OS/400 and i5/OS areas such as System APIs, Globalization, and Software Serviceability. He is also the designer of Control Language for Files (CLF).A frequent speaker and writer, Bruce can be reached at This email address is being protected from spambots. You need JavaScript enabled to view it.. 


MC Press books written by Bruce Vining available now on the MC Press Bookstore.

IBM System i APIs at Work IBM System i APIs at Work
Leverage the power of APIs with this definitive resource.
List Price $89.95

Now On Sale

BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

$0.00 Raised:
$

Book Reviews

Resource Center

  • SB Profound WC 5536 Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. You can find Part 1 here. In Part 2 of our free Node.js Webinar Series, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Brian will briefly discuss the different tools available, and demonstrate his preferred setup for Node development on IBM i or any platform. Attend this webinar to learn:

  • SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.

  • SB HelpSystems ROBOT Generic IBM announced the E1080 servers using the latest Power10 processor in September 2021. The most powerful processor from IBM to date, Power10 is designed to handle the demands of doing business in today’s high-tech atmosphere, including running cloud applications, supporting big data, and managing AI workloads. But what does Power10 mean for your data center? In this recorded webinar, IBMers Dan Sundt and Dylan Boday join IBM Power Champion Tom Huntington for a discussion on why Power10 technology is the right strategic investment if you run IBM i, AIX, or Linux. In this action-packed hour, Tom will share trends from the IBM i and AIX user communities while Dan and Dylan dive into the tech specs for key hardware, including:

  • Magic MarkTRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now!  Request Now.

  • SB HelpSystems ROBOT GenericForms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.

  • SB HelpSystems ROBOT GenericIT security is a top priority for businesses around the world, but most IBM i pros don’t know where to begin—and most cybersecurity experts don’t know IBM i. In this session, Robin Tatam explores the business impact of lax IBM i security, the top vulnerabilities putting IBM i at risk, and the steps you can take to protect your organization. If you’re looking to avoid unexpected downtime or corrupted data, you don’t want to miss this session.

  • SB HelpSystems ROBOT GenericCan you trust all of your users all of the time? A typical end user receives 16 malicious emails each month, but only 17 percent of these phishing campaigns are reported to IT. Once an attack is underway, most organizations won’t discover the breach until six months later. A staggering amount of damage can occur in that time. Despite these risks, 93 percent of organizations are leaving their IBM i systems vulnerable to cybercrime. In this on-demand webinar, IBM i security experts Robin Tatam and Sandi Moore will reveal:

  • FORTRA Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:

  • FORTRAManaging messages on your IBM i can be more than a full-time job if you have to do it manually. Messages need a response and resources must be monitored—often over multiple systems and across platforms. How can you be sure you won’t miss important system events? Automate your message center with the Robot Message Management Solution. Key features include:

  • FORTRAThe thought of printing, distributing, and storing iSeries reports manually may reduce you to tears. Paper and labor costs associated with report generation can spiral out of control. Mountains of paper threaten to swamp your files. Robot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing. Manage your reports with the Robot Report Management Solution. Key features include:

  • FORTRAFor over 30 years, Robot has been a leader in systems management for IBM i. With batch job creation and scheduling at its core, the Robot Job Scheduling Solution reduces the opportunity for human error and helps you maintain service levels, automating even the biggest, most complex runbooks. Manage your job schedule with the Robot Job Scheduling Solution. Key features include:

  • LANSA Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.

  • LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed. Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

  • LANSASupply Chain is becoming increasingly complex and unpredictable. From raw materials for manufacturing to food supply chains, the journey from source to production to delivery to consumers is marred with inefficiencies, manual processes, shortages, recalls, counterfeits, and scandals. In this webinar, we discuss how:

  • The MC Resource Centers bring you the widest selection of white papers, trial software, and on-demand webcasts for you to choose from. >> Review the list of White Papers, Trial Software or On-Demand Webcast at the MC Press Resource Center. >> Add the items to yru Cart and complet he checkout process and submit

  • Profound Logic Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.

  • SB Profound WC 5536Join us for this hour-long webcast that will explore:

  • Fortra IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn: