Sidebar

Simon's Solutions: Monitor for End Job Operations, Part II

RPG
Typography
  • Smaller Small Medium Big Bigger
  • Default Helvetica Segoe Georgia Times

Learn critical cleanup techniques that target end-of-job due to end job commands.

 

This article continues the discussion we started in Part I. Let's start by looking at invocation exit programs and procedures.

If an MI process phase is terminated and the process was not in termination phase, then the invocations are terminated. Invocation exit programs/procedures set for the terminated invocations are allowed to run. Invocation entries (aka call stack entries) are terminated in the order of from the bottom to the top of the invocation stack (aka call stack). Invocation exits are a cleanup mechanism targeting the abnormal end-of-invocationfor example, end-of-invocation due to unhandled exceptions or thread termination. For this reason, invocation exits can monitor for end job commands issued to a job and protect resources allocated in each individual invocation.

An OPM program can register an invocation exit program for itself via the Set Invocation Exit (SETIEXIT) MI instruction. An ILE HLL procedure can register one or more invocation exit procedures for itself via the Register Call Stack Entry Termination User Exit Procedure (CEERTX) API. Simon Coulter mentioned these invocation exits techniques that target end-of-job due to end job operations in a post called Re: Regarding *PSSR in the midrange-l mailing list back in 1999:

The *PSSR is not called when the job is terminated…. using SHTDN will work if the program is not waiting for input.

What is required here is an invocation exit program. Use the CEERTX (Register Call Stack Entry Termination User Exit Procedure) API. This should be the first thing the program does, then if it is terminated by anything other than a return-to-caller the named program is executed -- usually to clean-up or restore some state.

You can also use the SETIEXIT MI instruction.

The exit program will get control when the invocation is terminated due to normal exception handling or when the process (job) is terminated.

The CEEUTX API or the CLRIEXIT MI instruction can be used to remove the exit program.

For the same reason explained by Simon in his 2001 post, as an HLL-specific exception handling construct, *PSSR routine will not be invoked when an invocation is terminated due to an end job command.

Using Invocation Exit Programs in OPM Programs via the SETIEXIT and CLRIEXIT MI Instructions

For decades, the SETIEXIT instruction has been used in OPM RPG and OPM CL programs to register invocation exits. Issue a CRTRPGPGM or CRTCLPGM command with GENOPT(*LIST) and see the MI instructions in the result compiler listing. You will find the invocation exit programs used by OPM RPG and OPM CL are QSYS/QRGXINVX and QSYS/QCLCLNUP, respectively.

The Set Invocation Exit (SETIEXIT) and Clear Invocation Exit (CLRIEXIT) MI instructions register and unregister, respectively, the invocation exit program for the OPM program in which they are issued. The SETIEXIT instruction accepts an initialized or resolved system pointer to the invocation exit program as its first operand, and an argument list to be passed to the invocation exit program as its second operand. The system pointer to the invocation exit program must be in either the static or automatic storage of the program invoking this instruction. If the argument list operand is null, no arguments are passed to the invocation exit program. If an invocation exit program currently exists for the requesting invocation, it is replaced. No operand verification takes place when this instruction is executed. Nor are copies made of the operands, so changes made to the operand values after execution of this instruction will be used during later operand verification when the invocation exit program is invoked. At that time, execute authorization verification to the invocation exit program and any contexts referenced for materialization take place. Also, materialization lock enforcement occurs to contexts referenced for materialization. The CLRIEXIT instruction removes the invocation exit program for the requesting invocation. An implicit clear of the invocation exit occurs when the invocation exit program is given control or the program that set the invocation exit completes execution.

The following is an MI program, eoj09.emi, that registers itself as its invocation exit program via the SETIEXIT instruction. EOJ09 accept a CHAR(1) flag parameter passed by reference and an optional CHAR(20) arg parameter passed as scalar. When the flag parameter is set to 'E', EOJ09 works as an invocation exit program and does necessary cleanup work.

dcl spcptr @flag parm           ;

dcl dd arg char(20)   parm       ;

/**

* Parameter list of EOJ09's external entry   point.

* -   CHAR(1) @var flag passed by reference. Set @var flag to 'E' if

*     EOJ09 is expected to execute as an invocation exit program.

* -   Optional CHAR(20) scalar.

*/

dcl ol plist (

       @flag,

       arg

) parm ext min(1)               ;

entry i-main(plist)   ext         ;

dcl dd flag char(1)   bas(@flag) ;

       /* Check flag parm. Branch to label   i-inv-exit

           if flag equal to 'E'. */

       cmpbla(b) flag, "E"

         / eq(i-inv-exit)     ;

brk "START"                     ;

       /* Retrieve a SYSPTR of mine via   MATINVE, option hex 01 */

dcl dd inve-tmpl char(16)   auto bdry(16)     ;

       dcl sysptr me def(inve-tmpl) pos(1) ;

       matinve inve-tmpl, *, x'01' ;

brk "1"                             ;

       /* Set myself as my INV-EXIT */

       setiexit me, argl-exit ;

brk "2"                         ;

       /* Do my works */

       cpybrep msg, ' '       ;

       cpybla msg, "Doing my works   ..." ;

       %sendmsg(msg, 32)       ;

dcl dd wt auto   char(16)         ;

       dcl dd * char(8) def(wt) pos(1) init(

           x"00000D693A400000"

       ) ; /* 1 hour */

       waittime wt             ; /* Sleep ... */

see-you:      

       rtx *                   ;

/* Run as INV-EXIT */

i-inv-exit:

brk   "INVEXIT"                   ;

       cpybrep msg, ' '       ;

       cpybla msg, "INV-EXIT:" ;

       cpybla msg(11:20), arg ;

       %sendmsg(msg, 32)       ;

       cpybrep msg, "cleanup " ;

       %sendmsg(msg, 32)       ;

       b see-you               ;

dcl dd exit-flag char(1)   init("E") ;

dcl spcptr @exit-flag auto   init(exit-flag) ;

dcl dd exit-arg char(20)   stat init (

       "Oops, time to leave!"

)                               ;

/* Argument list to   INV-EXIT */

dcl ol argl-exit (

       @exit-flag,

       exit-arg

) arg                           ;

dcl dd msg char(32)   auto       ;

pend                           ;

Submit a batch job that calls EOJ09 like so:

   SBMJOB JOB(A)

           CMD(CALL EOJ09 A)

           LOG(4 0 *MSG) /* Log message text   */

Then end it with an ENDJOB A *IMMED command. The printed job log of job ABC might look like the following:

Job name . . . . . . . . . . :   A               User . . . . . . :   LJL         Number . . . . . . . . . . . :   531606

   Job description . . . . . . :   LJL             Library . . . . . :   LSBIN

MSGID       TYPE                   SEV DATE       TIME             FROM PGM     LIBRARY     INST       TO PGM     LIBRARY     INST

CPF1124     Information             00   12/09/26   14:18:12.843632 QWTPIIPP     QSYS       0671     *EXT                    *N

                                     Message   . . . . :   Job 531606/LJL/A started on   12/09/26 at 14:18:12 in

                                         subsystem QBATCH in QSYS. Job entered system on 12/09/26   at 14:18:12.

CPI1125     Information             00   12/09/26   14:18:12.844144 QWTPCRJA     QSYS       010F     *EXT                   *N

                                     Message   . . . . :   Job 531606/LJL/A submitted.

*NONE       Request                       12/09/26 14:18:12.844304 QWTSCSBJ                 *N       QCMD       QSYS       0194

                                     Message   . . . . : -CALL PGM(EOJ09) PARM(A)

*NONE       Information                   12/09/26 14:18:12.844488 EOJ09         LSBIN       0019    QCMD       QSYS       01C7

                                     Message   . . . . :   Doing my work ...

CPC1125     Completion             50   12/09/26   14:18:18.576376 QWTCCCNJ     QSYS       0794     *EXT                   *N

                                    Message . . . . :   Job 531606/LJL/A was ended by user LJL.

*NONE       Information                   12/09/26 14:18:18.576512 EOJ09         LSBIN       0019     EOJ09       LSBIN       0009

                                     Message   . . . . :   INV-EXIT: Oops, time to   leave!

*NONE       Information                   12/09/26 14:18:18.576528 EOJ09         LSBIN       0019     EOJ09       LSBIN       0009

                                     Message   . . . . :   cleanup cleanup cleanup   cleanup

CPF1164     Completion             00   12/09/26   14:18:18.576976 QWTMCEOJ     QSYS       00D8     *EXT                   *N

                                     Message   . . . . :   Job 531606/LJL/A ended on 12/09/26   at 14:18:18; 1 seconds

                                     used;   end code 50 .

Using Invocation Exit Procedures in ILE Programs via the CEERTX and CEEUTX CEE APIs

The Register Call Stack Entry Termination User Exit Procedure (CEERTX) and the Unregister Call Stack Entry Termination User Exit Procedure (CEEUTX) APIs register and unregister, respectively, an invocation exit procedure for the invocation entry in which they are invoked. Note that the CEERTX and CEEUTX APIs are implemented as system built-ins instead of ILE procedures (see <leenv.h>, aka source member QSYSINC/H.LEENV, in which these two CEE APIs are declared). Multiple invocation exit procedures can be registered via CEERTX for each invocation entry (aka call stack entry). When an invocation ends abnormally, invocation exit procedures registered for the invocation run in first in/first out (FIFO) order.

The CEERTX API accepts procedure pointer @exit_proc as its first (and only necessary) parameter, which specifies the invocation exit procedure. The second parameter of CEERTX is an optional space pointer, @exit_arg, addressing the argument to be passed to the invocation exit procedure when the target invocation ends abnormally. The third parameter of CEERTX is optional structure fc of type FEEDBACK (see Data Type Definitions of ILE CEE APIs for details). The invocation exit procedure registered by CEERTX accepts only one parameter, the space pointer @exit_arg passed to CEERTX. The CEEUTX API accepts an input procedure pointer and removes a previous registration of it for the target invocation. If the same procedure is registered for the invocation more than once, CEEUTX processes the registrations in last in/first out (LIFO) order. The following RPG example, eoj10.rpgle, demonstrates the basic usage of CEERTX.

     h dftactgrp(*no) bnddir('QC2LE')

     * Prototype of CEERTX

     d ceertx         pr                 extproc('CEERTX')

     d   @exit_proc                   *   procptr

     d     @exit_arg                       *   options(*omit)

     d     fc                         12a     options(*omit)

     * Prototype of CEEUTX

     d ceeutx         pr                 extproc('CEEUTX')

     d   @exit_proc                   *   procptr

     d     fc                         12a     options(*omit)

     * Prototype of libc routine sleep()

     d sleep           pr           10i 0 extproc('sleep')

     d                               10u 0 value

    *   Invocation exit procedure

     d inv_exit       pr

     d     @arg                         *

     d @exit_proc     s               *   procptr

     d                                       inz(%paddr(inv_exit))

     d @arg           s               * inz(%addr(hello))

     d hello           s             20a     inz('Hello from INV-EXIT')

     /free

           ceertx(@exit_proc : @arg : *omit);

           sleep(600);

           *inlr = *on;

     /end-free

     p inv_exit       b

     d inv_exit      pi

     d     @arg                         *

     d arg             s             20a     based(@arg)

     /free

           dsply 'Exit Arg' '' arg;

     /end-free

     p                 e

To test EOJ10, you can simply submit a batch job calls EOJ10, end it with a ENDJOB *IMMED command, and then check the QSYSOPR message queue for the output message of EOJ10.

Monitor for End Job Operations via the *EXT Scope Message

The Send Scope Message (QMHSNDSM) API sends a scope message to a call stack entry. Scope messages are a way to call a program when the call stack entry that called the QMHSNDSM API ends or when the job using this API ends. The exit can be either normal or abnormal. The three scope types (*EXT, *PGM, and *CSE) indicate when the scope-handling program should be called. As Simon mentioned in a 2011 post, to have the scope-handling program run at job or routing step ending, specify *EXT for the scope type parameter. To unregister a scope-handling program, you can remove the previously sent scope message by using the Remove Program Messages (QMHRMVPM) API.

An interesting part of the QMHSNDSM API's design is that it distinguishes between a normal exit of an invocation and a transfer control. The difference between program scoping (*PGM) and call stack entry (*CSE) scoping is in how they handle a transfer control. When a transfer control occurs, the scope-handling program is called for scope type *PGM because the program or ILE procedure ended, but the scope-handling program is not called for scope type *CSE because the call stack is still active.

The following is an RPG example, eoj11.rpgle, that monitors an end job operation by registering itself as a *EXT scope program. When the number of parameters passed to EOJ11 is more than zero, EOJ11 works as a scope program.

     h dftactgrp(*no) bnddir('QC2LE')

     * API error code structure

     d qusec_t         ds                 qualified

     d                                       based(@dummy)

     d     bytes_in                   10i 0

     d     bytes_out                   10i   0

     d     msgid                       7a

     d                               1a

     * Message-specific message data

     * Prototype of the Send Scope Message   (QMHSNDSM) API

     d QMHSNDSM       pr                  extpgm('QMHSNDSM')

     d     type                       10a

     d     scope_pgm                   20a

     d     arg                         1a     options(*varsize)

     d     arg_len                     10i   0

     d     msg_key                    4a

     d     ec                                 likeds(qusec_t)

     * Prototype of libc routine sleep()

     d sleep           pr           10i 0 extproc('sleep')

     d                               10u 0 value

     d scope_type     s             10a     inz('*EXT')

     d scope_pgm       s             20a     inz('EOJ11     *LIBL')

     d arg             s             20a   inz('Hi,   scope program!')

     d arg_len         s             10i 0 inz(32)

     d msg_key         s             4a

     d ec                ds                 likeds(qusec_t)

     d text           s             30a

     d i_main         pr                 extpgm('EOJ11')

     d     greeting                   20a

     d i_main         pi

     d     greeting                   20a

     /free

           if %parms() > 0; // Now, EOJ11   works as a scope program.

               // Do cleanup works

               dsply 'Scope-handling program   invoked' '';

               text = 'ARG: ' + greeting;

               dsply text '';

              dsply 'Cleanup, cleanup, cleanup ...'   '';

               *inlr = *on;

               return;

           endif;

           // Register myself as a *EXT   scope-handling program

           ec.bytes_in = %len(ec);

           QMHSNDSM( scope_type

                  : scope_pgm

                   : arg

                   : arg_len

                   : msg_key

                   : ec);

           // Do my works

           dsply 'Doing my works ...' '';

           sleep(600);

           *inlr = *on;

     /end-free

To test EOJ11, submit a batch job that runs EOJ11, and then end it with an ENDJOB *IMMED command. The messages sent to the QSYSOPR message queue might look like the following:

   DSPLY   Doing my work ...            

   Job 531775/LJL/A was ended by user LJL.

   DSPLY   Scope-handling program invoked

   DSPLY   ARG: Hi, scope program!        

   DSPLY   Cleanup, cleanup, cleanup ...  

Know the End Reason of an MI Process in an Invocation Exit, ACTGRP Exit, or Scope Program

An end job operation is one of the reasons that an invocation exit, ACTGRP exit, or scope program registered in an MI process is invoked, but it's not the only reason. An unhandled exception or an unhandled signal delivered to the process with a default signal-handling action of terminate the process or terminate the request would also lead to process termination. To know the process termination reason exactly, you can materialize the Process Status Indicators via the Materialize Process Attributes (MATPRATR) MI instruction with option hex 20 within an invocation exit, ACTGRP exit, or scope program. The Process Initial Internal Termination (PIIT) status and the Process Initial External Termination (PIET) status in the materialized Process Status Indicators represent the final internal termination status and external termination status prior to entering the termination phase, respectively, and are updated by the most recent internal termination action and external termination action, respectively. It is possible for both the PIIT and PIET status fields to contain valid termination status values. The PIIT and/or PIET status fields contain valid termination status values when an invocation exit, ACTGRP exit, or scope program registered for the process is invoked. The 1-byte PIIT reason and 1-byte PIET reason fields represent the reason of final internal termination and final external termination, respectively. The following ILE RPG prototype of the MATPRATR instruction and the definition of the materialization template structure for Process Status Indicators, matpratr_20_t, are extracted from mih-prcthd.rpgleinc. Possible internal/external process termination reasons are listed in the comments of subfields piit and piet of the matpratr_20_t structure.

     /**

     * Materialization template for   MATPRATR, option hex 20 --

     * Process status indicators.

     */

     d matpratr_20_t   ds                 qualified

     d                                       based(@dummy)

     d     bytes_in                   10i   0

     d     bytes_out                   10i   0

     *

     * Thread state.

     * Bits 0-2: External existence state

     *     000 = Suspended due to Suspend Process or Suspend Thread

     *     010 = Suspended due to Suspend Process or Suspend Thread,

     *         in instruction wait

     *     100 = Active, in ineligible wait

     *     101 = Active, in current MPL

     *     110 = Active, in instruction wait

     *     111 = Active, in instruction wait, in current MPL

     * Bit 3: Invocation exit active

     * Bit 4: Stopped by a signal

     * Bit 5: Suspended by Suspend Thread

      *   Bits 6-7: Reserved (binary 0)

     * Bits 8-10: Internal processing phase

     *     001 = Initiation phase

     *     010 = Problem phase

     *     100 = Termination phase

     * Bits 11-15: Reserved (binary 0)

     *

     d     thd_state                    2a

     d     pending_thread_interrupts...

     d                               2a

     *

     * Process initial internal termination   status

     *

     * @remark The process initial internal   termination status

     * represents the final internal   termination status prior to

     * entering the termination phase. It is   updated by the most

     * recent internal termination action.   It is possible for both

     * the process initial internal   termination status and the

     * process initial external termination   status fields to contain

     * valid non-zero values.

     *

     d     piit                         3a

     *

     * Hex 80 = Return from first invocation   in problem phase

     * Hex 40 = Return from first invocation   in initiation phase and

     *         no problem phase program specified.

     * Hex 21 = Terminate Thread instruction   issued against the

     *         initial thread by a thread in the   process.

     * Hex 20 = Terminate Process   instruction issued by a thread

    *           within the process.

     * Hex 18 = An unhandled signal with a   default signal handling

     *         action of terminate the process or   terminate the

     *         request was delivered to the   process.

     * Hex 10 = Exception was not handled by   the initial thread in

     *         the process.

     * Hex 00 = Process terminated   externally.

     *

     d       iit_reason                 1a     overlay(piit:1)

     * Initial internal termination code

     d       iit_code                  2a   overlay(piit:2)

     *

     * Process initial external termination   status

     *

     * @remark The process external internal   termination status

     * represents the final external   termination status prior to

     * entering the termination phase. It is   updated by the most

     * recent external termination action.   It is possible for both

     * the process initial internal   termination status and the

     * process initial external termination   status fields to contain

     * valid non-zero values.

     *

     d     piet                         3a

     * Initial external termination reason:

     *     Hex 80 = Terminate Process instruction issued explicitly to

     *           the process by a thread in   another process.

     *     Hex 40 = Terminate Thread instruction issued explicitly to

     *           the initial thread of the process   by a thread in

     *           another process.

     *     Hex 00 = Process terminated internally.

     d       iet_reason                 1a     overlay(piet:1)

     * Initial external termination code

     d       iet_code                   2a     overlay(piet:2)

     *

     * Process final termination status

     *

     * @remark The process final termination   status is presented as

     * event-related data in the terminate   process event. Usually the

     * event is the only source of the   process final termination

     * status since the process will cease   to exist before its

     * attributes can be materialized.

     *

     * @remark The process final termination   status describes how the

     * final phase (aka the termination   phase) of the process

     * terminated. It is updated by the most   recent termination

     * action for the final process phase.

     *

     d     pfit                        3a

     /**

     * @BIF _MATPRATR1 (Materialize Process   Attributes (MATPRATR))

     */

     d matpratr1       pr                 extproc('_MATPRATR1')

     d       receiver                         likeds(matpratr_tmpl_t)

     d       option                    1a

     /**

     * @BIF _MATPRATR2 (Materialize Process   Attributes (MATPRATR))

     */

     d matpratr2       pr                 extproc('_MATPRATR2')

     d       receiver                         likeds(matpratr_tmpl_t)

     d       pcs                        *

     d       option                     1a

The pcs operand of _MATPRATR2 identifies the process control space (PCS) object associated with the process whose attributes are to be materialized.

The following RPG example, eoj12.rpgle, reports the following information available in the Process Status Indicators returned by MATPRATR: current process phase, whether invocation exit is currently active, process initial internal termination (PIIT) reason, and process initial external termination (PIET) reason. Add a call to program EOJ12 to previously presented example ACTGRP exit, invocation exit, or scope programs so that you can tell whether your job is ending due to end job operations or not.

     h dftactgrp(*no) bnddir('QC2LE')

     fQSYSPRT   O     f 132       printer

     /copy mih-prcthd.rpgleinc

     d w               s             1a

     d item_name       s             40a   inz('Item   name')

     d item_value     s           120a     inz('...')

     d psts           ds                 likeds(matpratr_20_t)

     d opt             s             1a     inz(x'20')

     d a2             s             2a

     /free

           // Materialize process state   indicators of the current MI process

           psts.bytes_in =   %len(matpratr_20_t);

           matpratr1(psts : opt);

           // Current process phase -- bits   8-10 of thd_state

           a2 = %bitand(psts.thd_state :   x'00E0');

         item_name = 'Current process   phase:';

           except ITEMREC;

           select;

           when a2 = x'0020';

               item_value = 'Initiation   phase';

           when a2 = x'0040';

               item_value = 'Problem phase';

         when a2 = x'0080';

               item_value = 'Termination   phase';

           endsl;

           except VALREC;

           // Invocation exit active?

           item_name = 'Invocation exit   active:';

           except ITEMREC;

           a2 = %bitand(psts.thd_state :   x'1000');

           if a2 = x'0000';

               item_value = 'No';

           else;

               item_value = 'Yes';

           endif;

           except VALREC;

           if psts.iit_reason = x'00' and   psts.iet_reason = x'00';

              *inlr = *on;

               return;

           endif;

           // Initial internal termination   reason

           item_name = 'Initial internal   termination reason:';

           except ITEMREC;

           select;

           when psts.iit_reason = x'80';

               item_value = 'Return from   first invocation '

                   + 'in problem phase';

           when psts.iit_reason = x'40';

               item_value = 'Return from   first invocation in '

                   + 'initiation phase and no   problem phase program '

                   + 'specified';

           when psts.iit_reason = x'21';

               item_value = 'Terminate Thread   instruction issued against '

                   + 'the initial thread by a   thread in the process';

          when psts.iit_reason = x'20';

               item_value = 'Terminate   Process instruction issued '

                   + 'by a thread within the   process';

           when psts.iit_reason = x'18';

               item_value = 'An unhandled   signal with a default signal '

                   + 'handling action of   terminate the process or '

                   + 'terminate the request   was delivered to the process';

           when psts.iit_reason = x'10';

               item_value = 'Exception was   not handled by the initial '

                   + 'thread in the process';

           when psts.iit_reason = x'00';

               item_value = 'Process   terminated externally';

           endsl;

           except VALREC;

           // Initial external termination   reason

           item_name = 'Initial external   termination reason:';

           except ITEMREC;

           select;

           when psts.iet_reason = x'80';

               item_value = 'Terminate   Process instruction issued '

                   + 'explicitly to the   process by a thread in '

                   + 'another process';

           when psts.iet_reason = x'40';

               item_value = 'Terminate Thread   instruction issued '

                   + 'explicitly to the   initial thread of the process '

                  + 'by a thread in another process';

           when psts.iet_reason = x'00';

               item_value = 'Process   terminated internally';

           endsl;

           except VALREC;

           *inlr = *on;

     /end-free

     oQSYSPRT   e              ITEMREC

     o                       item_name

     oQSYSPRT   e           VALREC

     o                       w                   5

     o                       item_value

For example, add a call to EOJ12 to the invocation exit procedure of the previous RPG example eoj10.rpgle as shown:

     p inv_exit       b

     d   eoj12           pr                 extpgm('EOJ12')

     d inv_exit       pi

     d     @arg                         *

     d arg             s             20a     based(@arg)

    /free

             eoj12();

           dsply 'Exit Arg' '' arg;

     /end-free

     p                 e

Submit a batch job that runs EOJ10, end the submitted job with an ENDJOB *IMMED command, and then check the output spooled file printed by EOJ12. The output of EOJ12 might look like the following:

Current process phase:

     Problem phase

Invocation exit active:

     Yes

Initial internal termination reason:

     Process terminated externally

Initial external termination reason:

     Terminate Process instruction issued   explicitly to the process by a thread in another process

Submit a batch job to call EOJ10 again, and end the submitted job with an ENDJOB *CNTRLD command. The resulting output of EOJ12 might look like this:

Current process phase:

     Problem phase

Invocation exit active:

     Yes

Initial internal termination reason:

     Terminate Process instruction issued by   a thread within the process

Initial external termination reason:

     Process terminated internally

Now you know how to tell whether a job is ending due to an end job command within an invocation exit, an ACTGRP exit, or a scope program.

Final Thoughts

As mentioned in Part I of this article, an end job command can specify a delay time, either via the DELAY parameter of an ENDJOB *CNTRLD command or the QENDJOBLMT system value for an ENDJOB *IMMED command. After the delay time specified by an end job command elapses, the job will be ended by the system. Be aware that the same is not the case for a job utilizing one of these three end-of-job cleanup techniques: invocation exits, ACTGRP exits, and scope programs. Any delay or hanging that occurs in an invocation exit, an ACTGRP exit, or a scope program will delay or hang the end-of-job processing. Imagine that you issue an ENDJOB *IMMED command to end a job. An invocation exit procedure registered for one of the programs currently in the job's call stack receives control and starts doing necessary cleanup work. However, the invocation exit is stuck for some reason (for example, trying to allocate an exclusive lock on an MI object being used by many processes). In this condition, how long it will take the job to end is undetermined. The last chance to end such a job is by issuing an End Job Abnormal (ENDJOBABN) command to the job 10 minutes after the previous ENDJOB *IMMED command.

Junlei Li

Junlei Li is a programmer from Tianjin, China, with 10 years of experience in software design and programming. Junlei Li began programming under i5/OS (formerly known as AS/400, iSeries) in late 2005. He is familiar with most programming languages available on i5/OS—from special-purpose languages such as OPM/ILE RPG to CL to general-purpose languages such as C, C++, Java; from strong-typed languages to script languages such as QShell and REXX. One of his favorite programming languages on i5/OS is machine interface (MI) instructions, through which one can discover some of the internal behaviors of i5/OS and some of the highlights of i5/OS in terms of operating system design.

 

Junlei Li's Web site is http://i5toolkit.sourceforge.net/, where his open-source project i5/OS Programmer's Toolkit (https://sourceforge.net/projects/i5toolkit/) is documented.

BLOG COMMENTS POWERED BY DISQUS

LATEST COMMENTS

Support MC Press Online

RESOURCE CENTER

  • WHITE PAPERS

  • WEBCAST

  • TRIAL SOFTWARE

  • White Paper: Node.js for Enterprise IBM i Modernization

    SB Profound WP 5539

    If your business is thinking about modernizing your legacy IBM i (also known as AS/400 or iSeries) applications, you will want to read this white paper first!

    Download this paper and learn how Node.js can ensure that you:
    - Modernize on-time and budget - no more lengthy, costly, disruptive app rewrites!
    - Retain your IBM i systems of record
    - Find and hire new development talent
    - Integrate new Node.js applications with your existing RPG, Java, .Net, and PHP apps
    - Extend your IBM i capabilties to include Watson API, Cloud, and Internet of Things


    Read Node.js for Enterprise IBM i Modernization Now!

     

  • Profound Logic Solution Guide

    SB Profound WP 5539More than ever, there is a demand for IT to deliver innovation.
    Your IBM i has been an essential part of your business operations for years. However, your organization may struggle to maintain the current system and implement new projects.
    The thousands of customers we've worked with and surveyed state that expectations regarding the digital footprint and vision of the companyare not aligned with the current IT environment.

    Get your copy of this important guide today!

     

  • 2022 IBM i Marketplace Survey Results

    Fortra2022 marks the eighth edition of the IBM i Marketplace Survey Results. Each year, Fortra captures data on how businesses use the IBM i platform and the IT and cybersecurity initiatives it supports.

    Over the years, this survey has become a true industry benchmark, revealing to readers the trends that are shaping and driving the market and providing insight into what the future may bring for this technology.

  • Brunswick bowls a perfect 300 with LANSA!

    FortraBrunswick is the leader in bowling products, services, and industry expertise for the development and renovation of new and existing bowling centers and mixed-use recreation facilities across the entertainment industry. However, the lifeblood of Brunswick’s capital equipment business was running on a 15-year-old software application written in Visual Basic 6 (VB6) with a SQL Server back-end. The application was at the end of its life and needed to be replaced.
    With the help of Visual LANSA, they found an easy-to-use, long-term platform that enabled their team to collaborate, innovate, and integrate with existing systems and databases within a single platform.
    Read the case study to learn how they achieved success and increased the speed of development by 30% with Visual LANSA.

     

  • Progressive Web Apps: Create a Universal Experience Across All Devices

    LANSAProgressive Web Apps allow you to reach anyone, anywhere, and on any device with a single unified codebase. This means that your applications—regardless of browser, device, or platform—instantly become more reliable and consistent. They are the present and future of application development, and more and more businesses are catching on.
    Download this whitepaper and learn:

    • How PWAs support fast application development and streamline DevOps
    • How to give your business a competitive edge using PWAs
    • What makes progressive web apps so versatile, both online and offline

     

     

  • The Power of Coding in a Low-Code Solution

    LANSAWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed.
    Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

    • Discover the benefits of Low-code's quick application creation
    • Understand the differences in model-based and language-based Low-Code platforms
    • Explore the strengths of LANSA's Low-Code Solution to Low-Code’s biggest drawbacks

     

     

  • Why Migrate When You Can Modernize?

    LANSABusiness users want new applications now. Market and regulatory pressures require faster application updates and delivery into production. Your IBM i developers may be approaching retirement, and you see no sure way to fill their positions with experienced developers. In addition, you may be caught between maintaining your existing applications and the uncertainty of moving to something new.
    In this white paper, you’ll learn how to think of these issues as opportunities rather than problems. We’ll explore motivations to migrate or modernize, their risks and considerations you should be aware of before embarking on a (migration or modernization) project.
    Lastly, we’ll discuss how modernizing IBM i applications with optimized business workflows, integration with other technologies and new mobile and web user interfaces will enable IT – and the business – to experience time-added value and much more.

     

  • UPDATED: Developer Kit: Making a Business Case for Modernization and Beyond

    Profound Logic Software, Inc.Having trouble getting management approval for modernization projects? The problem may be you're not speaking enough "business" to them.

    This Developer Kit provides you study-backed data and a ready-to-use business case template to help get your very next development project approved!

  • What to Do When Your AS/400 Talent Retires

    FortraIT managers hoping to find new IBM i talent are discovering that the pool of experienced RPG programmers and operators or administrators is small.

    This guide offers strategies and software suggestions to help you plan IT staffing and resources and smooth the transition after your AS/400 talent retires. Read on to learn:

    • Why IBM i skills depletion is a top concern
    • How leading organizations are coping
    • Where automation will make the biggest impact

     

  • Node.js on IBM i Webinar Series Pt. 2: Setting Up Your Development Tools

    Profound Logic Software, Inc.Have you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application. In Part 2, Brian May teaches you the different tooling options available for writing code, debugging, and using Git for version control. Attend this webinar to learn:

    • Different tools to develop Node.js applications on IBM i
    • Debugging Node.js
    • The basics of Git and tools to help those new to it
    • Using NodeRun.com as a pre-built development environment

     

     

  • Expert Tips for IBM i Security: Beyond the Basics

    SB PowerTech WC GenericIn this session, IBM i security expert Robin Tatam provides a quick recap of IBM i security basics and guides you through some advanced cybersecurity techniques that can help you take data protection to the next level. Robin will cover:

    • Reducing the risk posed by special authorities
    • Establishing object-level security
    • Overseeing user actions and data access

    Don't miss this chance to take your knowledge of IBM i security beyond the basics.

     

     

  • 5 IBM i Security Quick Wins

    SB PowerTech WC GenericIn today’s threat landscape, upper management is laser-focused on cybersecurity. You need to make progress in securing your systems—and make it fast.
    There’s no shortage of actions you could take, but what tactics will actually deliver the results you need? And how can you find a security strategy that fits your budget and time constraints?
    Join top IBM i security expert Robin Tatam as he outlines the five fastest and most impactful changes you can make to strengthen IBM i security this year.
    Your system didn’t become unsecure overnight and you won’t be able to turn it around overnight either. But quick wins are possible with IBM i security, and Robin Tatam will show you how to achieve them.

  • Security Bulletin: Malware Infection Discovered on IBM i Server!

    SB PowerTech WC GenericMalicious programs can bring entire businesses to their knees—and IBM i shops are not immune. It’s critical to grasp the true impact malware can have on IBM i and the network that connects to it. Attend this webinar to gain a thorough understanding of the relationships between:

    • Viruses, native objects, and the integrated file system (IFS)
    • Power Systems and Windows-based viruses and malware
    • PC-based anti-virus scanning versus native IBM i scanning

    There are a number of ways you can minimize your exposure to viruses. IBM i security expert Sandi Moore explains the facts, including how to ensure you're fully protected and compliant with regulations such as PCI.

     

     

  • Encryption on IBM i Simplified

    SB PowerTech WC GenericDB2 Field Procedures (FieldProcs) were introduced in IBM i 7.1 and have greatly simplified encryption, often without requiring any application changes. Now you can quickly encrypt sensitive data on the IBM i including PII, PCI, PHI data in your physical files and tables.
    Watch this webinar to learn how you can quickly implement encryption on the IBM i. During the webinar, security expert Robin Tatam will show you how to:

    • Use Field Procedures to automate encryption and decryption
    • Restrict and mask field level access by user or group
    • Meet compliance requirements with effective key management and audit trails

     

  • Lessons Learned from IBM i Cyber Attacks

    SB PowerTech WC GenericDespite the many options IBM has provided to protect your systems and data, many organizations still struggle to apply appropriate security controls.
    In this webinar, you'll get insight into how the criminals accessed these systems, the fallout from these attacks, and how the incidents could have been avoided by following security best practices.

    • Learn which security gaps cyber criminals love most
    • Find out how other IBM i organizations have fallen victim
    • Get the details on policies and processes you can implement to protect your organization, even when staff works from home

    You will learn the steps you can take to avoid the mistakes made in these examples, as well as other inadequate and misconfigured settings that put businesses at risk.

     

     

  • The Power of Coding in a Low-Code Solution

    SB PowerTech WC GenericWhen it comes to creating your business applications, there are hundreds of coding platforms and programming languages to choose from. These options range from very complex traditional programming languages to Low-Code platforms where sometimes no traditional coding experience is needed.
    Download our whitepaper, The Power of Writing Code in a Low-Code Solution, and:

    • Discover the benefits of Low-code's quick application creation
    • Understand the differences in model-based and language-based Low-Code platforms
    • Explore the strengths of LANSA's Low-Code Solution to Low-Code’s biggest drawbacks

     

     

  • Node Webinar Series Pt. 1: The World of Node.js on IBM i

    SB Profound WC GenericHave you been wondering about Node.js? Our free Node.js Webinar Series takes you from total beginner to creating a fully-functional IBM i Node.js business application.
    Part 1 will teach you what Node.js is, why it's a great option for IBM i shops, and how to take advantage of the ecosystem surrounding Node.
    In addition to background information, our Director of Product Development Scott Klement will demonstrate applications that take advantage of the Node Package Manager (npm).
    Watch Now.

  • The Biggest Mistakes in IBM i Security

    SB Profound WC Generic The Biggest Mistakes in IBM i Security
    Here’s the harsh reality: cybersecurity pros have to get their jobs right every single day, while an attacker only has to succeed once to do incredible damage.
    Whether that’s thousands of exposed records, millions of dollars in fines and legal fees, or diminished share value, it’s easy to judge organizations that fall victim. IBM i enjoys an enviable reputation for security, but no system is impervious to mistakes.
    Join this webinar to learn about the biggest errors made when securing a Power Systems server.
    This knowledge is critical for ensuring integrity of your application data and preventing you from becoming the next Equifax. It’s also essential for complying with all formal regulations, including SOX, PCI, GDPR, and HIPAA
    Watch Now.

  • Comply in 5! Well, actually UNDER 5 minutes!!

    SB CYBRA PPL 5382

    TRY the one package that solves all your document design and printing challenges on all your platforms.

    Produce bar code labels, electronic forms, ad hoc reports, and RFID tags – without programming! MarkMagic is the only document design and print solution that combines report writing, WYSIWYG label and forms design, and conditional printing in one integrated product.

    Request your trial now!

  • Backup and Recovery on IBM i: Your Strategy for the Unexpected

    FortraRobot automates the routine tasks of iSeries backup and recovery, saving you time and money and making the process safer and more reliable. Automate your backups with the Robot Backup and Recovery Solution. Key features include:
    - Simplified backup procedures
    - Easy data encryption
    - Save media management
    - Guided restoration
    - Seamless product integration
    Make sure your data survives when catastrophe hits. Try the Robot Backup and Recovery Solution FREE for 30 days.

  • Manage IBM i Messages by Exception with Robot

    SB HelpSystems SC 5413Managing messages on your IBM i can be more than a full-time job if you have to do it manually. How can you be sure you won’t miss important system events?
    Automate your message center with the Robot Message Management Solution. Key features include:
    - Automated message management
    - Tailored notifications and automatic escalation
    - System-wide control of your IBM i partitions
    - Two-way system notifications from your mobile device
    - Seamless product integration
    Try the Robot Message Management Solution FREE for 30 days.

  • Easiest Way to Save Money? Stop Printing IBM i Reports

    FortraRobot automates report bursting, distribution, bundling, and archiving, and offers secure, selective online report viewing.
    Manage your reports with the Robot Report Management Solution. Key features include:

    - Automated report distribution
    - View online without delay
    - Browser interface to make notes
    - Custom retention capabilities
    - Seamless product integration
    Rerun another report? Never again. Try the Robot Report Management Solution FREE for 30 days.

  • Hassle-Free IBM i Operations around the Clock

    SB HelpSystems SC 5413For over 30 years, Robot has been a leader in systems management for IBM i.
    Manage your job schedule with the Robot Job Scheduling Solution. Key features include:
    - Automated batch, interactive, and cross-platform scheduling
    - Event-driven dependency processing
    - Centralized monitoring and reporting
    - Audit log and ready-to-use reports
    - Seamless product integration
    Scale your software, not your staff. Try the Robot Job Scheduling Solution FREE for 30 days.