Sidebar

The API Corner: More on Sending Messages from an Application Program

APIs
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

Learn how to send program messages based on an API error code structure.

 

In the previous article, "Inform Users of Problems by Sending Error Messages from Application Programs," the Send Program Message (QMHSNDPM) API was used to send a user error message indicating that a severe error had been encountered. In this article, the QMHSNDPM API will also be used, but now to send a system-related error message followed by a user error message.

 

As a review, back in "What to Do with Messages in the Application Program," we saw how to call a system API with the sending of error messages disabled. The scenario used was determining if an object existed by calling the Retrieve Object Description (QUSROBJD) API and, if an error was returned in the API error code data structure, handling the error in an appropriate way. The code shown at that time was this:

 

  RObjD(QUSD0100 :%size(QUSD0100) :'OBJD0100' :QualName :Type :ErrCde);

  if ErrCde.Common.QUSBAVL > 0;                                       

     select;                                                          

        when ErrCde.Common.QUSEI = 'CPF9801';                          

             // Create the user space                                 

        when ErrCde.Common.QUSEI = '???????';                       

             // Additional error checks that I will handle          

        other;                                                       

             // Something more than I expected so send 

             // appropriate message(s) and end         

     endsl;                                                         

  endif;                                                             

                                                                    

  // Continue processing and eventually end the program normally    

 

In the previous SELECT structure, the first WHEN operation is checking the Exception ID of the API error code structure for CPF9801 – Object &2 in library &3 not found. This error message is related to an expected condition, and the program will create the object when necessary. No message to the user of the program is necessary.

 

The second WHEN operation is intended to check for exception IDs that may indicate an environmental problem rather than an application program failure. Reviewing the documentation for the Retrieve Object Description (QUSROBJD) API, the following errors might fall into this category and will be used to replace the '???????' literal used in the earlier article.

  •         CPF9802 – Not authorized to object &2 in library &3     
  •         CPF9810 – Library &1 not found     
  •         CPF9820 – Not authorized to use library &1      

 

When any of these errors are encountered, the application program will send the CPF message as a diagnostic followed by the application error message APP0002 as an escape. Here's the code to do this:

 

dApp0002          ds                  qualified  

d PgmName                       10               

dLen_MsgDta       s             10u 0       

        when ((ErrCde.Common.QUSEI = 'CPF9802') or     

              (ErrCde.Common.QUSEI = 'CPF9810') or     

              (ErrCde.Common.QUSEI = 'CPF9820'));      

             if ErrCde.Common.QUSBAVL < %size(QUSEC);              

                Len_MsgDta = 0;                                    

             else;                                                 

                Len_MsgDta = ErrCde.Common.QUSBAVL - %size(QUSEC); 

             endif;                                                

             SndMsg( ErrCde.Common.QUSEI :'QCPFMSG   *LIBL'        

                    :ErrCde.ErrMsgTxt :Len_MsgDta                  

                    :'*DIAG' :'*PGMBDY' :1 :MsgKey :QUSEC);        

             App0002.PgmName = PSDS.PgmName;                       

             SndMsg( 'APP0002' :'APPLMSGF  QGPL' :App0002          

                    :%size(App0002) :'*ESCAPE' :'*PGMBDY' :1       

                    :MsgKey :QUSEC);                               

 

Similar to how message description APP0001 was used in the previous article, the APP0002 error message has replacement data representing the name of the program. This is defined using the data structure App0002. The APP0002 message description is created using this command:

 

ADDMSGD MSGID(APP0002) MSGF(QGPL/APPLMSGF) +

 MSG('Severe error found by program &1. Notify your system administrator.') +

 SECLVL('This error indicates an environmental problem. Review the job log +

 for previous error(s) and correct them.') FMT((*CHAR 10))

 

A new variable, Len_MsgDta, is also defined. This variable is used to specify the length of the message replacement data to be used when sending the CPF error message. The length of the message replacement data is determined by examining the Bytes Available field of the API error code structure (ErrCde.Common.QUSBAVL). When a message has no replacement data, the Bytes Available field will be set to 15; otherwise, Bytes Available will be set to the length of the replacement data plus 16 bytes (to account for the Bytes Provided, Bytes Available, Exception ID, and Reserved field of the QUSEC base structure). For this reason, the application first examines ErrCde.Common.QUSBAVL and if less than 16 (the size of the QUSEC base structure) sets Len_MsgDta to 0. Otherwise, Len_MsgDta is set to the value of Bytes Available less 16.

 

The application program now sends the CPF error message reported by the API to the job log as a diagnostic message. The one assumption being made here is that the message description is in the message file QCPFMSGF. For system APIs, this is generally a safe assumption. APIs provided by other program products may use a different message file, which would require a change to the second parameter value passed to the QMHSNDPM API.

 

Having sent the CPF error message, the application now records the name of the application program in the App0002 data structure and sends message description APP0002 as an escape message to the caller of the application program. If the application has been called from the command line and library SOMELIB does not exist, the user will see these two messages:

 

Library SOMELIB not found.                                            

Severe error found by program ROBJD. Notify your system administrator.

 

The system administrator would then authorize the (presumably new) user to the library SOMELIB.

 

The OTHER operation catches all other error messages reported back to the application program from the QUSROBJD API. For these error situations, the application again sends the CPF message to the job log as a diagnostic, but now sends message APP0001 (rather than APP0002) as an escape as these "other" errors are more associated with failures within the application program (or the job itself). The mechanics of sending these messages is essentially the same as seen in the previous WHEN logic.

 

The pertinent parts of the application program are provided below.

 

dRObjD            pr                  extpgm('QSYS/QUSROBJD')         

d Receiver                       1    options(*varsize)               

d LenReceiver                   10i 0 const                           

d Format                         8    const                           

d ObjName                       20    const                           

d ObjType                       10    const                           

d ErrCde                              likeds(QUSEC) options(*nopass)  

d ASP                            1    const options(*varsize :*nopass)

                                                                      

dSndMsg           pr                  extpgm('QSYS/QMHSNDPM')         

d MsgID                          7    const                           

d QualMsgF                      20    const                           

d MsgDta                     65535    const options(*varsize)         

d LenMsgDta                     10i 0 const                           

d MsgType                       10    const                           

d CallStackEntry             65535    const options(*varsize)         

d CallStackCntr                 10i 0 const                       

d MsgKey                         4                               

d QUSEC                               likeds(QUSEC)              

d LenCSE                        10i 0 const options(*nopass)     

d CSEQual                       20    const options(*nopass)     

d DSPWaitTime                   10i 0 const options(*nopass)     

d CSEType                       10    const options(*nopass)     

d CCSID                         10i 0 const options(*nopass)     

                                                                  

 /copy qsysinc/qrpglesrc,qusrobjd                                

 /copy qsysinc/qrpglesrc,qusec                                   

                                                                 

dQualName         ds                                             

d Name                          10    inz('SOMEOBJ')             

d Lib                           10    inz('SOMELIB')             

                                                                 

dPSDS            sds                  qualified                  

d PgmName               334    343                            

                                                              

dErrCde           ds                  qualified               

d Common                              likeds(QUSEC)           

d ErrMsgTxt                    512                            

                                                              

dApp0001          ds                  qualified               

d PgmName                       10                            

                                                              

dApp0002          ds                  qualified               

d PgmName                       10                            

                                                               

dType             s             10    inz('*USRSPC')          

dMsgKey           s              4                            

dLen_MsgDta       s             10u 0                         

                                                               

 /free                                                        

                                                                      

  QUSBPRV = 0;                                                         

  ErrCde.Common.QUSBPRV = %size(ErrCde);                              

                                                                      

  RObjD(QUSD0100 :%size(QUSD0100) :'OBJD0100' :QualName :Type :ErrCde);

  if ErrCde.Common.QUSBAVL > 0;                                       

     select;                                                          

        when ErrCde.Common.QUSEI = 'CPF9801';                         

             // Create the user space                                  

        when ((ErrCde.Common.QUSEI = 'CPF9802') or                    

              (ErrCde.Common.QUSEI = 'CPF9810') or                    

              (ErrCde.Common.QUSEI = 'CPF9820'));                     

             if ErrCde.Common.QUSBAVL < %size(QUSEC);                 

                Len_MsgDta = 0;                                       

             else;                                                    

                Len_MsgDta = ErrCde.Common.QUSBAVL - %size(QUSEC);    

             endif;                                                   

             SndMsg( ErrCde.Common.QUSEI :'QCPFMSG   *LIBL'         

                    :ErrCde.ErrMsgTxt :Len_MsgDta                   

                    :'*DIAG' :'*PGMBDY' :1 :MsgKey :QUSEC);         

             App0002.PgmName = PSDS.PgmName;                        

             SndMsg( 'APP0002' :'APPLMSGF  QGPL' :App0002           

                    :%size(App0002) :'*ESCAPE' :'*PGMBDY' :1        

                    :MsgKey :QUSEC);                                

        other;                                                      

             if ErrCde.Common.QUSBAVL < %size(QUSEC);               

                Len_MsgDta = 0;                                      

             else;                                                  

                Len_MsgDta = ErrCde.Common.QUSBAVL - %size(QUSEC);  

             endif;                                                 

             SndMsg( ErrCde.Common.QUSEI :'QCPFMSG   *LIBL'         

                    :ErrCde.ErrMsgTxt :Len_MsgDta                   

                    :'*DIAG' :'*PGMBDY' :1 :MsgKey :QUSEC);         

             App0001.PgmName = PSDS.PgmName;                        

             SndMsg( 'APP0001' :'APPLMSGF  QGPL' :App0001       

                    :%size(App0001) :'*ESCAPE' :'*PGMBDY' :1    

                    :MsgKey :QUSEC);                            

     endsl;                                                     

  endif;                                                         

                                                                

  *inlr = *on;                                                  

  return;                                                       

                                                                 

 /end-free                                                      

You should now have a good feel for how to send messages using the Send Program Message API. In the future, we'll look at other capabilities of the message-handling APIs.

 

In the meantime, if you have any API questions, send them to me at This email address is being protected from spambots. You need JavaScript enabled to view it.. I'll see what I can do about answering your burning questions in future columns.

Bruce Vining

Bruce Vining is president and co-founder of Bruce Vining Services, LLC, a firm providing contract programming and consulting services to the System i community. He began his career in 1979 as an IBM Systems Engineer in St. Louis, Missouri, and then transferred to Rochester, Minnesota, in 1985, where he continues to reside. From 1992 until leaving IBM in 2007, Bruce was a member of the System Design Control Group responsible for OS/400 and i5/OS areas such as System APIs, Globalization, and Software Serviceability. He is also the designer of Control Language for Files (CLF).A frequent speaker and writer, Bruce can be reached at bvining@brucevining.com. 


MC Press books written by Bruce Vining available now on the MC Press Bookstore.

IBM System i APIs at Work IBM System i APIs at Work
Leverage the power of APIs with this definitive resource.
List Price $89.95

Now On Sale

BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

RESOURCE CENTER

  • WHITE PAPERS

  • WEBCAST

  • TRIAL SOFTWARE

  • White Paper: Node.js for Enterprise IBM i Modernization

    SB Profound WP 5539

    If your business is thinking about modernizing your legacy IBM i (also known as AS/400 or iSeries) applications, you will want to read this white paper first!

    Download this paper and learn how Node.js can ensure that you:
    - Modernize on-time and budget - no more lengthy, costly, disruptive app rewrites!
    - Retain your IBM i systems of record
    - Find and hire new development talent
    - Integrate new Node.js applications with your existing RPG, Java, .Net, and PHP apps
    - Extend your IBM i capabilties to include Watson API, Cloud, and Internet of Things


    Read Node.js for Enterprise IBM i Modernization Now!

     

  • Profound Logic Solution Guide

    SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation.
    Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects.
    The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the companyare not aligned with the current IT environment.

    Get your copy of this important guide today!

     

  • 2022 IBM i Marketplace Survey Results

    Fortra2022 marks the eighth edition of the IBM i Marketplace Survey Results. Each year, Fortra captures data on how businesses use the IBM i platform and the IT and cybersecurity initiatives it supports.

    Over the years, this survey has become a true industry benchmark, revealing to readers the trends that are shaping and driving the market and providing insight into what the future may bring for this technology.

  • Brunswick bowls a perfect 300 with LANSA!

    FortraBrunswick is the leader in bowling products, services, and industry expertise for the development and renovation of new and existing bowling centers and mixed-use recreation facilities across the entertainment industry. However, the lifeblood of Brunswick’s capital equipment business was running on a 15-year-old software application written in Visual Basic 6 (VB6) with a SQL Server back-end. The application was at the end of its life and needed to be replaced.
    With the help of Visual LANSA, they found an easy-to-use, long-term platform that enabled their team to collaborate, innovate, and integrate with existing systems and databases within a single platform.
    Read the case study to learn how they achieved success and increased the speed of development by 30% with Visual LANSA.

     

  • Progressive Web Apps: Create a Universal Experience Across All Devices

    LANSAProgressive Web Apps allow you to reach anyone, anywhere, and on any device with a single unified codebase. This means that your applications—regardless of browser, device, or platform—instantly become more reliable and consistent. They are the present and future of application development, and more and more businesses are catching on.
    Download this whitepaper and learn:

    • How PWAs support fast application development and streamline DevOps
    • How to give your business a competitive edge using PWAs
    • What makes progressive web apps so versatile, both online and offline

     

     

  • The Power of Coding in a Low-Code Solution

    LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed.
    Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

    • Discover the benefits of Low-code's quick application creation
    • Understand the differences in model-based and language-based Low-Code platforms
    • Explore the strengths of LANSA's Low-Code Solution to Low-Code’s biggest drawbacks

     

     

  • Why Migrate When You Can Modernize?

    LANSABusiness users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.
    In this white paper, you’ll learn how to think of these issues as opportunities rather than problems. We’ll explore motivations to migrate or modernize, their risks and considerations you should be aware of before embarking on a (migration or modernization) project.
    Lastly, we’ll discuss how modernizing IBM i applications with optimized business workflows, integration with other technologies and new mobile and web user interfaces will enable IT – and the business – to experience time-added value and much more.

     

  • UPDATED: Developer Kit: Making a Business Case for Modernization and Beyond

    Profound Logic Software, Inc.Having trouble getting management approval for modernization projects? The problem may be you're not speaking enough "business" to them.

    This Developer Kit provides you study-backed data and a ready-to-use business case template to help get your very next development project approved!

  • What to Do When Your AS/400 Talent Retires

    FortraIT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators is small.

    This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn:

    • Why IBM i skills depletion is a top concern
    • How leading organizations are coping
    • Where automation will make the biggest impact

     

  • Node.js on IBM i Webinar Series Pt. 2: Setting Up Your Development Tools

    Profound Logic Software, Inc.Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. In Part 2, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Attend this webinar to learn:

    • Different tools to develop Node.js applications on IBM i
    • Debugging Node.js
    • The basics of Git and tools to help those new to it
    • Using NodeRun.com as a pre-built development environment

     

     

  • Expert Tips for IBM i Security: Beyond the Basics

    SB PowerTech WC GenericIn this session, IBM i security expert Robin Tatam provides a quick recap of IBM i security basics and guides you through some advanced cybersecurity techniques that can help you take data protection to the next level. Robin will cover:

    • Reducing the risk posed by special authorities
    • Establishing object-level security
    • Overseeing user actions and data access

    Don't miss this chance to take your knowledge of IBM i security beyond the basics.

     

     

  • 5 IBM i Security Quick Wins

    SB PowerTech WC GenericIn today’s threat landscape, upper management is laser-focused on cybersecurity. You need to make progress in securing your systems—and make it fast.
    There’s no shortage of actions you could take, but what tactics will actually deliver the results you need? And how can you find a security strategy that fits your budget and time constraints?
    Join top IBM i security expert Robin Tatam as he outlines the five fastest and most impactful changes you can make to strengthen IBM i security this year.
    Your system didn’t become unsecure overnight and you won’t be able to turn it around overnight either. But quick wins are possible with IBM i security, and Robin Tatam will show you how to achieve them.

  • Security Bulletin: Malware Infection Discovered on IBM i Server!

    SB PowerTech WC GenericMalicious programs can bring entire businesses to their knees—and IBM i shops are not immune. It’s critical to grasp the true impact malware can have on IBM i and the network that connects to it. Attend this webinar to gain a thorough understanding of the relationships between:

    • Viruses, native objects, and the integrated file system (IFS)
    • Power Systems and Windows-based viruses and malware
    • PC-based anti-virus scanning versus native IBM i scanning

    There are a number of ways you can minimize your exposure to viruses. IBM i security expert Sandi Moore explains the facts, including how to ensure you're fully protected and compliant with regulations such as PCI.

     

     

  • Encryption on IBM i Simplified

    SB PowerTech WC GenericDB2 Field Procedures (FieldProcs) were introduced in IBM i 7.1 and have greatly simplified encryption, often without requiring any application changes. Now you can quickly encrypt sensitive data on the IBM i including PII, PCI, PHI data in your physical files and tables.
    Watch this webinar to learn how you can quickly implement encryption on the IBM i. During the webinar, security expert Robin Tatam will show you how to:

    • Use Field Procedures to automate encryption and decryption
    • Restrict and mask field level access by user or group
    • Meet compliance requirements with effective key management and audit trails

     

  • Lessons Learned from IBM i Cyber Attacks

    SB PowerTech WC GenericDespite the many options IBM has provided to protect your systems and data, many organizations still struggle to apply appropriate security controls.
    In this webinar, you'll get insight into how the criminals accessed these systems, the fallout from these attacks, and how the incidents could have been avoided by following security best practices.

    • Learn which security gaps cyber criminals love most
    • Find out how other IBM i organizations have fallen victim
    • Get the details on policies and processes you can implement to protect your organization, even when staff works from home

    You will learn the steps you can take to avoid the mistakes made in these examples, as well as other inadequate and misconfigured settings that put businesses at risk.

     

     

  • The Power of Coding in a Low-Code Solution

    SB PowerTech WC GenericWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed.
    Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

    • Discover the benefits of Low-code's quick application creation
    • Understand the differences in model-based and language-based Low-Code platforms
    • Explore the strengths of LANSA's Low-Code Solution to Low-Code’s biggest drawbacks

     

     

  • Node Webinar Series Pt. 1: The World of Node.js on IBM i

    SB Profound WC GenericHave you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.
    Part 1 will teach you what Node.js is, why it's a great option for IBM i shops, and how to take advantage of the ecosystem surrounding Node.
    In addition to background information, our Director of Product Development Scott Klement will demonstrate applications that take advantage of the Node Package Manager (npm).
    Watch Now.

  • The Biggest Mistakes in IBM i Security

    SB Profound WC Generic The Biggest Mistakes in IBM i Security
    Here’s the harsh reality: cybersecurity pros have to get their jobs right every single day, while an attacker only has to succeed once to do incredible damage.
    Whether that’s thousands of exposed records, millions of dollars in fines and legal fees, or diminished share value, it’s easy to judge organizations that fall victim. IBM i enjoys an enviable reputation for security, but no system is impervious to mistakes.
    Join this webinar to learn about the biggest errors made when securing a Power Systems server.
    This knowledge is critical for ensuring integrity of your application data and preventing you from becoming the next Equifax. It’s also essential for complying with all formal regulations, including SOX, PCI, GDPR, and HIPAA
    Watch Now.

  • Comply in 5! Well, actually UNDER 5 minutes!!

    SB CYBRA PPL 5382

    TRY the one package that solves all your document design and printing challenges on all your platforms.

    Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product.

    Request your trial now!

  • Backup and Recovery on IBM i: Your Strategy for the Unexpected

    FortraRobot automates the routine tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:
    - Simplified backup procedures
    - Easy data encryption
    - Save media management
    - Guided restoration
    - Seamless product integration
    Make sure your data survives when catastrophe hits. Try the Robot Backup and Recovery Solution FREE for 30 days.

  • Manage IBM i Messages by Exception with Robot

    SB HelpSystems SC 5413Managing messages on your IBM i can be more than a full-time job if you have to do it manually. How can you be sure you won’t miss important system events?
    Automate your message center with the Robot Message Management Solution. Key features include:
    - Automated message management
    - Tailored notifications and automatic escalation
    - System-wide control of your IBM i partitions
    - Two-way system notifications from your mobile device
    - Seamless product integration
    Try the Robot Message Management Solution FREE for 30 days.

  • Easiest Way to Save Money? Stop Printing IBM i Reports

    FortraRobot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing.
    Manage your reports with the Robot Report Management Solution. Key features include:

    - Automated report distribution
    - View online without delay
    - Browser interface to make notes
    - Custom retention capabilities
    - Seamless product integration
    Rerun another report? Never again. Try the Robot Report Management Solution FREE for 30 days.

  • Hassle-Free IBM i Operations around the Clock

    SB HelpSystems SC 5413For over 30 years, Robot has been a leader in systems management for IBM i.
    Manage your job schedule with the Robot Job Scheduling Solution. Key features include:
    - Automated batch, interactive, and cross-platform scheduling
    - Event-driven dependency processing
    - Centralized monitoring and reporting
    - Audit log and ready-to-use reports
    - Seamless product integration
    Scale your software, not your staff. Try the Robot Job Scheduling Solution FREE for 30 days.