24
Wed, Apr
0 New Articles

How Could Life Be Better?

RPG
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times
When thinking about an RPG application and the file I/O necessary to accomplish a given task, you can thank your lucky stars that the architects of the RPG language made it so easy to write and implement an I/O-intensive application with a number of operations to chose from. Most applications consist of little more than an OPEN, a SETLL, a READx, some processing, and, finally, a CLOSE. And, with RPG, a file declaration is a simple matter of determining what type of file access is required. Even novices can prompt their way through the file access and processing choices, guided by SEU syntax feedback messages.

So, how could life be better? You answered that question, whether you realize it or not, when you made a choice early in the application design stage that later proved to be either completely wrong at worst or inflexible at best. To make the seriousness of such choices painfully clear, it sometimes takes a shift like the one from DB2 to UDB/400, for example. UDB/400 facilitates the creation and access of files with null-capable fields, which is great--unless your applications are not set up to handle null-field processing. This is when life could be significantly better. But how?

ILE Is the Answer

The answer is provided by ILE. C I/O functions have the flexibility to free us from the shackles of both static file declaration choices and the lack of support for runtime file selection containing null-field data. Note that I'm talking about support for null-field data in program-described files, which is not the same as support for null fields in externally described files (currently offered only as a compile option). You might challenge my assertion that there's a need to use C I/O in the normal course of application development--except in rare instances, like a generic file access or reporting utility, where runtime overrides are made to an internal program-described file. But the premise put forth in this article is that flexibility is gained in all development activities by using C I/O instead of RPG opcodes.

A Shift in Thinking

The complete code that accompanies this article is available for download. Read on to learn about it.

Figure 1 shows the shell of a new I/O paradigm for RPG IV (ILE RPG) that employs C I/O.

     h dftactgrp(*no) actgrp(*new) bnddir('QC2LE') 

      *-------------------------------------------------------------------
      *  Domestic procedure and program prototypes
      *-------------------------------------------------------------------
      *------------------------------------------------------------------
      * Prototype for ior()
      *------------------------------------------------------------------
     d ior             pr              10i 0 extproc('ior')
     d                                 10i 0 value
     d                                 10i 0 value

ior() Arguments:
1: First integer to be ORed
2: Second integer to be ORed
Return:

Combined (ORed) integer result


      *---------------------------------------------------------------------
      * Prototype for testing fields for null value.
      *------------------------------------------------------------------
     d is_field_null...
     d                 pr                n
[L]  d                                   *   value
     d                                 10u 0 value
     d                                 10u 0 value

is_field_null() Arguments:
1: Pointer to null map (innullmap or outnullmap)
2: Length of null map
3: Field number (order) in file to be tested for nulls
Return:
Boolean (true = field contains null value or false = not null)


      *------------------------------------------------------------------
      * Prototype for setting null map values.
      *------------------------------------------------------------------
     d set_null_map...
     d                 pr
     d                                   *   value
     d                                 10u 0 value
     d                                  1a   value options(*nopass)
     d                                 10u 0 value options(*nopass)

set_null_map() Arguments:
1: Pointer to null map (innullmap or outnullmap)
2: Length of null map
3: Null indicator value ('0' = *off or not null, '1' = *on or set to null)
(optional, defaults to *off)
4: Field number (order) in file to be set to null (optional, defaults to all fields)
Return:
Pointer to file ODP


     d pIgnDtaExc      s                 *   procPtr 
     d                         inz(%paddr('igndtaexc'))
   
     d ignDtaExc       pr                    extproc('igndtaexc')
     d                                   *   value
     d                                   *
     d                                 10i 0
     d                                 12a

      *----------------------------------------------------------
      * Imported Prototypes for CEEHDLR & CEEHDLU
[K1]  *  procedures.
      *----------------------------------------------------------
     d registerHdlr    pr                   extProc('CEEHDLR')
     d  pUserProc                        *  procPtr
     d  pUserToken                       *  const
     d  feedback                       12a  options(*Omit)

     d unregisterHdlr  pr                   extProc('CEEHDLU')
     d  pUserProc                        *  procPtr
     d  feedback                       12a  options(*Omit)

     d Resume          c                    const(10)
     d UpToNextHndlr   c                    const(20)
     d UptoNextProc    c                    const(21)
      *------------------=---------------------------------------
      *  Imported procedure and program prototypes
      *----------------------------------------------------------
                       :
[A]  d/copy qrpglesrc,recioth
 
   *------- File pointer positioning constants 
     d ropen_max       c                   32766 
     d rrn_eq          c                   x'08000300' 
     d key_eq          c                   x'0B000100' 
     d key_gt          c                   x'0D000100' 
     d key_lt          c                   x'09000100' 
     d key_le          c                   x'0A000100' 
     d key_ge          c                   x'0C000100' 
     d key_nxtunq      c                   x'05000100' 
     d key_prvunq      c                   x'06000100' 
     d key_nxteq       c                   x'0E000100' 
     d key_prveq       c                   x'0F000100' 
 
     d first           c                   x'01000300' 
     d last            c                   x'02000300' 
     d next            c                   x'03000300' 
     d previous        c                   x'04000300' 
 
     d start_frc       c                   x'03000004' 
     d start           c                   x'01000004' 
     d end_frc         c                   x'04000004' 
     d end             c                   x'02000004' 
 
      *------- Record locking and IO feedback buffer option constants 
     d dft             c                   x'0B000100' 
     d no_lock         c                   x'00000001' 
     d no_posn         c                   x'00100000' 
     d prior           c                   x'00001000' 
     d data_only       c                   x'00000002' 
     d nulkey_map      c                   x'00000008' 
 
     d read_next       c                   3 
     d read_prev       c                   4 
 
      *------- Null capable field option values (I/O) 
     d notnul_val      c                   '0' 
     d nul_val         c                   '1' 
     d map_error       c                   '2' 
 
     d dk_yes          c                   1 
     d dk_no           c                   0 
 
      *------- IO operation potential errors 
     d etrunc          c                   3003 
     d enotopen        c                   3004 
     d enotread        c                   3005 
     d erecio          c                   3008 
     d enotwrite       c                   3009 
     d enorec          c                   3026 
     d enotupd         c                   3041 
     d enotdlt         c                   3042 
     d eioerror        c                   3101 
     d eiorecerr       c                   3102 
 
     d eof             s             10i 0 inz(-1) 
     d rc              s             10i 0 
     d errnum          s             10i 0  based(perrnum) 
 
     d                 ds 
     d  nopts                        10i 0 
     d   aopts                        4a   overlay(nopts) 
 
      *------------------------------------------------------------------ 
      * I/O record access feedback data structures 
      *------------------------------------------------------------------ 
     d riofb_t         ds                  based(rfb) 
     d  key@                           * 
     d  sysparms                       * 
     d  rrn                          10u 0 
     d  num_bytes                    10i 0 
     d  blk_count                     5u 0 
     d  blk_fillby                    1a 
      * dup_key(bit 1) + icf_locate(bit 2) + resrvd1(bits 3-8) * 
     d  mixed_bits                    1a 
     d  resrvd2                      20a 
 
     d rfile           ds                  based(fp) 
     d  reserved1                    16a 
     d  in_buf                         * 
     d  out_buf                        * 
     d  reserved2                    48a 
     d  riofb@                             like(riofb_t) 
     d  reserved3                    32a 
     d  buf_length                   10u 0 
     d  reserved4                    28a 
     d  innullmap                      * 
     d  outnullmap                     * 
     d  nullkeymap                     * 
     d  reserved5                    48a 
     d  min_length                   10i 0 
     d  nullmaplen                    5u 0 
     d  nullkmapln                    5u 0 
     d  reserved6                     8a 

[B]  d/copy qrpglesrc,recioh
 
      *================================================================= 
      *               I 
      * MCPressOnline I  Recioh - RPG prototypes for  
      *               I 
      *               I 
      *               I Note: Unless otherwise specified, most every  
      *               I       character string must be null-terminated. 
      *               I       Add an 'f' suffix to function prototypes 
      *               I       names to avoid ambiguity with free-form  
      *               I       RPGIV opcodes.   
      *================================================================= 
      *------------------------------------------------------------------ 
      * Prototype for _Riofbk(). 
      *------------------------------------------------------------------ 
     d iofbk           pr              *   ExtProc('_Riofbk') 
     d                                 *   value 
      *------------------------------------------------------------------ 
      * Prototype for _Ropen(). 
      *------------------------------------------------------------------ 
     d open            pr              *   ExtProc('_Ropen') 
     d                                 *   value 
     d                                 *   value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Ropnfbk(). 
      *------------------------------------------------------------------ 
     d openfbk         pr              *   ExtProc('_Ropnfbk') 
     d                                 *   value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rlocate(). 
      *------------------------------------------------------------------ 
     d locate          pr              *   ExtProc('_Rlocate') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
     d                               10i 0 value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rreadk(). 
      *------------------------------------------------------------------ 
     d readk           pr              *   ExtProc('_Rreadk') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
     d                               10i 0 value 
     d                                 *   value 
     d                               10u 0 value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rreadn(). 
      *------------------------------------------------------------------ 
     d readn           pr              *   ExtProc('_Rreadn') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
     d                               10i 0 value options(*nopass) 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rreadd(). 
      *------------------------------------------------------------------ 
     d readd           pr              *   ExtProc('_Rreadd') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
     d                               10i 0 value 
     d                               10i 0 value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rreadf(). 
      *------------------------------------------------------------------ 
     d readf           pr              *   ExtProc('_Rreadf') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
     d                               10i 0 value options(*nopass) 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rreadl(). 
      *------------------------------------------------------------------ 
     d readl           pr              *   ExtProc('_Rreadl') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
     d                               10i 0 value options(*nopass) 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rreadp(). 
      *------------------------------------------------------------------ 
     d readp           pr              *   ExtProc('_Rreadp') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
     d                               10i 0 value options(*nopass) 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rupdate(). 
      *------------------------------------------------------------------ 
     d update          pr              *   ExtProc('_Rupdate') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rwrite(). 
      *------------------------------------------------------------------ 
     d write           pr              *   ExtProc('_Rwrite') 
     d                                 *   value 
     d                                 *   value 
     d                               10i 0 value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rdelete(). 
      *------------------------------------------------------------------ 
     d delete          pr              *   ExtProc('_Rdelete') 
     d                                 *   value 
 
      *------------------------------------------------------------------ 
      * Prototype for _Rclose(). 
      *------------------------------------------------------------------ 
     d close           pr            10i 0 ExtProc('_Rclose') 
     d                                 *   value 
 
      *------------------------------------------------------------------ 
      * Prototype for errno(). 
      *------------------------------------------------------------------ 
     d errno           pr              *   ExtProc('__errno') 
 
      *------------------------------------------------------------------ 
      * Prototype for clearerr(). 
      *------------------------------------------------------------------ 
     d clearerr        pr                  ExtProc('clearerr') 
     d                                 *   value 
         :
[C]  d printf          pr                 extproc('printf')
     d                                 *  value options(*string)
     d                                 *  value
     d                                    options(*string:*nopass)
     d                                 *  value 
     d                                    options(*string:*nopass)
                       :
      *----------------------------------------------------------
      *  Global variables & constants
      *----------------------------------------------------------
     d failure         s               n   inz(*Off)
     d success         s               n   inz(*On)
     d exception       s               n 
     d newline         c                    x'25'

[D]  d buffer        e ds                   extName(customer)
                       :

     d fp              s               *   
     d file            s             10a    inz('CUSTOMER')
     d lib             s             10a    inz('*LIBL')
[E]  d ofile           s             50a
     d oopts           s             24a    inz('rr, nullcap=Y, + 
     d                                      blkrcd=Y')
     d nullkey         s               *
    

     d @nolock         s             10i 0
     d @dft            s             10i 0
     d @key_ge         s             10i 0
     d @setll          s             10i 0
     d @prior          s             10i 0
     d @data           s             10i 0
     d @loval          s             10i 0

      *
      * Set file positioning and read options.
[F]   *
     c                   eval      aopts = key_ge
     c                   eval      @key_ge = nopts
     c                   eval      aopts = prior
     c                   eval      @prior = nopts
             :
     c                   eval      @loval = ior(@first:@prior)
     c                   eval      @setll = ior(@key_ge:@prior)
             :
     c                   eval      ofile =  %trim(lib) + '/'
     c                                       +  %trim(file)
     c                                       +  ' (*first)'
     c                                       + x'00'
     c                   eval      oopts =  %trim(oopts) 
     c                                          + x'00'
[G]  c                   eval      fp = open(%addr(ofile)
     c                                      :%addr(oopts))

open() Arguments:
1: Pointer to file name string
2: Pointer to open options
Return:

Pointer to file ODP


     c                   if          ( fp = *null )
     c                   callp(e) printf('Open failed for %s'
     c                                   + newline
     c                                  :ofile)
     c                   eval      *inlr = *on
     c                   return
     c                   endif
                                 – this –  
     c                   eval      rfb = locate(fp
     c                                         :%addr(nullkey)
     c                                         :0
     c                                         :@loval)

                                 – or –
     c                   eval      %str(%addr(keydata)
     c                    :%size(keydata))
     c                                 = %subst(keydata:1:inlen)
[H]
     c                   eval      rfb = locate(fp
     c                                 :%addr(keydata)
     c                                 :inlen
     c                                 :ior(ior(@setll:@nolock):@data))

locate() Arguments:
1: File pointer (fp)
2: Pointer to key data or null pointer
3: Length of key data or 0 when null pointer
4: Record processing options
Return:
Pointer to record feedback area (rfb)


     c                   if        ( num_bytes = *zero )
     c                   callp(e) printf('Positioning failed for '
     c                                      + 'file %s key %s'
     c                                      + newline
     c                                      :ofile
     c                                      :keydata)
     c                  eval      *inlr = *on
     c                  return
     c                  endif

     c                  callp     registerHdlr(pIgnDtaExc
     c                                       :%addr(exception)
     c                                       :*omit)
     c                  dow      (not exception and num_bytes <>eof)
     c                  eval      rfb = readn(fp
     c                                    :%addr(buffer)
     c                                    :%size(buffer)
     c                                    :@nolock)

readn() Arguments:
1: File pointer (fp)
2: Pointer to data buffer format (buffer for customer record)
3: Size of customer record buffer
4: Record processing options
Return:
Pointer to record feedback area (rfb)


     c                   if        ( exception or num_bytes = eof )
     c                   iter
     c                   endif
[I]        
                  (do some processing)
:
     c                   if        ( is_field_null(innullmap 
     c                              :nullmaplen :5) )
     c                   callp(e)  printf('Customer: %s'
     c                                    + newline
     c                                    + 'City,State: %s'
     c                                    + newline
     c                                    + '** Discount is null **'
     c                                    + newline
     c                                    + newline
     c                                   :name
     c                                   :%trim(city) + ',' + state)
     c                   else
     c                   callp(e) printf('Customer: %s'
     c                                         + newline
     c                     + 'City,State: %s'
     c                                         + newline
     c                                         + newline
     c                                        :name
     c                                        :%trim(city) + ',' + state)
     c             endif
     c             enddo
                
     c             callp     unregisterHdlr(pIgnDtaExc
     c                                      :*omit)

              :
[J]  c             callp(e)  close(fp)

close() Arguments:
1: File pointer (fp)
Return:
Return code = 0 if successful, eof (–1) if unsuccessful

     c             eval      fp = *null
              :
              :
              :

      *----------------------------------------------------------
     p ignDtaExc       b                       export
      *----------------------------------------------------------
     d                 pi
     d pcondToken                          *   value
     d puserToken                          *
     d resultCode                        10i 0
     d newCondTok                        12a

     d condToken       ds                      based(pCondToken)
     d  severity                          5u 0
     d  msgNbr                            2a
     d  bitFields                         1a
     d  facilityId                        3a
     d  msgRefKey                        10u 0

     d exception        s                  n   based(puserToken)
[K2]
     c                   eval      exception = *on
     c                   eval      resultCode = resume

     c                   return
      *--------------------------------------------------------
     p ignDtaExc       e
      *--------------------------------------------------------

Figure 1: This I/O paradigm for RPG uses C I/O.

Close examination of the /Copy members recioth and recioh ([A] and [B], respectively, in Figure 1) reveals the type definitions and prototypes (shown, in italicized code fragments immediately after the copy member statements) required to effectively use C I/O in an RPG IV application or function. Stepping through a few of these will demonstrate their purpose and ease of use. There are a few steps that, if you understand them well, will help you use C I/O with the same confidence and proficiency as you currently use RPG I/O opcodes. They are listed below:

1. Declare Files

Ensure the file name string variable (ofile in [E]) is properly initialized with the desired file name (either fully qualified to the exact library/file [member] or defaulted to *LIBL) and null-terminated (as shown in the top portion of [G]). In this case, the file name is initialized to "*LIBL/CUSTOMER(*first)".

2. Set Access Options

Ensure the file open options (oopts in [E]) are null-terminated (as shown in the top portion of [G]) and properly initialized with your desired access requirements. In this case, rr means read-only access; for other options, refer to the ILE C/C++ Run-Time Library Reference (SC09-2715-00).

3. Set Processing Options

Ensure your file processing options are properly defined (recioth in [A]) and combined in the proper manner to enable your desired access. To combine the file processing options, they can be ORed as shown in [F] of Figure 1, created with the ior function written in C as shown in Figure 2 below, or written in RPG IV as shown in Figure 3 below.

4. Specify C I/O Function Calls for Desired Processing

Using the file name string and file processing options integer variables defined in previous steps and the declared C I/O prototypes (declared in recioh and shown throughout Figure 1 in the [B] labels), make the following calls:

Open (_Ropen) the desired file and ensure the file pointer (fp in [E]) is not *null (as shown in [G]). Otherwise, send an error message using the printf function as shown in a previous article, "What? RPG IV a Better C Than C?", and prototyped in [C].

Position (_Rlocate) the file cursor where desired (using either an appropriate key value string null-terminated or the equivalent of *loval as shown in [H]) and verify successful positioning by ensuring the num_bytes variable is zero. Otherwise, send an error message with the printf function and end the program.

Loop and read (_Rreadn) records from the file (pointed to by fp) into the buffer (pointed to by taking the %addr of buffer redefined by your file's external definition--in this case, Customer as shown in [D]--for the %size of buffer as shown in [I]).

Close (_Rclose) the file (pointed to by fp) and set the pointer to *null if your program is reentrant (as shown in [J]). Then, end the program.

5. Implement Proper Error Handling

Use language-independent condition handlers (as implemented in [K1] and [K2]) and check C record feedback fields (as defined in [H] for the locate operation and [I] for the read operation) to ensure file conditions are detected and responded to in the proper manner.

Those are the basic steps you need to know to effectively use C I/O functions in your RPG IV applications.

/*                                                                 */
/** C Utility prototypes                                           */
/*                                                                 */
int ior(int, int);

/*                                                                 */
/** Inclusive Or                                                   */
/*                                                                 */
int ior(int, int);

int ior(int a, int b)
{
   return a | b;
}

Figure 2: This is the "C inclusive OR" (CIOR) utility.

      *--------------------------------------------------------------
     p ior             b                        
      *--------------------------------------------------------------
     d                 pi               10i 0
     d int1                             10i 0   value
     d int2                             10i 0   value

     d                 ds
     d  num_val1                        10i 0
     d    alphval1                       1a     overlay(num_val1) dim(4)
     d  num_val2                        10i 0
     d    alphval2                       1a     overlay(num_val2) dim(4)
     d  res_val                         10i 0
     d    rsa                            1a     overlay(res_val) dim(4)

     d vidx            s                5u 0
     d idx             s                5u 0
     d bitc            s                5u 0
     d alphval         s                1a      dim(4)

     c                   eval      num_val1 = int1
     c                   eval      num_val2 = int2
     c                   clear                   res_val
     c                   do        2             vidx
     c                   if        ( vidx = 1 )
     c                   eval           alphval = alphval1
     c                   else
     c                   eval           alphval = alphval2
     c                   endif

     c                   do        4             idx
     c                   do        8             bitc

     c                   clear                   *in41
     c                   select
     c                   when      bitc = 1
     c                   testb     '0'           alphval(idx)         41
     c                   when      bitc = 2
     c                   testb     '1'           alphval(idx)         41
     c                   when      bitc = 3
     c                   testb     '2'           alphval(idx)         41
     c                   when      bitc = 4
     c                   testb     '3'           alphval(idx)         41
     c                   when      bitc = 5
     c                   testb     '4'           alphval(idx)         41
     c                   when      bitc = 6
     c                   testb     '5'           alphval(idx)         41
     c                   when      bitc = 7
     c                   testb     '6'           alphval(idx)         41
     c                   when      bitc = 8
     c                   testb     '7'           alphval(idx)         41
     c                   endsl

     c                   if        not *in41
     c                   select
     c                   when      bitc = 1
     c                   biton     '0'           rsa( idx )
     c                   when      bitc = 2
     c                   biton     '1'           rsa( idx )
     c                   when      bitc = 3
     c                   biton     '2'           rsa( idx )
     c                   when      bitc = 4
     c                   biton     '3'           rsa( idx )
     c                   when      bitc = 5
     c                   biton     '4'           rsa( idx )
     c                   when      bitc = 6
     c                   biton     '5'           rsa( idx )
     c                   when      bitc = 7
     c                   biton     '6'           rsa( idx )
     c                   when      bitc = 8
     c                   biton     '7'           rsa( idx )
     c                   endsl
     c                   endif

     c                   enddo
     c                   enddo

     c                   enddo

     c                   return       res_val
      *-------------------------------------------------------------
     p ior               e
      *-------------------------------------------------------------


Figure 3: This is the "RPG inclusive OR" (RPGIOR) function.


By Way of Example

The example program of Figure 1 reads through the Customer file and prints the customer name, city, and state, double-spaced to the display. When the program encounters a customer with a null value for the discount field, it will print an additional line to indicate so.

An Inclusionary OR?

In addition, to "OR" the file access options together, rather than using the ior function (as implemented in Figure 2 with the "|", which requires a C compiler), you can instead implement the code shown in Figure 3 as an RPG IV subprocedure and use the same prototype shown at the top of Figure 1. It is a bit clumsy, comparatively speaking, and can be replaced in V5R2 with the more elegant %OR BIF that one could safely assume will permit a simple format like the following:

eval     result_int  =  %or(int1 : int2)


This would allow you to replace the code in [F] of Figure 1 like so:

eval     @loval = %or(@first : @prior)
eval     @setll = %or(@setll : @prior)


This is much more satisfying than maintaining the bulkier RPG subprocedure depicted in Figure 3 or resorting to another language, as depicted in Figure 2, to obtain the required functionality.

Managing Your Null-Capable Fields

Null field values can be detected by checking the field null indicator array defined in recioth in the file information data structure (rfile in Figure 1, adjacent to [A]), pointed to by the file pointer fp, and identified by the pointers innullmap and outnullmap, depending on the type of operation executed. The innullmap is interrogated on an input operation when you want to determine if the field currently in the record buffer is a null value or not (a null field will be set to the default value for the field data type, *blanks for alpha and *zeros for numeric, in the record buffer). The outnullmap should be set just prior to writing a record, but the innullmap should be set just prior to updating a record. Set the field array indicator to *off when the relative field value to be updated is not null, and set the field array value to *on when you want to set the relative field value to *nulls.

Also shown in [I] of Figure 1 is the use of the is_field_null prototyped in [L] of Figure 1 and shown in its entirety in Figure 4.

      *-------------------------------------------------------------
     p is_field_null...
     p                 b
      *-------------------------------------------------------------
     d                 pi              n
     d pnullmap                        *   value
     d len_nullmap                   10u 0 value
     d field                         10u 0 value

     d fldary          s              1a   dim(32767) based(pnullmap)

     c                   if        ( len_nullmap < field )
     c                   return     failure
     c                   endif

     c                   return     ( fldary(field) = *on )
      *------------------------------------------------------------
     p is_field_null...
     p                 e
      *------------------------------------------------------------

      *------------------------------------------------------------
     p set_null_map...
     p                 b
      *------------------------------------------------------------
     d                 pi
     d pnullmap                        *   value
     d len_nullmap                   10u 0 value
     d null_value                     1a   value options(*nopass)
     d field                         10u 0 value options(*nopass)

     d index           s             10u 0
     d null_setting    s              1a   inz(*off)
     d fld             s             10u 0
     d fldary          s              1a   dim(32767) based(pnullmap)

     c                   if        ( %parms > 2 )
     c                   eval      null_setting = null_value
     c                   endif

     c                   if        ( %parms > 3 )
     c                   eval      fld = field
     c                   endif

     c                   if        ( fld = *zero )
     c                   do        len_nullmap   index
     c                   eval      fldary(index) = null_setting
     c                   enddo
     c                   else
     c                   if        ( len_nullmap >= field )
     c                   eval      fldary(field) = null_setting
     c                   endif
     c                   endif

     c                   return
      *-----------------------------------------------------------
     p set_null_map...
     p                 e
      *-----------------------------------------------------------

Figure 4: This is an example of null map handling in RPG IV.

This function takes three arguments (a pointer to a file field null map, the length of the null map, and an ordinal integer value for representing the field in the file to test for nulls). It returns a Boolean value of true or false, depending on whether or not the field identified in the third argument contains nulls. Note that the pointer is passed by value to this function rather than used as a basing pointer in the main procedure of the program. The reason for this is not only for the purpose of efficiency and reuse of logic, but also because the null map pointers (input used on read-only and update access; output used on writes) are defined in the file information data structure (rfile in Figure 1, depicted in the window adjacent to [A]) as const * (or constant pointers). This ensures that the pointer cannot be changed (or referred) directly, or used as a basing pointer, without providing one level of indirection (or a copy of the pointer rather than the actual pointer itself).

The is_field_null and the set_field_null functions, shown in Figure 4, are defined as much for functionality as for practicality. This point can go unnoticed if you are using the C I/O functions within the scope of a C program, because all arguments are passed by value to C functions. So you would not experience any problems in referring to the pointer directly, as it is a copy and not the actual pointer.

Handling the Unexpected

The registration and de-registration of a condition handler prototyped in [K1] and defined in [K2] is shown in [I]. The condition handler allows the programmer to pass a reference to a Boolean (n-data type) or a program indicator that will be set on in the event of an I/O exception during the read and allows the program to resume without causing an abnormal exception condition to be raised. Additionally, the num_bytes variable (defined in the recioth riob_t data structure, pointed by rfb, and returned in both the locate and read operations) is interrogated for equivalence to eof (an integer defined in recioth with a value of –1) to determine if an end-of-file condition has been reached. You can also provide more granular error handling by retrieving the error number (using the __errno C function) and printing the error (using the perror C function) and/or by interrogating the condition token fields shown in [K2]. However, that is beyond the topic of discussion in this article.

Another unexpected situation may arise if you are using the included C I/O prototypes in free-form ILE RPG IV style. For example, if you mix the C I/O prototype close() in free-form ILE RPG, the compiler will not be able to implicitly resolve the ambiguity of having two close operations: the C I/O close() and the RPG IV free-form close(). You see, in free-form RPG IV, the close operation has an implicit first argument that allows specification of the operational extender in free-form style, like so: close(E). To resolve this ambiguity, rename your C I/O prototypes by adding an "f" suffix character to each function, like so:

d  closef            pr      10i  0  extproc('_Rclose')
d    file_pointer             *     value


So remember: To avoid ambiguities when using free-form RPG IV, always add a suffix character to C I/O operations to distinguish them from free-form RPG IV I/O operations.

Give It a Whirl, and Stay Tuned to MC Mag Online

As I mentioned earlier, the complete code for this article can be downloaded from the MC Press Web site. It contains the SQL source statements necessary to create and populate the Customer file with records to test this application on your system. Notwithstanding your current application requirements, future applications will be better leveraged to take advantage of opportunities posed by industrious users, and your response time in meeting new feature requirements will be considerably improved by using C I/O rather than RPG I/O opcodes. This leaves you with more time to read the next article in this series, "Interfaces in ILE RPG IV--Finding the Middle Ground," which describes implementing interfaces in RPG IV and is accompanied by a Java source program to keep you awake! How could life be better?


Jim Barnes is a freelance writer and independent consultant working in Houston, Texas. Jim can be reached at This email address is being protected from spambots. You need JavaScript enabled to view it..



Jim D. Barnes is a freelance writer and Systems Engineer in Plano, Texas.

BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

$0.00 Raised:
$

Book Reviews

Resource Center

  • SB Profound WC 5536 Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. You can find Part 1 here. In Part 2 of our free Node.js Webinar Series, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Brian will briefly discuss the different tools available, and demonstrate his preferred setup for Node development on IBM i or any platform. Attend this webinar to learn:

  • SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation. Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects. The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the company are not aligned with the current IT environment.

  • SB HelpSystems ROBOT Generic IBM announced the E1080 servers using the latest Power10 processor in September 2021. The most powerful processor from IBM to date, Power10 is designed to handle the demands of doing business in today’s high-tech atmosphere, including running cloud applications, supporting big data, and managing AI workloads. But what does Power10 mean for your data center? In this recorded webinar, IBMers Dan Sundt and Dylan Boday join IBM Power Champion Tom Huntington for a discussion on why Power10 technology is the right strategic investment if you run IBM i, AIX, or Linux. In this action-packed hour, Tom will share trends from the IBM i and AIX user communities while Dan and Dylan dive into the tech specs for key hardware, including:

  • Magic MarkTRY the one package that solves all your document design and printing challenges on all your platforms. Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product. Make sure your data survives when catastrophe hits. Request your trial now!  Request Now.

  • SB HelpSystems ROBOT GenericForms of ransomware has been around for over 30 years, and with more and more organizations suffering attacks each year, it continues to endure. What has made ransomware such a durable threat and what is the best way to combat it? In order to prevent ransomware, organizations must first understand how it works.

  • SB HelpSystems ROBOT GenericIT security is a top priority for businesses around the world, but most IBM i pros don’t know where to begin—and most cybersecurity experts don’t know IBM i. In this session, Robin Tatam explores the business impact of lax IBM i security, the top vulnerabilities putting IBM i at risk, and the steps you can take to protect your organization. If you’re looking to avoid unexpected downtime or corrupted data, you don’t want to miss this session.

  • SB HelpSystems ROBOT GenericCan you trust all of your users all of the time? A typical end user receives 16 malicious emails each month, but only 17 percent of these phishing campaigns are reported to IT. Once an attack is underway, most organizations won’t discover the breach until six months later. A staggering amount of damage can occur in that time. Despite these risks, 93 percent of organizations are leaving their IBM i systems vulnerable to cybercrime. In this on-demand webinar, IBM i security experts Robin Tatam and Sandi Moore will reveal:

  • FORTRA Disaster protection is vital to every business. Yet, it often consists of patched together procedures that are prone to error. From automatic backups to data encryption to media management, Robot automates the routine (yet often complex) tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:

  • FORTRAManaging messages on your IBM i can be more than a full-time job if you have to do it manually. Messages need a response and resources must be monitored—often over multiple systems and across platforms. How can you be sure you won’t miss important system events? Automate your message center with the Robot Message Management Solution. Key features include:

  • FORTRAThe thought of printing, distributing, and storing iSeries reports manually may reduce you to tears. Paper and labor costs associated with report generation can spiral out of control. Mountains of paper threaten to swamp your files. Robot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing. Manage your reports with the Robot Report Management Solution. Key features include:

  • FORTRAFor over 30 years, Robot has been a leader in systems management for IBM i. With batch job creation and scheduling at its core, the Robot Job Scheduling Solution reduces the opportunity for human error and helps you maintain service levels, automating even the biggest, most complex runbooks. Manage your job schedule with the Robot Job Scheduling Solution. Key features include:

  • LANSA Business users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.

  • LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed. Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

  • LANSASupply Chain is becoming increasingly complex and unpredictable. From raw materials for manufacturing to food supply chains, the journey from source to production to delivery to consumers is marred with inefficiencies, manual processes, shortages, recalls, counterfeits, and scandals. In this webinar, we discuss how:

  • The MC Resource Centers bring you the widest selection of white papers, trial software, and on-demand webcasts for you to choose from. >> Review the list of White Papers, Trial Software or On-Demand Webcast at the MC Press Resource Center. >> Add the items to yru Cart and complet he checkout process and submit

  • Profound Logic Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.

  • SB Profound WC 5536Join us for this hour-long webcast that will explore:

  • Fortra IT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators with intimate knowledge of the operating system and the applications that run on it is small. This begs the question: How will you manage the platform that supports such a big part of your business? This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn: