Manipulating the Library List from Within RPG

  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

Even though many people say the iSeries 400 is a closed and proprietary system, it does offer a huge number of "openness" application program interfaces (APIs).

I remember years ago when IBM Rochester held the first meetings to discuss the idea of adding APIs to the system. The first set of APIs included User Space, User Index, and Data Queue APIs. At the time, all the API names were designed to begin with the letters QUS. The "US" identifier stood for "USER"--IBM's term for "programmer" back then.

Today, there are so many APIs that the manual itself is over 3,000 pages long! I don't know the exact number of APIs available in OS/400, but it's hundreds and hundreds if not well over a thousand by now. So the naming convention of QUSxxxxx has long since been retired.

Rather than attempt to keep track of all the APIs and their purpose in life, I've tried to maintain an easy way to search and review the APIs I may need. I keep a copy of the OS/400 System API Reference manual in PDF form on my PC. When a new release of OS/400 becomes available, I usually download an updated copy of the API manual. It is available at

What Good Are APIs?

APIs provide a program interface to system routines. Just like the CL command interface provides access to virtually every system function, APIs provide a way for high-level language (HLL) programs to run these same types of system functions.

For example, suppose you need to retrieve a system value while you're inside an RPG IV program. You could simply write a CL program that calls the RTVSYSVAL command and then return the corresponding value to the RPG program through a parameter; nothing wrong with that.

Using APIs, however, you could simply call the same interface that the RTVSYSVAL command uses from within RPG. The API is QWCRSVAL. A cool thing about the APIs is that added function is often provided. For example, the QWCRSVAL API allows you to retrieve several system values simultaneously. You could, for example, retrieve all the password-related system values with one call to QWCRSVAL.

Two very interesting APIs are the Retrieve Job Information API (which I use to retrieve the library list) and the Change Library List) API. These allow you to, as expected, retrieve or change the library list from within an HLL. But the great thing about these APIs, particularly the Change Library List API, is that they allow you to actually set the so-called product libraries as well as the current library and the library list.

Change Library List (QLICHGLL)

QLICHGLL allows you to modify the library list for your job. As I mentioned, you can change the regular "user portion" of the library list as well as the two product libraries and the current library.

Current library
Product library 1
Product library 2
User library list
Array of Char(11)
User library list count
Int(4) in RPG 9B0 or 10i0
Standard API error data structure

The first parameter is the current library name. It must be specified (it cannot be blank), and it must be left-justified with a trailing blank. In addition to any valid library name, the current library parameter accepts the following special values:

*SAME--The current library is not changed.

*CRTDFT--There is no current library. The CRTxxxPGM command will use QGPL as the default library name.

The product library parameters have the same restrictions as the current library parameter. In addition, the product library parameters accept the following special values:

*NONE--The product library (if any) is removed. Either product library 1 or 2 may have this value.

*SAME--The product library is not changed. Either product library 1 or 2 may have this value.

The user library list parameter is an array of 11-position character values. Each array element may contain a library name, left-justified with a trailing blank in position 11.

The user library list count parameter tells the API how many library names have been specified in the User Library List. Effectively, this is the number of used array elements. This value is a 4-byte binary or 4-byte integer field.

The final parameter is the standard API error data structure. Often, we just ignore that parameter by passing it a value of X'00'.

The following CPF error messages may be generated by the QLICHGLL API:
CPF2106 Library list not changed.
CPF2110 Library &1 not found.
CPF2113 Cannot allocate library &1.
CPF2133 First product library on library list destroyed.
CPF2134 Second product library on library list destroyed.
CPF2137 Current library on library list destroyed.
CPF2176 Library &1 damaged.
CPF2182 Not authorized to library &1.
CPF2184 Library list not replaced.
CPF219A Library QTEMP cannot be specified.
CPF219F Number of libraries for library list not valid.
CPF24B4 Severe error while addressing parameter list.
CPF3C90 Literal value cannot be changed.
CPF3CF1 Error code parameter not valid.
CPF9872 Program or service program &1 in library &2 ended. Reason code &3.

Retrieve Job Information (QUSRJOBI)

The QUSRJOBI API is an old API, but it has been continually updated throughout the years. QUSRJOBI can retrieve most information about the current running job, including the library list.

Library list
Length of first parameter variable
Format name
Char(8) 'JOBI0700'
Qualified job name
Internal job identifier
Standard API error data structure

The first parameter, library list, is a return value--a data structure that contains all the libraries on the library list, including system portion, user portion, product libraries, and the current library name. Note that the QLICHGLL API does not support changing the system portion of the library list. But that is typically never done in production code, so this shouldn't be an issue.

The second parameter is the length of the data structure being used to receive the library list (i.e., the length of the first parameter).

The third parameter is the name of the format used by the API. This format controls what type of information the API returns. The QUSRJOBI API can return a lot of different information, so the convention for this and many other APIs is to accept a format ID that indicates which pieces of information the API should return. To retrieve the library list, format ID 'JOBI0700' is passed.

The fourth parameter is the qualified job name for the job whose information is being retrieved. Yes, you can retrieve the library list for another job if you want. But a more practical use is to retrieve the library list for the current job. So rather than pass in a 26-byte data structure simply create a field that is 26 positions in length and set the first character of the field to an asterisk (*). Leave the rest of the field blank.

The fifth parameter is the internal job name. Leave this parameter blank.

The sixth and final parameter is the standard API error data structure.

Wrapping It All Up

Logically, we would need to call QUSRJOBI to retrieve the current library list, modify the list, and then call QLICHGLL to set the list to what we want.

But wouldn't it be more useful to have this function wrapped in a usable RPG IV procedure? Listed in Figure 1 is the RPG IV source for two procedure prototypes, and they are:

GETLIBL--Retrieve the library list for the job.

SETLIBL--Change the library list to the new list specified.

To use the procedures, you need to include the prototypes for them in your code using either the /COPY or /INCLUDE compiler directives.

      ** GETLIBL - Retrieve the specified library list
      **   Usage:  libl = GetLibl( list-type : rtn-Count )
      **   Note: all parameters are optional.

      **   Return Value:
      **     LIBL - An array that receives the library list.
      **   Parameters:
      **     RTN-COUNT - An optional variable that recieves
      **                 a count of the number of library returned.
      **     LIST-TYPE - An optional parameter that controls which
      **                 library list is to be returned. The named
      **                 constants in the LIBL include member may
      **                 be used for this value.

     D GetLibl         PR            11A   DIM(250)
     D  lType                         5I 0 Const Options(*NOPASS)
     D  nLiblCount                    5I 0 Options(*NOPASS)

      ** SETLIBL – Set (change) the library list
      **   Usage:  libl = SetLibl( libl : list-type )

      **   Return Value:
      **     Reserved -  Nothing returned at this time.
      **   Parameters:
      **     LIBL      - An array of 11-character elements.
      **                 Each library name to be placed on the library
      **                 must be stored in a corresponding element.
      **     LIST-TYPE - An optional parameter that controls which
      **                 library list is to be changed. The named
      **                 constants in the LIBL include member may
      **                 be used for this value. The default is
      **                 the user portion of the library list.
     D SetLibl         PR             1N
     D  Libl                         11A   Const DIM(250)
     D  lType                         5I 0 Const Options(*NOPASS)

      ** ADDLIBLE – Add Library List Entries
      **   Usage:  count = AddLiblE( libl : pos-lib : before/after-flag) )

      **   Return Value:
      **     count     - A count of the number of libraries on the library list.
      **   Parameters:
      **     LIBL      - A character string of one or more library 
      **                 names separated by one or more blanks.
      **     POSLIB    - An optional parameter that may contain the 
      **                 name of a library used to control the placement
      **                 of the library names being added to the list.
      **                 Special values *FIRST, and *LAST may also be 
      **                 specified to insert the library names at the start
      **                 or end of the library list.
      **     POS       - An optional parameter that indicates the order
      **                 in which the new library name(s) are inserted
      **                 into the library list. *ON = BEFORE the POSLIB
      **                                        *OFF = AFTER the POSLIB
     D AddLiblE        PR            10I 0
     D  InLibl                     2750A   Const VARYING
     D  PosLib                       10A   Const VARYING
     D                                     Options(*NOPASS)
     D  Pos                           1N   Const
     D                                     Options(*NOPASS)

      ** Library list types (parameter 1) named constants
     D llUSRLIBL       C                   Const(0)
     D llCURLIB        C                   Const(1)
     D llSYSLIBL       C                   Const(2)
     D llPRODLIBL      C                   Const(3)

Figure 1: Prototypes for Library List Procedures

Listed in Figure 2 is the RPG IV source for two procedures that wrap the functionality of these two APIs to provide a simplified interface to their function.


      ** Maximum libraries allowed on library list
     D MAXLIBL         C                   Const(250)
      ** Field reference for Library Name (APIs use 11-pos name)
     D LIBNAME         S             11A
      ** API Error data structure
     D ll_Error        DS                  EXPORT
     D  ll_DSLen                     10I 0 Inz(%Size(ll_Error))
     D  ll_ByteRtn                   10I 0 Inz
     D  ll_cpfmsgid                   7A
     D  ll_reserved                   1A
     D  ll_msgdata                  132A

     D QUSRJOBI        PR                  EXTPGM('QUSRJOBI')
     D  libl                       6000A   OPTIONS(*VARSIZE)
     D  nLibl                        10I 0 Const
     D  FmtName                       8A   Const
     D  Job                          26A   Const
     D  InternJob                    16A   Const
     D  Api_Error                    16A

     D QLICHGLL        PR                  EXTPGM('QLICHGLL')
     D  CurLib                       11A   Const
     D  ProdLib1                     11A   Const
     D  ProdLib2                     11A   Const
     D  UsrLibl                      11A   Const DIM(MAXLIBL)
     D  nUsrLiblCount                10I 0 Const
     D  Api_Error                    16A

     ** ------------------------------------------
     ** G E T L I B L -- (Get Library List)
     ** ------------------------------------------
     P GetLibl         B                   EXPORT
      ** GETLIBL - Retrieve the specified library list
      **   Usage:  libl = GetLibl( list-type : rtn-Count )
      **   Note: all parameters are optional.

      **   Return Value:
      **     LIBL - An array that receives the library list.
      **   Parameters:
      **     RTN-COUNT - An optional variable that recieves
      **                 a count of the number of library returned.
      **     LIST-TYPE - An optional parameter that controls which
      **                 library list is to be returned.
      **                 Use the named constants in the prototype
      **                 include member for the LIST-TYPE.
     D GetLibl         PI            11A   DIM(250)
     D  lType                         5I 0 Const Options(*NOPASS)
     D  nLiblCount                    5I 0 Options(*NOPASS)

      ** Return value is returned in LIBLARRAY
     D Libl            DS
     D* LiblArray                          DIM(LMAXLIBL) LIKE(LIBNAME)
      ** Due to a bug in the RPG compiler, a global named constant
      ** cannot be specifed on the DIM keyword. :(
     D  LiblArray                          DIM(250) LIKE(LIBNAME)

     D nCount          S             10I 0
     D nSysLSize       S             10I 0
     D nUsrLSize       S             10I 0
     D nCurLSize       S             10I 0
     D nProdLSize      S             10I 0

     DLiblDS           DS                  INZ
     D nBytesRtn                     10I 0
     D nBytesAvail                   10I 0
     D j_Name                        10A
     D j_User                        10A
     D j_Nbr                          6A
     D ij_ID                         16A
     D j_Status                      10A
     D j_Type                         1A
     D j_subtype                      1A
     D j_Reserved                     2A
     D nSysLib                       10I 0
     D nProdLib                      10I 0
     D nCurLib                       10I 0
     D nUsrLib                       10I 0
     D LibLists                    3100A

     D SysLibl         s           2750A   Based(pSysLibl)
     D ProdLibl        s           2750A   Based(pProdLibL)
     D CurLib          s           2750A   Based(pCurLib)
     D UsrLibl         s           2750A   Based(pUsrLibl)

     C                   CALLP     QusRJobI(LiblDS : %Size(LiblDS):
     C                              'JOBI0700' : '*' : ' ' : ll_Error)

     C                   Eval      nSysLSize  = nSysLib  * %size(LibName)
     C                   Eval      nProdLSize = nProdLib * %size(LibName)
     C                   Eval      nCurLSize  = nCurLib  * %size(LibName)
     C                   Eval      nUsrLSize  = nUsrLib  * %size(LibName)

     C                   Eval      pSysLibl  = %addr(LibLists)
     C                   Eval      pProdLibl = pSysLibl + nSysLSize
     C                   Eval      pCurLib   = pProdLibl + nProdLSize
     C                   Eval      pUsrLibl  = pCurLib + nCurLSize

     C                   Select
     C                   When      %Parms = 0 or lType = llUsrLibl
     C                   eval      Libl = %subst(UsrLibl : 1 : nUsrLSize)
     C                   eval      nCount = nUsrLib
     C                   When      lType = llCurlib
     C                   eval      Libl = %subst(CurLib : 1 : nCurLSize)
     C                   eval      nCount = nCurLib
     C                   When      lType = LLSysLibl
     C                   eval      Libl = %subst(SysLibl : 1 : nSysLSize)
     C                   eval      nCount = nSysLib
     C                   When      lType = llPRODLIBL
     C                   eval      Libl = %subst(ProdLibl : 1 : nProdLSize)
     C                   eval      nCount = nProdLib
     C                   other
     C                   eval      Libl = %subst(UsrLibl : 1 : nUsrLSize)
     C                   eval      nCount = nUsrLib
     C                   endsl
     C                   if        %Parms >= 2
     C                   Eval      nLibLCount = nCount
     C                   endif
     C                   return    LiblArray
     P GetLibl         E

      ** ----------------------------------------
      ** S E T L I B L - Change Library List
      ** ----------------------------------------
     P SetLibl         B                   EXPORT
     D SetLibl         PI             1N
     D  InLibl                       11A   Const DIM(250)
     D  lType                         5I 0 Const Options(*NOPASS)

     D CurLib          s                   Like(LIBNAME)
     D ProdLib1        s                   Like(LIBNAME)
     D ProdLib2        s                   Like(LIBNAME)

     D i               S             10I 0 Inz(0)

     C                   Dow       InLibl(i+1) <> *BLANKS
     C                   Eval      i = i + 1
     C                   enddo
     C                   Select
     C                   When      %Parms < 2 or lType = llUSRLIBL
     C                   CallP     QliChgLL('*SAME':'*SAME':'*SAME':
     C                                      InLibl : i :
     C                                      ll_Error )
     C                   When      lType = llCURLIB
     C                   Eval      CurLib  = InLibl(1)
     C                   CallP     QliChgLL(CurLib :'*SAME':'*SAME':' ': -1
     C                                    : ll_Error )
     C                   When      lType = llPRODLIBL
     C                   Eval      ProdLib1 = InLibl(1)
     C                   Eval      ProdLib2 = InLibl(2)
     C                   If        ProdLib2 = *BLANKS
     C                   Eval      ProdLib2 = '*SAME'
     C                   endif
     C                   CallP     QliChgLL('*SAME':ProdLib1:ProdLib2:' ':-1
     C                                    : ll_Error )
     C                   endsl
     C                   return    *ON
     P SetLibl         E

      ** ----------------------------------------------
          A D D L I B L E  -  Add Library List Entries
      ** ----------------------------------------------
     P AddLiblE        B                   EXPORT

     D AddLiblE        PI            10I 0
     D  InLibl                     2750A   Const VARYING
     D  PosLib                       10A   Const VARYING
     D                                     Options(*NOPASS)
     D  Pos                           1N   Const
     D                                     Options(*NOPASS)

     D  AddLibl        S                   DIM(250) LIKE(LIBNAME)
     D  OrgLibl        S                   DIM(250) LIKE(LIBNAME)
     D  NewLibl        S                   DIM(250) LIKE(LIBNAME)

      ** *ON = place new lib(s) after otherwise place before
     D lAfter          S              1N   INZ(*OFF)
     D PlaceLib        S                   LIKE(LIBNAME) INZ('*FIRST')
     D i               S             10I 0
     D x               S             10I 0
     D nPos            S             10I 0
     D nStart          S             10I 0
     D nLiblCount      S              5I 0
     D nAddLiblCount   S              5I 0
     C                   if        %Parms >= 3
     C                   Eval      lAfter = Pos
     C                   endif
     C                   if        %Parms >= 2
     C                   Eval      PlaceLib = PosLib
     C                   endif

     C                   Eval      nStart = 1
     C                   Eval      OrgLibl = GetLibl(llUsrLibl: nLiblCount)
     C                   Eval      nPos = %Scan(' ':InLibl)
     C                   Dow       nPos > 0 and i < MAXLIBL
     C                   Eval      i = i + 1
     C                   Eval      AddLibl(i) = %subst(InLibl : nStart :
     C                                               (nPos - nStart)+ 1)
     C                   Eval      nStart = nPos+1
     C                   Eval      nPos = %Scan(' ':InLibl:nStart)
     C                   enddo
     C                   If        %Len(InLibl) > nStart
     C                   Eval      i = i + 1
     C                   Eval      AddLibl(i) = %subst(InLibl : nStart :
     C                                           (%Len(InLibl)- nStart)+ 1)
     C                   endif

     C                   eval      nAddLiblCount = i
      ** Insert the new library(s) at the beginning
      ** of the existing library list
     C                   if        PlaceLib = '*FIRST'
     C                   eval      NewLibl = AddLibl
     C                   Eval      x = nAddLiblCount + 1
     C*                  eval      NewLibl(x) = OrgLibl
     C                   MOVEA     OrgLibl       NewLibl(x)
     C                   Eval      nLiblCount = nAddLiblCount + nLiblCount
     C                   else

     ** Insert before or after an existing library name
     C                   Eval      X = 1
     C                   for       i = 1 TO nLiblCount

      ** Detect match on Placement-Libary name?
     C                   if        OrgLibl(i) = PlaceLib
      ** Insert *AFTER
     C                   if        lAfter
      ** Copy the Placement Library to the list
     C                   Eval      NewLibl(x) = OrgLibl(i)
     C                   Eval      X = X + 1
      ** Add the new library names after the placement library
     C                   MOVEA     AddLibl       NewLibl(x)
      ** Copy the rest of the original library list
     C                   Eval      X = X + nAddLiblCount
     C                   Eval      i = i + 1
     C                   MOVEA     OrgLibl(i)    NewLibl(x)

      ** Insert *BEFORE
     C                   else
      ** Add the new library names before the placement library
     C                   MOVEA     AddLibl       NewLibl(x)
     C                   Eval      X = X + nAddLiblCount
      ** Copy the Placement Library to the list
     C                   Eval      NewLibl(x) = OrgLibl(i)
      ** Copy the rest of the original library list
     C                   Eval      X = X + nAddLiblCount
     C                   Eval      i = i + 1
     C                   MOVEA     OrgLibl(i)    NewLibl(x)
     C                   endif
      ** Done processing the library list
     C                   LEAVE

      ** NO-match on Placement-Libary name
     C                   else
      ** Just copy the library to the new list
     C                   Eval      NewLibl(x) = OrgLibl(i)
     C                   Eval      X = X + 1
     C                   endif
     C                   endfor

     C                   eval      nLiblCount = X - 1
     C                   endif
      ** Now do a Change Library List via the QLICHGLL API
     C                   CallP     SetLibl(NewLibl)
     C                   Return    X - 1
     P AddLiblE        E

Figure 2: Source code for Library List Procedures

Robert Cozzi

Bob Cozzi is a programmer/consultant, writer/author, and software developer. His popular RPG xTools add-on subprocedure library for RPG IV is fast becoming a standard with RPG developers. His book The Modern RPG Language has been the most widely used RPG programming book for more than a decade. He, along with others, speaks at and produces the highly popular RPG World conference for RPG programmers.

MC Press books written by Robert Cozzi available now on the MC Press Bookstore.

Get this jam-packed resource of quick, easy-to-implement RPG tips!
List Price $65.00

Now On Sale

The Modern RPG IV Language The Modern RPG IV Language
Cozzi on everything RPG! What more could you want?
List Price $99.95

Now On Sale







  • Mobile Computing and the IBM i

    SB ASNA PPL 5450Mobile computing is rapidly maturing into a solid platform for delivering enterprise applications. Many IBM i shops today are realizing that integrating their IBM i with mobile applications is the fast path to improved business workflows, better customer relations, and more responsive business reporting.

    This ASNA whitepaper takes a look at mobile computing for the IBM i. It discusses the different ways mobile applications may be used within the enterprise and how ASNA products solve the challenges mobile presents. It also presents the case that you already have the mobile programming team your projects need: that team is your existing RPG development team!

    Get your copy today!

  • Automate IBM i Operations using Wireless Devices

    DDL SystemsDownload the technical whitepaper on MANAGING YOUR IBM i WIRELESSLY and (optionally) register to download an absolutely FREE software trail. This whitepaper provides an in-depth review of the native IBM i technology and ACO MONITOR's advanced two-way messaging features to remotely manage your IBM i while in or away from the office. Notify on-duty personnel of system events and remotely respond to complex problems (via your Smartphone) before they become critical-24/7. Problem solved!

    Order your copy here.

  • DR Strategy Guide from Maxava: Brand New Edition - now fully updated to include Cloud!


    Download your free copy of DR Strategy Guide for IBM i from Maxava today.


  • White Paper: Node.js for Enterprise IBM i Modernization

    SB Profound WP 5539

    If your business is thinking about modernizing your legacy IBM i (also known as AS/400 or iSeries) applications, you will want to read this white paper first!

    Download this paper and learn how Node.js can ensure that you:
    - Modernize on-time and budget - no more lengthy, costly, disruptive app rewrites!
    - Retain your IBM i systems of record
    - Find and hire new development talent
    - Integrate new Node.js applications with your existing RPG, Java, .Net, and PHP apps
    - Extend your IBM i capabilties to include Watson API, Cloud, and Internet of Things

    Read Node.js for Enterprise IBM i Modernization Now!


  • 2020 IBM i Marketplace Survey Results


    This year marks the sixth edition of the popular IBM i Marketplace Survey Results. Each year, HelpSystems sets out to gather data about how businesses use the IBM i platform and the IT initiatives it supports. Year over year, the survey has begun to reveal long-term trends that give insight into the future of this trusted technology.

    More than 500 IBM i users from around the globe participated in this year’s survey, and we’re so happy to share the results with you. We hope you’ll find the information interesting and useful as you evaluate your own IT projects.

  • AIX Security Basics eCourse

    Core Security

    With so many organizations depending on AIX day to day, ensuring proper security and configuration is critical to ensure the safety of your environment. Don’t let common threats put your critical AIX servers at risk. Avoid simple mistakes and start to build a long-term plan with this AIX Security eCourse. Enroll today to get easy to follow instructions on topics like:

    • Removing extraneous files
    • Patching systems efficiently
    • Setting and validating permissions
    • Managing service considerations
    • Getting overall visibility into your networks


  • Developer Kit: Making a Business Case for Modernization and Beyond

    Profound Logic Software, Inc.

    Having trouble getting management approval for modernization projects? The problem may be you're not speaking enough "business" to them.

    This Developer Kit provides you study-backed data and a ready-to-use business case template to help get your very next development project approved!

  • What to Do When Your AS/400 Talent Retires

    HelpSystemsIT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators is small.

    This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn:

    • Why IBM i skills depletion is a top concern
    • How leading organizations are coping
    • Where automation will make the biggest impact


  • IBM i Resources Retiring?

    SB HelpSystems WC GenericLet’s face it: IBM i experts and RPG programmers are retiring from the workforce. Are you prepared to handle their departure?
    Our panel of IBM i experts—Chuck Losinski, Robin Tatam, Richard Schoen, and Tom Huntington—will outline strategies that allow your company to cope with IBM i skills depletion by adopting these strategies that allow you to get the job done without deep expertise on the OS:
    - Automate IBM i processes
    - Use managed services to help fill the gaps
    - Secure the system against data loss and viruses
    The strategies you discover in this webinar will help you ensure that your system of record—your IBM i—continues to deliver a powerful business advantage, even as staff retires.


  • Backup and Recovery Considerations for Security Data and Encrypted Backups

    SB PowerTech WC GenericSecurity expert Carol Woodbury is joined by Debbie Saugen. Debbie is an expert on IBM i backup and recovery, disaster recovery, and high availability, helping IBM i shops build and implement effective business continuity plans.
    In today’s business climate, business continuity is more important than ever. But 83 percent of organizations are not totally confident in their backup strategy.
    During this webinar, Carol and Debbie discuss the importance of a good backup plan, how to ensure you’re backing up your security information, and your options for encrypted back-ups.

  • Profound.js: The Agile Approach to Legacy Modernization

    SB Profound WC GenericIn this presentation, Alex Roytman and Liam Allan will unveil a completely new and unique way to modernize your legacy applications. Learn how Agile Modernization:
    - Uses the power of Node.js in place of costly system re-writes and migrations
    - Enables you to modernize legacy systems in an iterative, low-risk manner
    - Makes it easier to hire developers for your modernization efforts
    - Integrates with Profound UI (GUI modernization) for a seamless, end-to-end legacy modernization solution


  • Data Breaches: Is IBM i Really at Risk?

    SB PowerTech WC GenericIBM i is known for its security, but this OS could be more vulnerable than you think.
    Although Power Servers often live inside the safety of the perimeter firewall, the risk of suffering a data leak or data corruption remains high.
    Watch noted IBM i security expert Robin Tatam as he discusses common ways that this supposedly “secure” operating system may actually be vulnerable and who the culprits might be.

    Watch the webinar today!


  • Easy Mobile Development

    SB Profound WC GenericWatch this on-demand webinar and learn how to rapidly and easily deploy mobile apps to your organization – even when working with legacy RPG code! IBM Champion Scott Klement will demonstrate how to:
    - Develop RPG applications without mobile development experience
    - Deploy secure applications for any mobile device
    - Build one application for all platforms, including Apple and Android
    - Extend the life and reach of your IBM i (aka iSeries, AS400) platform
    You’ll see examples from customers who have used our products and services to deliver the mobile applications of their dreams, faster and easier than they ever thought possible!


  • Profound UI: Unlock True Modernization from your IBM i Enterprise

    SB Profound PPL 5491Modern, web-based applications can make your Enterprise more efficient, connected and engaged. This session will demonstrate how the Profound UI framework is the best and most native way to convert your existing RPG applications and develop new modern applications for your business. Additionally, you will learn how you can address modernization across your Enterprise, including databases and legacy source code, with Profound Logic.

  • Node Webinar Series Pt. 1: The World of Node.js on IBM i

    Profound Logic Software, Inc.Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.

    Part 1 will teach you what Node.js is, why it's a great option for IBM i shops, and how to take advantage of the ecosystem surrounding Node.

    In addition to background information, our Director of Product Development Scott Klement will demonstrate applications that take advantage of the Node Package Manager (npm).

  • 5 New and Unique Ways to Use the IBM i Audit Journal

    SB HelpSystems ROBOT GenericYou must be asking yourself: am I doing everything I can to protect my organization’s data? Tune in as our panel of IBM i high availability experts discuss:

    - Why companies don’t test role swaps when they know they should
    - Whether high availability in the cloud makes sense for IBM i users
    - Why some organizations don’t have high availability yet
    - How to get high availability up and running at your organization
    - High availability considerations for today’s security concerns

  • Profound.js 2.0: Extend the Power of Node to your IBM i Applications

    SB Profound WC 5541In this Webinar, we'll demonstrate how Profound.js 2.0 enables you to easily adopt Node.js in your business, and to take advantage of the many benefits of Node, including access to a much larger pool of developers for IBM i and access to countless reusable open source code packages on npm (Node Package Manager).
    You will see how Profound.js 2.0 allows you to:

    • Provide RPG-like capabilities for server-side JavaScript.
    • Easily create web and mobile application interfaces for Node on IBM i.
    • Let existing RPG programs call Node.js modules directly, and vice versa.
    • Automatically generate code for Node.js.
    • Automatically converts existing RPGLE code into clean, simplified Node.js code.

    Download and watch today!


  • Make Modern Apps You'll Love with Profound UI & Profound.js

    SB Profound WC 5541Whether you have green screens or a drab GUI, your outdated apps can benefit from modern source code, modern GUIs, and modern tools.
    Profound Logic's Alex Roytman and Liam Allan are here to show you how Free-format RPG and Node.js make it possible to deliver applications your whole business will love:

    • Transform legacy RPG code to modern free-format RPG and Node.js
    • Deliver truly modern application interfaces with Profound UI
    • Extend your RPG applications to include Web Services and NPM packages with Node.js


  • Accelerating Programmer Productivity with Sequel


    Most business intelligence tools are just that: tools, a means to an end but not an accelerator. Yours could even be slowing you down. But what if your BI tool didn't just give you a platform for query-writing but also improved programmer productivity?
    Watch the recorded webinar to see how Sequel:

    • Makes creating complex results simple
    • Eliminates barriers to data sources
    • Increases flexibility with data usage and distribution

    Accelerated productivity makes everyone happy, from programmer to business user.

  • Business Intelligence is Changing: Make Your Game Plan

    SB_HelpSystems_WC_GenericIt’s time to develop a strategy that will help you meet your informational challenges head-on. Watch the webinar to learn how to set your IT department up for business intelligence success. You’ll learn how the right data access tool will help you:

    • Access IBM i data faster
    • Deliver useful information to executives and business users
    • Empower users with secure data access

    Ready to make your game plan and finally keep up with your data access requests?


  • Controlling Insider Threats on IBM i

    SB_HelpSystems_WC_GenericLet’s face facts: servers don’t hack other servers. Despite the avalanche of regulations, news headlines remain chock full of stories about data breaches, all initiated by insiders or intruders masquerading as insiders.
    User profiles are often duplicated or restored and are rarely reviewed for the appropriateness of their current configuration. This increases the risk of the profile being able to access data without the intended authority or having privileges that should be reserved for administrators.
    Watch security expert Robin Tatam as he discusses a new approach for onboarding new users on IBM i and best-practices techniques for managing and monitoring activities after they sign on.

  • Don't Just Settle for Query/400...

    SB_HelpSystems_WC_GenericWhile introducing Sequel Data Access, we’ll address common frustrations with Query/400, discuss major data access, distribution trends, and more advanced query tools. Plus, you’ll learn how a tool like Sequel lightens IT’s load by:

    - Accessing real-time data, so you can make real-time decisions
    - Providing run-time prompts, so users can help themselves
    - Delivering instant results in Microsoft Excel and PDF, without the wait
    - Automating the query process with on-demand data, dashboards, and scheduled jobs

  • How to Manage Documents the Easy Way

    SB_HelpSystems_WC_GenericWhat happens when your company depends on an outdated document management strategy?
    Everything is harder.
    You don’t need to stick with status quo anymore.
    Watch the webinar to learn how to put effective document management into practice and:

    • Capture documents faster, instead of wasting everyone’s time
    • Manage documents easily, so you can always find them
    • Distribute documents automatically, and move on to the next task


  • Lessons Learned from the AS/400 Breach

    SB_PowerTech_WC_GenericGet actionable info to avoid becoming the next cyberattack victim.
    In “Data breach digest—Scenarios from the field,” Verizon documented an AS/400 security breach. Whether you call it AS/400, iSeries, or IBM i, you now have proof that the system has been breached.
    Watch IBM i security expert Robin Tatam give an insightful discussion of the issues surrounding this specific scenario.
    Robin will also draw on his extensive cybersecurity experience to discuss policies, processes, and configuration details that you can implement to help reduce the risk of your system being the next victim of an attack.

  • Overwhelmed by Operating Systems?

    SB_HelpSystems_WC_GenericIn this 30-minute recorded webinar, our experts demonstrate how you can:

    • Manage multiple platforms from a central location
    • View monitoring results in a single pane of glass on your desktop or mobile device
    • Take advantage of best practice, plug-and-play monitoring templates
    • Create rules to automate daily checks across your entire infrastructure
    • Receive notification if something is wrong or about to go wrong

    This presentation includes a live demo of Network Server Suite.


  • Real-Time Disk Monitoring with Robot Monitor

    SB_HelpSystems_WC_GenericYou need to know when IBM i disk space starts to disappear and where it has gone before system performance and productivity start to suffer. Our experts will show you how Robot Monitor can help you pinpoint exactly when your auxiliary storage starts to disappear and why, so you can start taking a proactive approach to disk monitoring and analysis. You’ll also get insight into:

    • The main sources of disk consumption
    • How to monitor temporary storage and QTEMP objects in real time
    • How to monitor objects and libraries in real time and near-real time
    • How to track long-term disk trends



  • Stop Re-keying Data Between IBM I and Other Applications

    SB_HelpSystems_WC_GenericMany business still depend on RPG for their daily business processes and report generation.Wouldn’t it be nice if you could stop re-keying data between IBM i and other applications? Or if you could stop replicating data and start processing orders faster? Or what if you could automatically extract data from existing reports instead of re-keying? It’s all possible. Watch this webinar to learn about:

    • The data dilemma
    • 3 ways to stop re-keying data
    • Data automation in practice

    Plus, see how HelpSystems data automation software will help you stop re-keying data.


  • The Top Five RPG Open Access Myths....BUSTED!

    SB_Profound_WC_GenericWhen it comes to IBM Rational Open Access: RPG Edition, there are still many misconceptions - especially where application modernization is concerned!

    In this Webinar, we'll address some of the biggest myths about RPG Open Access, including:

    • Modernizing with RPG OA requires significant changes to the source code
    • The RPG language is outdated and impractical for modernizing applications
    • Modernizing with RPG OA is the equivalent to "screen scraping"


  • Time to Remove the Paper from Your Desk and Become More Efficient

    SB_HelpSystems_WC_GenericToo much paper is wasted. Attempts to locate documents in endless filing cabinets.And distributing documents is expensive and takes up far too much time.
    These are just three common reasons why it might be time for your company to implement a paperless document management system.
    Watch the webinar to learn more and discover how easy it can be to:

    • Capture
    • Manage
    • And distribute documents digitally


  • IBM i: It’s Not Just AS/400


    IBM’s Steve Will talks AS/400, POWER9, cognitive systems, and everything in between

    Are there still companies that use AS400? Of course!

    IBM i was built on the same foundation.
    Watch this recorded webinar with IBM i Chief Architect Steve Will and IBM Power Champion Tom Huntington to gain a unique perspective on the direction of this platform, including:

    • IBM i development strategies in progress at IBM
    • Ways that Watson will shake hands with IBM i
    • Key takeaways from the AS/400 days


  • Node.js on IBM i Webinar Series Pt. 2: Setting Up Your Development Tools

    Profound Logic Software, Inc.Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. In Part 2, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Attend this webinar to learn:

    • Different tools to develop Node.js applications on IBM i
    • Debugging Node.js
    • The basics of Git and tools to help those new to it
    • Using as a pre-built development environment



  • Inside the Integrated File System (IFS)

    SB_HelpSystems_WC_GenericDuring this webinar, you’ll learn basic tips, helpful tools, and integrated file system commands—including WRKLNK—for managing your IFS directories and Access Client Solutions (ACS). We’ll answer your most pressing IFS questions, including:

    • What is stored inside my IFS directories?
    • How do I monitor the IFS?
    • How do I replicate the IFS or back it up?
    • How do I secure the IFS?

    Understanding what the integrated file system is and how to work with it must be a critical part of your systems management plans for IBM i.


  • Expert Tips for IBM i Security: Beyond the Basics

    SB PowerTech WC GenericIn this session, IBM i security expert Robin Tatam provides a quick recap of IBM i security basics and guides you through some advanced cybersecurity techniques that can help you take data protection to the next level. Robin will cover:

    • Reducing the risk posed by special authorities
    • Establishing object-level security
    • Overseeing user actions and data access

    Don't miss this chance to take your knowledge of IBM i security beyond the basics.



  • 5 IBM i Security Quick Wins

    SB PowerTech WC GenericIn today’s threat landscape, upper management is laser-focused on cybersecurity. You need to make progress in securing your systems—and make it fast.
    There’s no shortage of actions you could take, but what tactics will actually deliver the results you need? And how can you find a security strategy that fits your budget and time constraints?
    Join top IBM i security expert Robin Tatam as he outlines the five fastest and most impactful changes you can make to strengthen IBM i security this year.
    Your system didn’t become unsecure overnight and you won’t be able to turn it around overnight either. But quick wins are possible with IBM i security, and Robin Tatam will show you how to achieve them.

  • How to Meet the Newest Encryption Requirements on IBM i

    SB PowerTech WC GenericA growing number of compliance mandates require sensitive data to be encrypted. But what kind of encryption solution will satisfy an auditor and how can you implement encryption on IBM i? Watch this on-demand webinar to find out how to meet today’s most common encryption requirements on IBM i. You’ll also learn:

    • Why disk encryption isn’t enough
    • What sets strong encryption apart from other solutions
    • Important considerations before implementing encryption



  • Comply in 5! Well, actually UNDER 5 minutes!!

    SB CYBRA PPL 5382

    TRY the one package that solves all your document design and printing challenges on all your platforms.

    Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product.

    Request your trial now!

  • Backup and Recovery on IBM i: Your Strategy for the Unexpected

    SB HelpSystems SC 5413Robot automates the routine tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:
    - Simplified backup procedures
    - Easy data encryption
    - Save media management
    - Guided restoration
    - Seamless product integration
    Make sure your data survives when catastrophe hits. Try the Robot Backup and Recovery Solution FREE for 30 days.

  • Manage IBM i Messages by Exception with Robot

    SB HelpSystems SC 5413Managing messages on your IBM i can be more than a full-time job if you have to do it manually. How can you be sure you won’t miss important system events?
    Automate your message center with the Robot Message Management Solution. Key features include:
    - Automated message management
    - Tailored notifications and automatic escalation
    - System-wide control of your IBM i partitions
    - Two-way system notifications from your mobile device
    - Seamless product integration
    Try the Robot Message Management Solution FREE for 30 days.

  • Easiest Way to Save Money? Stop Printing IBM i Reports

    SB HelpSystems SC 5413Robot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing.
    Manage your reports with the Robot Report Management Solution. Key features include:

    - Automated report distribution
    - View online without delay
    - Browser interface to make notes
    - Custom retention capabilities
    - Seamless product integration
    Rerun another report? Never again. Try the Robot Report Management Solution FREE for 30 days.

  • Hassle-Free IBM i Operations around the Clock

    SB HelpSystems SC 5413For over 30 years, Robot has been a leader in systems management for IBM i.
    Manage your job schedule with the Robot Job Scheduling Solution. Key features include:
    - Automated batch, interactive, and cross-platform scheduling
    - Event-driven dependency processing
    - Centralized monitoring and reporting
    - Audit log and ready-to-use reports
    - Seamless product integration
    Scale your software, not your staff. Try the Robot Job Scheduling Solution FREE for 30 days.

  • ACO MONITOR Manages your IBM i 24/7 and Notifies You When Your IBM i Needs Assistance!

    SB DDL Systems 5429More than a paging system - ACO MONITOR is a complete systems management solution for your Power Systems running IBM i. ACO MONITOR manages your Power System 24/7, uses advanced technology (like two-way messaging) to notify on-duty support personnel, and responds to complex problems before they reach critical status.

    ACO MONITOR is proven technology and is capable of processing thousands of mission-critical events daily. The software is pre-configured, easy to install, scalable, and greatly improves data center efficiency.