You've learned how to use BIFs to handle the Date data type and perform a variety of operations with it. It's now time to do the same for the Time data type. I'll show you what RPG has to offer and present a funny function as an example.

Now that you mastered Date data type operations thanks to the last two TechTips (1 and 2), let's do the same for the Time data type. As you'll see, there are a lot of similarities between the two: the way the BIFs work is the same, in some cases you can actually use the same BIF, and so on.

It's %TIME

The %TIME BIF is similar to %DATE in every way: it converts character, numeric, or timestamp data expressions to type Time. The converted value remains unchanged but is returned as a Time type value.

The first parameter is the value to be converted. If you do not specify a value, %TIME() returns the current system time, just like %DATE() returns the system date. The second, optional, parameter is the time format for numeric or character input. Regardless of the input format, the output is returned in *ISO format (HH.MM.SS).

But the resemblances don't end here: you can perform Time operations with the plus (+) and minus (–) operators, as long as the operands are of the Time data type or are "Time-type-operation-compatible." And what is that, you ask? Well, just like the %DAYS, %MONTHS, and %YEARS BIFs I explained previously turned numeric data into "Date-type-operation-compatible" format, there are a few BIFs that do the same for Time: %MSECONDS, %SECONDS, %MINUTES, and %HOURS. So if you want to know what the time will be in an hour (or in other words, the current time plus 1 hour), you can code it like this:

D W_TIME         S               T   INZ

(…)

C                   EVAL     W_TIME = %TIME() + %HOURS(1)

W_Time is defined as a Time data type variable (notice the T on the right side). The %TIME() is used to retrieve the system's current time, and finally + %HOURS(1) is used to add an hour to it. This is just a simple example, but you can do all sorts of things with Time variables: convert, compare, extract parts (using %SUBDT, just like you'd do with a Date variable), and so on.

Let's write a funny (or depressing, depends on how much you love your work) function to illustrate some of the possibilities.

Do You Know How Long You Have to Work Until the Weekend?

The HowLongUntilWE function calculates how many days and hours you still have to work until a (certainly) much-deserved weekend break. It assumes a couple of things, just to keep the example simple:

• You work from Monday to Friday;
• When calculating how long you still have to work today, the break time/lunch time/whatever you call it, is ignored because the function doesn't know at what time it occurs;
• It ignores the minutes you still have left to work today.

Naturally, I could add a few more input parameters and some logic to overcome all of these limitations, but this intends to be a simple example. Having said that, let's code! Here's the first part of the function, from the header to the end of the input parameter validations:

*------------------------------------------------------------------------*

*   How long until the weekend (returns the days and hours until the w-e)*

*------------------------------------------------------------------------*

P HowLongUntilWE B                   Export                              

D HowLongUntilWE PI           200A                                      

* Input parameters                                                        

D P_WDStart                     T   VALUE                              

D P_WDEnd                       T   VALUE                              

D P_BreakTime                   2P 0 VALUE                                

* Work variables                                                        

D W_Return       S           200A   INZ(*Blanks)                        

D W_Date         S               D   INZ                                

D W_WDLeft       S             1P 0 INZ                                

D W_WDHours       S             3P 0 INZ                                

D W_WorkTimeLeft S             3P 0 INZ                            

D W_HoursLeftToday...                                                

D                 S             3P 0 INZ                            

D W_TotalLeft     S             3P 0 INZ                              

* Check input parms                                                  

* P_WDStart                                                          

C                   TEST(E)                 P_WDStart                

C                   IF       %Error                                  

C                   EVAL     W_Return = 'Invalid Work Day Start Time!'

C                   RETURN   W_Return                                

C                   ENDIF                                            

* P_WDEnd                                                            

C                   TEST(E)                 P_WDEnd                  

C                   IF       %Error                                  

C                   EVAL     W_Return = 'Invalid Work Day End Time!'

C                   RETURN   W_Return                                

C                   ENDIF                                              

Notice how TEST is used to check whether the input parameters contain valid times. I could also check whether the start time is lower than the end time, with a simple comparison: IF P_WDEnd < P_WDStart. The next step is retrieving relevant information for our function. In this case, we'll start by figuring out how many work days are left this week:

* If the input parms are ok,                                      

* 1 - Calculate how many work days are left;                      

* (Assuming that you work from Monday to Friday. Day 5 is Friday)  

C                   EVAL     W_WDLeft = 5 - Clc_DayOfWeek(%DATE())

* If this returns a negative number, it means that you still have to

* work the entire week                                            

C                   IF       W_WDLeft < *ZEROS                    

C                   EVAL     W_WDLeft = 5                          

C                   ENDIF                                          

Then all I need to do is determine how long a work day is by subtracting the P_WDStart from P_WDEnd using %DIFF and also take into account the break time:

* 2.1 - Then calculate how long is a work day, in hours            

C                   EVAL     W_WDHours = %DIFF(P_WDEnd : P_WDStart :

C                                               *HOURS) - P_BreakTime

This will be used to calculate the total hours left to work this week:

* 2.2 - and multiply by the days;                                

C                   EVAL     W_WorkTimeLeft = W_WDLeft * W_WDHours

The math here is simple: assume that today is Wednesday and that you work from 9:00 a.m. to 6:00 p.m., with a one-hour break for lunch. W_WDLeft will be 5 – 3 = 2, because the Clc_DayOfWeek(%DATE()) call will return 3 (the "numeric value" assigned to Wednesday by the Clc_DayOfWeek function). Then the time difference between the start and end times will be 18 – 9 – 1 (P_WDEnd – P_WDStart – P_BreakTime) = 8, and finally W_WorkTimeLeft will be 8 * 2 = 16. Let's continue and calculate the time left today. This is where things get a little more complicated:

* 3 - Finally, calculate and add today's work time left.  

*     There are two options: either your work day hasn't started,    

*     and we'll count the complete work day                          

C                   IF       %TIME() < P_WDStart                    

C                   EVAL     W_WDLeft = W_WDLeft + 1                

C                   ELSE                                              

*     Or it has. The code will calculate how many hours you still have

*     left today, ignoring the break time, because it doesn't know at  

*     what time it would occur                                          

C                   EVAL     W_HoursLeftToday = %DIFF(P_WDEnd : %TIME() :

C                                               *HOURS)                  

C                  ENDIF                                                

C                   EVAL     W_TotalLeft = W_HoursLeftToday            

C                                           + W_WorkTimeLeft            

Notice the use of %TIME() to check if you are within your normal work schedule. It's here as a reminder that date and time operations require careful planning and executing to avoid incongruous and unexpected results. The final step is returning the results to the calling program by composing a human-readable string:

C                   EVAL     W_Return = 'You have to work '              

C                                         + %Char(W_WDLeft) + ' days and '

C                                         + %Char(W_HoursLeftToday)      

C                                         + ' hours until the weekend!'  

C                                         + ' Or a total of '            

C                                         + %Char(W_TotalLeft) + ' hours!'

* Return the string                                                      

C                   RETURN   W_Return                                    

P HowLongUntilWE E                                                      

This string will include the results in two formats: total days plus today's hours left and total hours left. This could be made more complex by including the minutes, but I chose not do to it. However, if you want to try, let me suggest a way to do it: use %DIFF to calculate the difference in minutes instead of hours and then resort to %REM to transform the minutes into hours. For instance, 1 hour and 30 minutes will be returned as 90. The expression %REM(90 : 60) will return 30.

Here's How to Find Out!

Let's end this TechTip with a simple example of HowLongUntilWE's usage:

*------------------------------------------------------------------------*

*   Variables                                                           *

*------------------------------------------------------------------------*

D W_HowLong     S          200A   INZ(*Blanks)                        

*------------------------------------------------------------------------*

*   Copy Statements                                                      *

*------------------------------------------------------------------------*

* Time Operations                                                        

/Copy QCPYLESRC,TIM_OPS_PR                                              

* Test HowLongUntilWE                                                    

C                   EVAL     W_HowLong = HowLongUntilWE(T'09.00.00' :    

C                                                      T'18.00.00' :    

C                                                       1)              

C                   EVAL     *INLR = *On    

Just a quick note regarding the function's parameters: I'm using time literals in this example, again just to keep things simple. In a real-life scenario, you'd use Time data type variables or expressions in their place.

That's all for time operations. You can download the source code for the time functions service program and test program here.

This TechTip ends the "BIF Up Your Code!" subseries of RPG Academy. I hope that you enjoyed reading it and that, somehow, it helped you solve those "real-life" problems in a more readable and maintainable way. I know I left out quite a few BIFs. Some address more advanced scenarios or very particular situations that are out of the scope of this series. The RPG Academy series will continue with another important aspect of "modern" RPG: code structuring and organization. Until then, let me know what you think about this TechTip and this series in the Comments section below and/or the usual LinkedIn groups.                  

Rafael Victoria-Pereira

• Email
• Site

Rafael Victória-Pereira has more than 20 years of IBM i experience as a programmer, analyst, and manager. Over that period, he has been an active voice in the IBM i community, encouraging and helping programmers transition to ILE and free-format RPG. Rafael has written more than 100 technical articles about topics ranging from interfaces (the topic for his first book, Flexible Input, Dazzling Output with IBM i) to modern RPG and SQL in his popular RPG Academy and SQL 101 series on mcpressonline.com and in his books Evolve Your RPG Coding and SQL for IBM i: A Database Modernization Guide. Rafael writes in an easy-to-read, practical style that is highly popular with his audience of IBM technology professionals.

Rafael is the Deputy IT Director - Infrastructures and Services at the Luis Simões Group in Portugal. His areas of expertise include programming in the IBM i native languages (RPG, CL, and DB2 SQL) and in "modern" programming languages, such as Java, C#, and Python, as well as project management and consultancy.

---

MC Press books written by Rafael Victória-Pereira available now on the MC Press Bookstore.

		Evolve Your RPG Coding: Move from OPM to ILE...and Beyond Transition to modern RPG programming with this step-by-step guide through ILE and free-format RPG, SQL, and modernization techniques. List Price $79.95 Now On Sale
		Flexible Input, Dazzling Output with IBM i Uncover easier, more flexible ways to get data into your system, plus some methods for exporting and presenting the vital business data it contains. List Price $79.95 Now On Sale
		SQL for IBM i: A Database Modernization Guide Learn how to use SQL’s capabilities to modernize and enhance your IBM i database. List Price $79.95 Now On Sale